Y a t il plus simple.

Version imprimable

Bonjour à tous.
Pour une fois c'est à mon tour de poser une question.

J'ai créer une fonction de suppression qui supprime une feuille et une ligne dans lui faisant référence dans la première feuille du classeur.
Dans la première ligne de référence j'ai un bouton qui me permet d'aller directement a cette feuille que je dois donc également supprimer.
Je ne connais pas le nom du bouton puisque lui même est généré par code vba.

J'ai réussi a faire un code qui me permet bien de supprimer le bouton puis la ligne. Et qui fonctionne mais je me demande si il n'y as pas plus facile de pointer le bon bouton a supprimer.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 Private Sub BnSupprimer_Click() Sheets(CBPostes.Value).Visible = True Sheets(CBPostes.Value).Unprotect Sheets(CBPostes.Value).Delete Dim derniereLigne As Integer derniereLigne = Sheets(NomFeuillePrincipale).Range("A" & Rows.Count).End(xlUp).Row Dim X As Integer Dim Dico Set Dico = CreateObject("Scripting.Dictionary") For X = 5 To derniereLigne If Sheets(NomFeuillePrincipale).Range("A" & X).Value = CBPostes.Value Then Sheets(NomFeuillePrincipale).Unprotect Dim shp As Variant For Each shp In ActiveWorkbook.Sheets(NomFeuillePrincipale).Shapes If Not Dico.exist(shp.TopLeftCell.Row) Then Dico.Add shp.TopLeftCell.Row, shp.Name End If Next Sheets(NomFeuillePrincipale).Shapes(Dico.Item(X)).Delete Sheets(NomFeuillePrincipale).Rows(X).Delete Sheets(NomFeuillePrincipale).Protect Exit For End If Next End Sub
C'est juste histoire d'optimiser. :ccool:

12/06/2013, 11h12
mercatog

Quand tu crée les boutons par code, donne leur un nom significatif et unique.
A la suppression, tu ira directement vers le bouton en question.
12/06/2013, 11h19
Ashireon

Oui aprés c'est clair que le plus simple est de supprimer un shape en connaissant son nom. Mais je me demander si il y avait un moyen de supprimer sans connaitre le nom en pointant par son range ou autre car cela est connu...
Mais je pense que c'est le meilleur moyen sinon ...

Il faudra passer par une boucle

Exemple: On supprime les Shapes et lignes dont la cellule de la colonne A contient la valeur X

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Test()
Dim Shp As Shape
 
With Worksheets("Feuil1")
    For Each Shp In .Shapes
        If .Range("A" & Shp.TopLeftCell.Row) = "X" Then
            Shp.TopLeftCell.EntireRow.Delete
            Shp.Delete
            Exit For
        End If
    Next Shp
End With
End Sub

Ok j'ai modifié selon ton idée ca fonctionne trés bien ca me fait le dico en moins pour recup les noms des shapes a generé

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub BnSupprimer_Click()
Sheets(CBPostes.Value).Visible = True
Sheets(CBPostes.Value).Unprotect
Sheets(CBPostes.Value).Delete
Dim derniereLigne As Integer
derniereLigne = Sheets(NomFeuillePrincipale).Range("A" & Rows.Count).End(xlUp).Row
Dim X As Integer
For X = 5 To derniereLigne
    If Sheets(NomFeuillePrincipale).Range("A" & X).Value = CBPostes.Value Then
        Sheets(NomFeuillePrincipale).Unprotect
            Dim shp As Shape
                For Each shp In ActiveWorkbook.Sheets(NomFeuillePrincipale).Shapes
                    If shp.TopLeftCell.Row = X Then
                        shp.Delete
                        Exit For
                    End If
                Next
 
        Sheets(NomFeuillePrincipale).Rows(X).Delete
        Sheets(NomFeuillePrincipale).Protect
        Exit For
    End If
Next
 
End Sub

Je mets en resolu

Non,; tu n'as pas compris le code. 1 seule boucle suffit et personnellement je ferai comme ceci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub BnSupprimer_Click()
Dim CBP As String
Dim Shp As Shape
 
Application.ScreenUpdating = False
If CBPostes.Value <> "" Then
 
    CBP = CBPostes.Value
    Application.DisplayAlerts = False
    On Error Resume Next
    Worksheets(CBP).Delete
    On Error GoTo 0
    Application.DisplayAlerts = True
 
    With Worksheets(NomFeuillePrincipale)
        For Each Shp In .Shapes
            If .Range("A" & Shp.TopLeftCell.Row) = CBP Then
                Shp.TopLeftCell.EntireRow.Delete
                On Error Resume Next
                Shp.Delete
                On Error GoTo 0
                Exit For
            End If
        Next Shp
    End With
End If
End Sub

12/06/2013, 13h20
Ashireon

Ok donc tu scannes tous les shapes tu recuperes leur numeros de lignes tu vérifies en une fois si le texte correspond a la combo et.. dans ce cas tu supprime la ligne. Pour moi j'ai compris ton code. Je voulais juste eviter de récupérer par un dico. Je te remercie cela me permet de voir autrement que ce que je fait car je suis encore au stade de la demmerde je dirai mais on apprends vite sur ce forum. :-)
12/06/2013, 16h02
Marc-L

Bonjour,

il y a une autre solution pour récupérer le nom d'un objet appelant la procédure, voir l'aide de la propriété Caller …

_______________________________________________________________________________

Merci de cliquer sur :plusser: pour chaque message ayant aidé puis sur :resolu: pour clore cette discussion …
12/06/2013, 16h47
Ashireon

Hello,

Pour ce qui concerne application.caller c'est quand tu cliques sur le dis bouton .. La ce n'est pas le cas.

LE bouton qui me lance la suppression d'un poste ( soit d'une ligne avec mon bouton d'appel de la feuille , et la feuille elle même ) se trouve dans les compléments donc n'a absolument rien a voir avec le bouton recherché à supprimer.:aie: