Appeler fonction vbs depuis le code

Version imprimable

26/09/2013, 11h45
kstou2001

Appeler fonction vbs depuis le code

Bonjour,

Je ne sais pas si c'est faisable mais je me lance.

J'ai mon appli vbnet. A l'intérieure, j'ai ajouté un fichier vbs (j'utilise sharp develop)

Au moment du clic sur un bouton, j'aimerais lancer une fonction de mon vbs intégré.

Est-ce possible car pour le moment je ne vois pas?

merci d'avance.
26/09/2013, 14h07
tomlev

Citation:

Envoyé par kstou2001

J'ai mon appli vbnet. A l'intérieure, j'ai ajouté un fichier vbs (j'utilise sharp develop)

Pourquoi faire ? Il y a quelque chose dans ce VBS que tu ne pourrais pas faire directement en VB.NET ?
26/09/2013, 15h14
kstou2001

mon vbs modifie une section d'un fichier ini en fonction du bouton radio selectionné (les valeurs ne seront pas les même).

A moins d'avoir quelque chose de tout prêt, ça m’ennuierait de réinventer la roue.
26/09/2013, 15h32
tomlev

Citation:

Envoyé par kstou2001

mon vbs modifie une section d'un fichier ini en fonction du bouton radio selectionné (les valeurs ne seront pas les même).

A moins d'avoir quelque chose de tout prêt, ça m’ennuierait de réinventer la roue.

Bah y a pas à réinventer la roue... il suffit d'adapter ton code VBS en VB.NET, ça devrait pas être bien compliqué. C'est bien de vouloir réutiliser le code existant, mais si c'est au prix d'un bricolage monstrueux, ça vaut pas le coup...
26/09/2013, 16h49
kstou2001

C'est pour cela que je demandais si c'était faisable avant de me lancer dans l'adaptation de mon code existant
26/09/2013, 21h48
wallace1

Citation:

Envoyé par kstou2001

C'est pour cela que je demandais si c'était faisable avant de me lancer dans l'adaptation de mon code existant

Bonsoir kstou2001,

Envoie ton code vbs, c'est tout à fait adaptable en VbNet ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
 
Function GetFile(ByVal FileName)
  Dim FS: Set FS = CreateObject("Scripting.FileSystemObject")
  'Go To windows folder If full path Not specified.
  If InStr(FileName, ":\") = 0 And Left (FileName,2)<>"\\" Then
    FileName = FS.GetSpecialFolder(0) & "\" & FileName
  End If
  On Error Resume Next
 
  GetFile = FS.OpenTextFile(FileName).ReadAll
End Function 
 
'Separates one field between sStart And sEnd
Function SeparateField(ByVal sFrom, ByVal sStart, ByVal sEnd)
  Dim PosB: PosB = InStr(1, sFrom, sStart, 1)
  If PosB > 0 Then
    PosB = PosB + Len(sStart)
    Dim PosE: PosE = InStr(PosB, sFrom, sEnd, 1)
    If PosE = 0 Then PosE = InStr(PosB, sFrom, vbCrLf, 1)
    If PosE = 0 Then PosE = Len(sFrom) + 1
    SeparateField = Mid(sFrom, PosB, PosE - PosB)
  End If
End Function
 
Function GetINIString(Section, KeyName, Default, FileName)
  Dim INIContents, PosSection, PosEndSection, sContents, Value, Found
 
  'Get contents of the INI file As a string
  INIContents = GetFile(FileName)
 
  'Find section
  PosSection = InStr(1, INIContents, "[" & Section & "]", vbTextCompare)
  If PosSection>0 Then
    'Section exists. Find end of section
    PosEndSection = InStr(PosSection, INIContents, vbCrLf & "[")
    '?Is this last section?
    If PosEndSection = 0 Then PosEndSection = Len(INIContents)+1
 
    'Separate section contents
    sContents = Mid(INIContents, PosSection, PosEndSection - PosSection)
 
    If InStr(1, sContents, vbCrLf & KeyName & "=", vbTextCompare)>0 Then
      Found = True
      'Separate value of a key.
      Value = SeparateField(sContents, vbCrLf & KeyName & "=", vbCrLf)
    End If
  End If
  If isempty(Found) Then Value = Default
  GetINIString = Value
End Function
 
Function WriteFile(ByVal FileName, ByVal Contents)
 
  Dim FS: Set FS = CreateObject("Scripting.FileSystemObject")
  'On Error Resume Next
 
  'Go To windows folder If full path Not specified.
  If InStr(FileName, ":\") = 0 And Left (FileName,2)<>"\\" Then
    FileName = FS.GetSpecialFolder(0) & "\" & FileName
  End If
 
  Dim OutStream: Set OutStream = FS.OpenTextFile(FileName, 2, True)
  OutStream.Write Contents
End Function 
 
Sub WriteINIString(Section, KeyName, Value, FileName)
  Dim INIContents, PosSection, PosEndSection
 
  'Get contents of the INI file As a string
  INIContents = GetFile(FileName)
 
  'Find section
  PosSection = InStr(1, INIContents, "[" & Section & "]", vbTextCompare)
  If PosSection>0 Then
    'Section exists. Find end of section
    PosEndSection = InStr(PosSection, INIContents, vbCrLf & "[")
    '?Is this last section?
    If PosEndSection = 0 Then PosEndSection = Len(INIContents)+1
 
    'Separate section contents
    Dim OldsContents, NewsContents, Line
    Dim sKeyName, Found
    OldsContents = Mid(INIContents, PosSection, PosEndSection - PosSection)
    OldsContents = split(OldsContents, vbCrLf)
 
    'Temp variable To find a Key
    sKeyName = LCase(KeyName & "=")
 
    'Enumerate section lines
    For Each Line In OldsContents
      If LCase(Left(Line, Len(sKeyName))) = sKeyName Then
        Line = KeyName & "=" & Value
        Found = True
      End If
      NewsContents = NewsContents & Line & vbCrLf
    Next
 
    If isempty(Found) Then
      'key Not found - add it at the end of section
      NewsContents = NewsContents & KeyName & "=" & Value
    Else
      'remove last vbCrLf - the vbCrLf is at PosEndSection
      NewsContents = Left(NewsContents, Len(NewsContents) - 2)
    End If
 
    'Combine pre-section, new section And post-section data.
    INIContents = Left(INIContents, PosSection-1) & NewsContents & Mid(INIContents, PosEndSection)
  else'if PosSection>0 Then
    'Section Not found. Add section data at the end of file contents.
    If Right(INIContents, 2) <> vbCrLf And Len(INIContents)>0 Then
      INIContents = INIContents & vbCrLf
    End If
    INIContents = INIContents & "[" & Section & "]" & vbCrLf & KeyName & "=" & Value
  end if'if PosSection>0 Then
  WriteFile FileName, INIContents
End Sub

27/09/2013, 09h07
tomlev

A mon avis tu peux copier coller ça dans un fichier .vb, et ça devrait compiler quasiment sans modification... Après bien sûr ce n'est pas exactement la façon dont on le ferait "nativement" en VB.NET, mais l'essentiel doit être compatible.
27/09/2013, 09h26
wallace1

Bonjour kstou2001,

Il ne faut pas reinventer la roue donc voila en vbNet un module de gestion de fichiers .ini :

http://www.developpez.net/forums/d11...i/#post7472174

C est a toi maintenant d implémenter le code afin de renseigner tes données lorsque l'utilisateur sélectionne tel ou tel RadioButton depuis le gestionnaire d événements CheckedChanged de tes radiobutton
27/09/2013, 10h11
kstou2001

Super ce code.
Par contre j'ai une erreur Fin d'instruction attendue et une erreur Expression attendue (BC30201)
sur la ligne:
Selected = Encoding.ASCII.GetString(bytes, 0, size - (If(size > 0, 1, 0)))
27/09/2013, 11h49
wallace1

Postes l intégralité de ton gestionnaire d évènements car présenté ainsi, on ne voit pas ce que tu tentes de faire et a quel endroit.......??
27/09/2013, 14h25
kstou2001

j'ai juste fais un copier/coller de la classe et au moment de compiler, erreur...
27/09/2013, 14h57
wallace1

Citation:

Envoyé par kstou2001

j'ai juste fais un copier/coller de la classe et au moment de compiler, erreur...

Que compiles-tu exactement ???
Ton application est-elle de type Windows Form ou Console ???
Fais une capture de ton écran.... (voilà mon screen au cas ou..... http://imabox.fr/a2/1327091459QOuiaE55.jpeg)