Copier des données dans Excel et les Coller dans Word.

Version imprimable

17/05/2013, 17h39
graphikris

Copier des données dans Excel et les Coller dans Word.

Bonjour,

Je cherche une macro me permettant de copier des données (pourcentages calcul grace à une formule) puis de coller le résultat (collage spécial) à un endroit bien précis dans une lettre faite avec Word.

Ex : Dans Excel => De A1:A100, j'inscris aléatoirement "OUI" ou "NON"
En A101 :

Code:

=NB.SI(A1:A100;"oui")/100

Format de cellule : Pourcentage.

Ce qui me calcule le pourcentage de "OUI" par rapport au "NON", par exemple : 64%

Ensuite, la macro doit ouvrir une lettre type déjà tapée sur Word et à un endroit précis du texte de cette lettre, le résultat doit venir se coller.

Ex : Dans Word => Monsieur XXXX, veuillez constater que le pourcentage de "OUI" s'élève à 64% pour le mois d'octobre 2012.

Quelqu'un saurait il me dépatouiller de cette galère ?

Cordialement,
Graphikris.

Salut graphikris ;)

Voici un code que j'utilise au boulot, à adapter

Il faut activer la référence "Microsoft Word xx.x Object Library"

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
  ' Chemin d'accès du document Word
  VPath = ThisWorkbook.Path & "\"
  ' Nom du fichier
  VFic = "fichier_modele.doc"
  ' Créer une instance de Word
  Set AppWd = New Word.Application
  ' Ouvrir le fichier et Afficher l'application
  AppWd.Documents.Open VPath & VFic
  AppWd.Visible = True
  Set WdDoc = AppWd.ActiveDocument
  ' Se positionner sur la balise <TABLEAU> qui est inscrite dans le document Word
  With AppWd.Selection.Find
    .ClearFormatting
    .Text = "<TABLEAU>"
    .MatchWildcards = False
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindContinue
  End With
  AppWd.Selection.Find.Execute
  ' Copier le tableau de la feuille "Rappels" dans excel
  With Sheets("Rappels")
    DLigR = .Range("F" & Rows.Count).End(xlUp).Row
    .Range("A1:F" & DLigR).Copy
    ' Le coller dans Word
    AppWd.Selection.Paste
  End With

J'espère que ce code sera assez explicite

A+

18/05/2013, 17h51
graphikris

Bjr et merci,
je vais essayé de bidouiller ton code afin de l'adapter à ce que je veux faire.
Je te tiens au courant (abonnes toi à la discussion de mon post).

Cordialement
Graphikris.

N'arrivant pas à adapter ce code aimablement envoyé, je recherche a nouveau quelqu'un qui saurait faire car dans le code transmis, c'est pour coller un tableau mais pour mon post, c'est des chiffres à différents endroits dans le fichier Word.
Si vous désirez que je vous transmette les 2 fichiers (excel et word), demandez le moi.

Cordialement,
Graphikris.

Désolé,

Je ne l'avais pas compris ainsi

Tu peux donc utiliser ceci à la place

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
' Chemin d'accès du document Word
  VPath = ThisWorkbook.Path & "\"
  ' Nom du fichier
  VFic = "fichier_modele.doc"
  ' Créer une instance de Word
  Set AppWd = New Word.Application
  ' Ouvrir le fichier et Afficher l'application
  AppWd.Documents.Open VPath & VFic
  AppWd.Visible = True
  Set WdDoc = AppWd.ActiveDocument
  ' Inscrire la valeur à la place de la balise <POURCENTAGE>
  VTemp = Format(Range("A1"),"0.00%")
  Ecriture_balise "POURCENTAGE", VTemp

La Sub d'écriture

Code:

1
2
3
4
5
6
7
'Sélection et remplacement de toutes les balises du modèle word associées à la ligne par la chaîne de caractères associée
Sub Ecriture_balise(LibBalise As String, ValBalise As String)
  Dim Balise As String
  Balise = "<" & LibBalise & ">"
  ' Remplacement de "<Balise>" par "Valeur_balise" dans le document
  WdDoc.Content.Find.Execute FindText:=Balise, ReplaceWith:=ValBalise, Replace:=wdReplaceAll  'Remplacement"
End Sub

A+

18/05/2013, 18h54
graphikris

Merci,
mais c'est quoi la Sub écriture ?
Je place où les modules ?
Excel, Word ?

Cordialement
18/05/2013, 19h16
Invité

Whouaouuuu, indique le dans ta signature que tu es débutant :?

Dans un MODULE
Tu crées un Sub Toto()
Dans laquelle tu mets le premier code
Ensuite tu copie et colles la sub écriture à la fin du même module

Dans ton modèle Word tu mets les balises souhaitées en écrivant entre "<" & ">" le nom de la balise

Tu n'as plus qu'à lancer le code de la première sub

a+
18/05/2013, 19h39
graphikris

Ok merci, juste une chose dans word pour la balise, si j'ai bien compris, je fais un truc du genre :

Monsieur,
le chiffre du mois précédent est <X>%
le chiffre de ce mois est <Y>%

mais comment je fais dans la macro pour que par exemple, si c'est la cellule B8 de la feuil1 qui correspond à X et la cellule D3 qui correspond à Y ?

Cordialement,
Graphikris.
18/05/2013, 20h07
Invité

1 pièce(s) jointe(s)

Re,

Je ne le fais pas en général, mais un exemple sera plus parlant ;)

A+

Bonjour,

Regarde avec ce qui suit et adapte. Il faut que tu crée un signet dans ton document Word appelé "Pourcent" (tu surligne "s'élève à" puis Insertion > Signet "Pourcent" > Ajouter), le pourcentage sera inséré juste après lui. Dans mon exemple, il te faut adapter le chemin du document Word (ici, "D:\Test.doc") :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 Sub ExcelVersWord() Dim AppWord As Word.Application Dim Doc As Word.Document 'crée une instance de Word Set AppWord = CreateObject("Word.Application") With AppWord 'la rend visible .Visible = True 'ouvre un document Set Doc = .Documents.Open("D:\Test.doc") With Doc 'insère le texte après le signet .Bookmarks("Pourcent").Range.InsertAfter " " & Format(Range("A101"), "0.00%") End With End With End Sub
Hervé.

Ah, J'ai oublié de te dire qu'il te faut cocher la référence à Word : Outils > Références > "Microsoft Word xx.x Object Library", xx.x étant la version que tu possède.

Hervé.

21/05/2013, 18h14
graphikris

Bonjour Theze,

Ton code marche à merveille, reste une question que je n'arrive pas à résoudre.
Il faudrait qu'une fois le fichier word ouvert avec les données collées au bon endroit, que je puisse imprimer le document et qu'à l'issue les données collées soient supprimées pour éviter que lorsque je redéclenche la macro le mois suivant les données précédentes soient toujours là.
En fait après l'impression, le fichier Word devrait se fermer automatiquement sans enregistrer les modif.

Cordialement
Graphikris.

Bonsoir,

Essai avec ceci, ça devrait convenir :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Sub ExcelVersWord()
 
    Dim AppWord As Word.Application
    Dim Doc As Word.Document
 
    'crée une instance de Word
    Set AppWord = CreateObject("Word.Application")
 
    With AppWord
 
        'la rend visible
        .Visible = True
 
        'ouvre un document
        Set Doc = .Documents.Open("D:\Test.doc")
 
        With Doc
 
            'insère le texte après le signet
            .Bookmarks("Pourcent").Range.InsertAfter " " & Format(Range("A101"), "0.00%")
 
            'impression
            .PrintOut
 
            'aperçu avant impression
            '.PrintPreview
 
        End With
 
        'quitte l'application sans enregistrer
        .Quit False
 
    End With
 
End Sub

Hervé.

24/05/2013, 18h00
graphikris

Bjr Theze,

çà fonctionne bien mais lorsque le fichier Word se ferme, il me demande de l'enregistrer en : normal.dot car il me dit que le fichier est ouvert par une autre application (je suppose que c'est la macro) ! ! !

Cordialement,
Graphikris.

Bonjour,

Essai de mettre la ligne suivante après l'impression :

Code:

1
2
 
.Saved = True

Ceci indique au compilateur que le document n'a été modifié depuis sa dernière ouverture.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Sub ExcelVersWord()
 
    Dim AppWord As Word.Application
    Dim Doc As Word.Document
 
    'crée une instance de Word
    Set AppWord = CreateObject("Word.Application")
 
    With AppWord
 
        'la rend visible
        .Visible = True
 
        'ouvre un document
        Set Doc = .Documents.Open("D:\Test.doc")
 
        With Doc
 
            'insère le texte après le signet
            .Bookmarks("Pourcent").Range.InsertAfter " " & Format(Range("A101"), "0.00%")
 
            'impression
            .PrintOut
 
            'aperçu avant impression
            '.PrintPreview
 
            'indique au compilateur que le document n'a pas été modifié
            .Saved = True
 
        End With
 
        'quitte l'application sans enregistrer
        .Quit False
 
    End With
 
End Sub

Hervé.

25/05/2013, 18h31
graphikris

:ccool: Theze

çà fonctionne.