Macro pour répéter une formule

Version imprimable

Bonjour à tous,
Je cherche à modifier une macro enregistrée. Dans celle-ci, on trouve une formule qui est répétée sur une plage de cellule défini. Hors, je souhaiterai que la formule soit répétée sur une plage qui serait défini en fonction des données d'une autre plage.

exemple :
on a des données en colonne C, la formule est en colonne E. On répète la formule en colonne E, jusqu'à la dernière cellule non vide en colonne C.

Voir ci-dessous le code créé par la macro enregistrée :
Code:

1 2 3 4 5 6 7 8 9 10 11 Range("B1").Select Range(Selection, Selection.End(xlDown)).Select Selection.TextToColumns Destination:=Range("C1"), DataType:=xlDelimited, _ TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=True, Tab:=False, _ Semicolon:=False, Comma:=False, Space:=True, Other:=False, FieldInfo _ :=Array(Array(1, 1), Array(2, 1)), TrailingMinusNumbers:=True Range("E1").Select ActiveCell.FormulaR1C1 = "=IF(RC3<>"""", RC2&""-""&RC3,RC2)" Range("E1").Select Selection.AutoFill Destination:=Range("E1:E21"), Type:=xlFillDefault Range("F1").Select
En gras ci-dessus, on trouve la ligne, qui je pense doit être modifiée.

Je vous remercie par avance pour votre aide.

Cordialement,
NoodleDS

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Test()
Dim LastLig As Long
 
With Worksheets("Feuil1")                 'A adapter
    LastLig = .Cells(.Rows.Count, 2).End(xlUp).Row
    .Range("B1:B" & LastLig).TextToColumns Destination:=.Range("C1"), _
        DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
        ConsecutiveDelimiter:=True, Tab:=False, Semicolon:=False, Comma:=False, _
        Space:=True, Other:=False, FieldInfo:=Array(Array(1, 1), Array(2, 1)), _
        TrailingMinusNumbers:=True
    .Range("E1:E" & LastLig).FormulaR1C1 = "=IF(RC3<>"""", RC2&""-""&RC3,RC2)"
End With
End Sub

10/07/2013, 00h14
NoodleDS

Bonjour,
mercatog, je te remercie pour ta réponse qui après quelques adaptations, fonctionnent parfaitement.

Cordialement,
NoodleDS