Nombre de colonnes d'une selection

Version imprimable

Bonjour,
Je m'interroge sur la façon d'obtenir le nombre de colonnes d'une selection !

Ca parait simple lorsque les cellules sont connexes mais dans le cas contraire le résultat est quelque peu étonnant!

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub nbcolonnes()
Dim MaSelection As Range
Dim MaSelection2 As Range
 
Set MaSelection = Union(Range("g9"), Range("i6"), Range("i13"), Range("k14"), Range("l7"))
MaSelection.Interior.Color = 10498160
 
MsgBox "Columns.count =" & MaSelection.Columns.Count _
& vbCr & "Areas count = " & MaSelection.Areas.Count, , "Maselection : " & MaSelection.Address
Debug.Print "Columns.count =" & MaSelection.Columns.Count _
& " Areas count = " & MaSelection.Areas.Count & " Maselection : " & MaSelection.Address
 
Set MaSelection2 = Range("$B$9:$C$10")
MsgBox "Columns.count =" & MaSelection2.Columns.Count _
& vbCr & "Areas count = " & MaSelection2.Areas.Count, , "Maselection2 : " & MaSelection2.Address
Debug.Print "Columns.count =" & MaSelection2.Columns.Count _
& " Areas count = " & MaSelection2.Areas.Count & " Maselection 2: " & MaSelection2.Address
 
 
Set MaSelection2 = Union(Range("B9"), Range("C10"))
MsgBox "Columns.count =" & MaSelection2.Columns.Count _
& vbCr & "Areas count = " & MaSelection2.Areas.Count, , "Maselection2 : " & MaSelection2.Address
Debug.Print "Columns.count =" & MaSelection2.Columns.Count _
& " Areas count = " & MaSelection2.Areas.Count & " Maselection 2: " & MaSelection2.Address
 
End Sub

donne

Columns.count =1 Areas count = 5 Maselection : $G$9,$I$6,$I$13,$K$14,$L$7 alors que j'ai 4 colonnes distinctes

Columns.count =2 Areas count = 1 Maselection 2: $B$9:$C$10
Columns.count =1 Areas count = 2 Maselection 2: $B$9,$C$10

Quelqu'un a-t-il une méthode "globale" ?

Je me répond avec une fonction que je viens de créer mais si quelqu'un a une autre méthode ...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Function NbcolDistinctes(maselection As Range) As Integer
    Dim nbcol As Integer
    Dim MonDico_Ou As Object
    nbcol = 0
    Set MonDico_Ou = CreateObject("Scripting.Dictionary")
    MonDico_Ou.CompareMode = vbTextCompare
    For a = 1 To maselection.Areas.Count
        For Each Macol In maselection.Areas(a).Columns
            If Not MonDico_Ou.Exists(Macol.Column) Then MonDico_Ou.Add Macol.Column, Macol.Column
            nbcol = nbcol + maselection.Areas(a).Columns.Count
        Next Macol
    Next a
    NbcolDistinctes = MonDico_Ou.Count
End Function

J'étais parti sur un tableau...
Code:

1 2 3 4 5 Set MaSelection = Union(Range("g9"), Range("i6"), Range("i13"), Range("k14"), Range("l7")) For Each c In MaSelection.Cells tablo(i) = c.Column i = i + 1 Next c
Il suffit de trouver le nombre d'élements distincts dans le tableau..

Bonjour,

Une autre piste avec une fonction employant les Collections

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub nbColonnesLignes()
Dim MaSelection As Range
Dim MaSelection2 As Range
'---
Set MaSelection = Union(Range("g9"), Range("i6"), Range("i13"), Range("k14"), Range("l7"))
MaSelection.Interior.Color = 10498160
MsgBox "Columns.count =" & RangeColumsOrRowsCount(MaSelection, xlByColumns) & vbCrLf & _
      "Rows.count =" & RangeColumsOrRowsCount(MaSelection, xlByRows)
'---
Set MaSelection2 = Range("$B$9:$C$10,b13,e20")
MaSelection2.Interior.Color = vbBlue
MsgBox "Columns.count =" & RangeColumsOrRowsCount(MaSelection2, xlByColumns) & vbCrLf & _
      "Rows.count =" & RangeColumsOrRowsCount(MaSelection2, xlByRows)
End Sub
 
Function RangeColumsOrRowsCount(Plage As Range, Sens As XlSearchOrder) As Long
Dim collRows As New Collection
Dim collColumns As New Collection
Dim C As Range
Dim A$
Dim B$
'---
On Error Resume Next
Set Plage = Plage.Offset(1, 1)
For Each C In Plage
  A$ = C.Address(False, False, xlR1C1, Range("a1"))
  '--- Lignes ---
  B$ = CStr(Mid(A$, 2, InStr(1, A$, "]") - 1))
  collRows.Add B$, B$
  '--- Colonnes ---
  B$ = CStr(Mid(A$, InStrRev(A$, "[")))
  collColumns.Add B$, B$
Next C
On Error GoTo 0
'---
If Sens = xlByColumns Then
  RangeColumsOrRowsCount = collColumns.Count
ElseIf Sens = xlByRows Then
  RangeColumsOrRowsCount = collRows.Count
End If
End Function

Je ne vois pas quel usage on peut en tirer ???
Merci de m'éclairer sur ce point.

Bonne journée et à plus.

16/11/2013, 18h46
ctac_

Bonjours,
1 petite copie de l'aide.
Cordialement
Ctac

Citation:

Référence du développeur Excel
Range.Columns, propriété
Cette propriété renvoie un objet Range qui représente les colonnes figurant dans la plage spécifiée.
Syntaxe

expression.Columns

expression Variable qui représente un objet Range.

Remarques

L'utilisation de cette propriété sans qualificateur d'objet correspond à celle de ActiveSheet.Columns.

Lorsqu'elle est appliquée à un objet Range constituant une sélection à zones multiples, cette propriété renvoie des colonnes uniquement à partir de la première zone de la plage. Par exemple, si l'objet Range possède deux zones — A1:B2 et C3:D4 — Selection.Columns.Count renvoie la valeur 2, pas 4. Pour utiliser cette propriété sur une plage susceptible de contenir une sélection à zones multiples, essayez Areas.Count pour déterminer si la plage contient plusieurs zones. Si c'est le cas, effectuez une boucle sur chaque zone de la plage.

Exemple

Cet exemple montre comment affecter la valeur 0 (zéro) à chaque cellule de la colonne 1 dans la plage « myRange ».

Visual Basic pour Applications
Range("myRange").Columns(1).Value = 0

Cet exemple montre comment afficher le nombre de colonnes dans la sélection de la feuille Sheet1. Si plusieurs zones sont sélectionnées, cet exemple montre comment faire une boucle sur chaque zone.

Visual Basic pour Applications
Worksheets("Sheet1").Activate
areaCount = Selection.Areas.Count
If areaCount <= 1 Then
MsgBox "The selection contains " & _
Selection.Columns.Count & " columns."
Else
For i = 1 To areaCount
MsgBox "Area " & i & " of the selection contains " & _
Selection.Areas(i).Columns.Count & " columns."
Next i
End If
18/11/2013, 14h47
Oliv-

Salut à tous et merci pour vos contributions.

Je n'avais pas pensé à regarder simplement dans l'aide !

Ce qui me rassure c'est que c'est un comportement "normal"
18/11/2013, 18h06
PMO2017

Bonjour,

Je précise que l'exemple de l'aide compte les colonnes qu'occupe chaque cellule de la sélection.
Cas 1 (cellules dans colonnes distinctes) :
Sélection = A1,C1,E1 donnera 3 colonnes.
Cas 2 (avec effet pernicieux) :
Sélection = A1,C1,E1,A3 donnera 4 colonnes alors que la colonne A qui est compté 2 fois ne devrait l'être qu'une seule fois.
****
La piste que je propose dans le message #4 indique le nombre de colonnes (ou de lignes) occupées soit, pour le Cas 2 (avec effet pernicieux), 3 colonnes.
J'avais cru comprendre que c'était cela qui était demandé.
18/11/2013, 20h21
nibledispo

nombre de colonnes

Bonsoir,

La méthode de Engue Engue et celle de l'aide semblent souffrir d'un inconvénient.
Sauf erreur de ma part, si la sélection comprend plusieurs "range" sur une même colonne le résultat n'est pas au rdv.

Cordialement,

Ma participation sur ce sujet

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function ColumnsCount(ByVal Plage As Range) As Integer
Dim Rng As Range, c As Range
 
If Not Plage Is Nothing Then
    For Each c In Plage.Areas
        If Rng Is Nothing Then
            Set Rng = Intersect(c.EntireColumn, Plage.Worksheet.Rows(1))
        Else
            Set Rng = Union(Rng, Intersect(c.EntireColumn, Plage.Worksheet.Rows(1)))
        End If
    Next c
    ColumnsCount = Rng.Count
    Set Rng = Nothing
End If
End Function

19/11/2013, 13h57
Oliv-

Bonjour à tous,
MERCI encore pour vos réponses, effectivement il peut y avoir des colonnes comptées 2 fois avec certaines méthodes.

Trsè intéressante ta méthode Mercatog

Mais je ne sais pas pourquoi mais j'aime bien ma méthode ;-)
19/11/2013, 13h59
EngueEngue

@nible

CF: Il suffit de trouver le nombre d'élements distincts dans le tableau..
19/11/2013, 15h59
nibledispo

nombre de colonnes

Bonjour Engue Engue.

C'est précisément ce que fait le code Mercatog qu'au demeurant je n'ai toujours pas réussi à comprendre.

Je vois bien au pas à pas ce que fait le code mais les lignes de ce code m'échappent encore.

Cordialement,
19/11/2013, 16h03
EngueEngue

Euh... toutes nos méthodes essaient d'arriver au même point donc c'est normal que ce soit exactement la même chose. Sauf que la méthode n'est pas du tout la même. Mercatog joue sur les propriétes des ensembles. Union et intersection (ce qui est brillant) alors que moi j'ai rempli bêtement un tableau, évincé les doublons et compter le nombre d'éléments.
19/11/2013, 16h09
mercatog

Citation:

Envoyé par nibledispo

Je vois bien au pas à pas ce que fait le code mais les lignes de ce code m'échappent encore.

Tu fais une projection (orthogonale) des plages sur la première ligne de la feuille. ça fait longtemps la géométrie ;). Tu obtiendras des cellules que tu vas compter en fin de compte.

Je rejoins Eugene. Tous les chemins mènent à Rome du moment où la logique était cernée.