[VBA-A]impossible de supp car tables comprends enr. connexes

Version imprimable

29/04/2006, 15h03
eultartuffe

[Résolu][VBA-A]impossible de supp car tables comprends enr. connexes

Bonjour tout le monde!
Bah j'ai à peu près tout dit. En fait j'ai un formulaire et je ne peux pa supprimer des enregistrements car il y a l'intégrité référentielle. Et donc quand je veux supprimer un enregistrement, le message d'erreur apparaît (et c'est normal) mais j'aimerais savoir si au lieu d'avoir un message comme ça (accompagné d'un plantage en plus!) on pourrait pas informer l'utilisateur par un Msgbox lui informant que cet enregistrement est requis dans une autre table.
Je vous remercie d'avances
Bonne après midi
29/04/2006, 15h08
eultartuffe

en fait quand je veux supprimer l'enregistrement dans ma table, il y a le message d'erreur "impossible de supprimer ou de modifier l'enregistrement car la table 'Assemblage' comprend des enregistrements connexes (erreur d'éxécution 3200" + plantage
J'aimerais juste savoir si on peut juste afficher un message perso à la place
29/04/2006, 15h23
zephyr59

Salut,

En effectuant un test de présence dans la table connexe, tu peux être en mesure de savoir s'il faut exécuter la requete de suppression ou emettre une message d'avertissement.
29/04/2006, 18h52
jmfmarques

Ou gérer les erreurs !
30/04/2006, 10h38
eultartuffe
Daccord merci beaucoup!
Mais comment effectuer un test de présence dans la table connexe (en ouvrant un autre RecordSet?)
Merci

J'ai regardé dans la FAQ et j'ai trouvé ça:

select case err.number
case 3200
msgbox....

Mais justement pour tester le numéro d'erreur d'Access, il faut que l'erreur se produise et donc je l'aurai toujours automatiquement avec un plantage? :
Code:

1 2 3 4 Rs.Delete Select Case Error(errornumber) Case 3200 MsgBox "erreur"
Ici l'erreur se produit au Delete et me renvoie donc direct le message d'erreur d'Access...Quelqu'un pourrait m'expliquer?
Merci
30/04/2006, 14h21
AlainTech

Code:

On Error Resume Next

Juste avant ton Rs.Delete

Daccord, merci pour vos réponses :) mais je ne vois pas à quoi sert le résume next car il saute juste l'instruction et l'utilisateur ne sait donc pas si l'enregistrement a été effacé ou pas...(puisqu'il n'y a pas de 'GoTo')

Voici le code de mon bouton Supprimer :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Private Sub btnSupprimer_Click()
  If Rs.RecordCount <> 0 Then
    On Error GoTo Erreur
    Dim intReponse As Integer
    intReponse = MsgBox("Voulez-vous vraiment effacer l'enregistrement?", _
             vbYesNo, "Suppression")
    ' Si l'utilisateur confirme la suppression
    If intReponse = vbYes Then
      Select Case Rs.AbsolutePosition + 1
        Case Is < Rs.RecordCount
          Rs.Delete
          Rs.MoveNext
          Call P_Liaison(Rs)
        Case Rs.RecordCount
          If Rs.RecordCount = 1 Then
            Rs.Delete
            compRef.Value = ""
            compNom.Value = ""
            compPrixAchatHT.Value = ""
            compPrixVenteHT.Value = ""
            categNum.Value = ""
            fourNum.Value = ""
            MsgBox "Il n'y a plus d'enregistrement dans cette table"
          Else
            Rs.Delete
            Rs.MovePrevious
            Call P_Liaison(Rs)
          End If
      End Select
      txtCourant.Value = Rs.AbsolutePosition + 1 & " sur " & Rs.RecordCount
    End If
Erreur: MsgBox "Cet enregistrement ne peut pas être supprimé" & _
          vbNewLine & "car il est utilisé dans la table 'Assemblage'"
  Else
    MsgBox ("Il n'y a pas d'enregistrement à supprimer")
  End If
End Sub

J'ai mis GoTo au début mais le problème c'est que MÊME si l'enregistrement est supprimé il me met le message d'erreur que j'ai mis dans 'Erreur'

Evidemment, si tu changes ton code en cours de route, on n'en sortira pas.

Soit tu gères ton erreur dans la ligne qui suit ton Delete, soit tu mets ta gestion d'erreur à la fin de ton code.
Mais pas un mix des 2!

Je te propose:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub btnSupprimer_Click()
  Dim intReponse As Integer
  On Error GoTo Erreur
  If Rs.RecordCount <> 0 Then
    intReponse = MsgBox("Voulez-vous vraiment effacer l'enregistrement?", _
             vbYesNo, "Suppression")
    ' Si l'utilisateur confirme la suppression
    If intReponse = vbYes Then
      Select Case Rs.AbsolutePosition + 1
        Case Is < Rs.RecordCount
          Rs.Delete
          Rs.MoveNext
          Call P_Liaison(Rs)
        Case Rs.RecordCount
          If Rs.RecordCount = 1 Then
            Rs.Delete
            compRef.Value = ""
            compNom.Value = ""
            compPrixAchatHT.Value = ""
            compPrixVenteHT.Value = ""
            categNum.Value = ""
            fourNum.Value = ""
            MsgBox "Il n'y a plus d'enregistrement dans cette table"
          Else
            Rs.Delete
            Rs.MovePrevious
            Call P_Liaison(Rs)
          End If
      End Select
      txtCourant.Value = Rs.AbsolutePosition + 1 & " sur " & Rs.RecordCount
    End If
  Else
    MsgBox ("Il n'y a pas d'enregistrement à supprimer")
  End If
  Exit Sub ' <-- IMPORTANT
Erreur: MsgBox "Cet enregistrement ne peut pas être supprimé" & _
          vbNewLine & "car il est utilisé dans la table 'Assemblage'"
End Sub

Ou alors:

Code:

1
2
3
4
5
6
7
On Error Resume Next
Rs.Delete
Select Case Error(errornumber)
  Case 3200
    MsgBox "erreur"
Err.Clear
On Error GoTo 0

01/05/2006, 20h35
eultartuffe

Merci beaucoup ça marche très bien! J'ai pris la première solution car elle me parait plus simple. Encore merci et bonne soirée ;)