Forcer valeur nulle dans variable

Version imprimable

Bonjour à tous,

Access me dit "utilisation incorrecte de null" à l'éxécution de ce code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Public Sub EnvoyerMailOutlook(Destinataires As String, Objet As String, TxtMessage As String, CC As String, Bcc As String, Optional Attach As Variant)
 
 
 Dim i As Integer
 
        Dim appOutLook As New Outlook.Application
        Dim oEmail As Outlook.MailItem
 
 
    ' Créer un nouvel item mail
 
    Set appOutLook = New Outlook.Application
    Set oEmail = appOutLook.CreateItem(olMailItem)
 
    ' Les paramètres
 
    oEmail.To = Destinataires
    oEmail.Subject = Objet
    oEmail.HTMLBody = TxtMessage
    oEmail.CC = CC & ""
    oEmail.Bcc = Bcc & ""
 
 
    If Not IsMissing(Attach) Then
 
       If TypeName(Attach) = "String" Then
 
             ' S'il y a des pièces jointes
            oEmail.Attachments.Add Attach
 
        Else
 
            For i = 0 To UBound(Attach) - 1
            oEmail.Attachments.Add Attach(i)
 
            Next
 
        End If
 
    End If
 
    ' Montre le message
    oEmail.Display
 
    ' Détruit les références aux objets
    Set oEmail = Nothing
 
    Set appOutLook = Nothing
 
End Sub

Je veux justement qu'il m'accepte les valeurs nulles des champs "Cc" et "Bcc" comment faire ?

Merci

Salut,

Pourquoi ne pas mettre tout simplement :

Code:

1
2
    if Not IsNull(oEmail.CC) then oEmail.CC  = CC
    if Not IsNull(oEmail.Bcc) then oEmail.Bcc = Bcc

@+.

Bonjour,

Les champs CC et BCC peuvent très bien rester vides !
En plus, tu passes des String à ta procédure, donc ton erreur est en amont.

Ca devrait passer avec cette méthode :
Code:

1 2 3 4 5 6 7 strDestinataires = Me!txtDestinataires strObjet = Me!txtObjet strTxtMessage = Me!TxtMessage strCC = Nz(Me!txtCC, "") strBcc = Nz(Me!txtBCC, "") vntAttach = m_vntaFichiersJoints Call EnvoyerMailOutlook(strDestinataires, strObjet, strTxtMessage, strCC, strBcc, vntAttach)
Et puis une petite gestion d'erreurs serait la bienvenue dans ta procédure (qui devrait être une fonction en fait)...

Argy

13/05/2013, 14h12
clickandgo

Merci pour ta réponse mais l'erreur apparaît toujours en utilisant NZ():(
13/05/2013, 14h18
zoom61

Je pense que tu devrais peut-être revoir l'appel de la fonction :

Code:

Call EnvoyerMailOutlook(Destinataires, Objet, TxtMessage, CC, Bcc)

@+.

Modifie en parallèle ton code comme suit et fais-nous un retour :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Private Sub cmdEnvoyer_Click()
'[....]
Dim strMsgErreur                                       As String
 
 
    If EnvoyerMailOutlook(strMsgErreur, Destinataires, Objet, TxtMessage, CC, Bcc) = False Then
        MsgBox "Ooops la boulette : " & vbCrLf & strMsgErreur, vbExclamation
    Else
        MsgBox "C'est parti !", vbInformation
    End If
End Sub
 
Public Function EnvoyerMailOutlook(MsgErreur As String, Destinataires As String, Objet As String, TxtMessage As String, CC As String, Bcc As String, Optional Attach As Variant) As Boolean
'Dim...
'[....]
 
    On Error GoTo ErreurEnvoyerMailOutlook
    'Code
    '[....]
    EnvoyerMailOutlook = True
    On Error GoTo 0
SortirEnvoyerMailOutlook:
    Exit Function
 
ErreurEnvoyerMailOutlook:
    EnvoyerMailOutlook = False
    MsgErreur = "(" & err.Number & ") " & err.Description
    Resume SortirEnvoyerMailOutlook
End Function

Argy

13/05/2013, 21h33
Robert1957

Bonjour clickandgo, zoom61, argyronet,
Je n'ai pas testé mais je crois que:

Code:

Public Sub EnvoyerMailOutlook(Destinataires As String, Objet As String, TxtMessage As String, CC As String, Bcc As String, Optional Attach As Variant)

devrait se lire:

Code:

Public Sub EnvoyerMailOutlook(Destinataires As String, Objet As String, TxtMessage As String, CC As Variant, Bcc As Variant, Optional Attach As Variant)

pour pouvoir passer la valeur null dans le sub ou la fonction. Après les autres solutions. Est-ce la bonne façon?
Bonne journée
13/05/2013, 23h37
clickandgo

Bonjour Robert , ça marche bien on dirait mais n'est ce pas dangereux d'utiliser "variant" ? (je suis quand même en explicit)
14/05/2013, 00h13
Robert1957

Bonjour clickandgo,
Je ne vois pas de problème, mais je demandais quand même à nos 2 experts ce qu'ils en pensaient. Je sais que c'est pas trop bon de véhiculer des nulls mais dans ton cas je crois que c'est la bonne façon. Attend leurs commentaires pour être certain.
Bonne journée
14/05/2013, 06h07
zoom61

Il a raison variant fonctionne. Et ce type de variable est plus complet que string. Donc tu n'as aucune inquiétude à avoir.

@+.
14/05/2013, 10h35
argyronet

Humm, un Variant accepte les NULL c'est la seule différence.
Tu peux tout déclarer en Variant, pas de souci, non seulement ça compilera sans erreur et en plus, tu n'auras un beau code bien fiable qui plantera en toute discrétion sans jamais t'embêter ;o)

Mieux encore, enlève Option Explicit et là, c'est le bonheur assuré.

Dicton : «Ca complie donc y a pas d'erreur»*

Je suis cynique mais pour envoyer un mail dans un script presque identique à celui exposé ici, j'ai toujours usé de paramètres String et si tu as une erreur 94, c'est qu'il y a une erreur en amont, point !
Si tu mets un Variant, tu adoptes alors le mode "Goret" et effectivement ça va marcher(humm, enfin...) mais tu ne sauras pas pourquoi...

Argy
14/05/2013, 12h32
Robert1957

Bonjour clickandgo, zoom61, argyronet,

Citation:

Si tu mets un Variant, tu adoptes alors le mode "Goret" et effectivement ça va marcher(humm, enfin...) mais tu ne sauras pas pourquoi...

Dans ce cas ci on sait pourquoi mais ce que je comprend de ta réponse c'est qu'on devrait plutôt traiter comme ceci:

Code:

...Optional CC As String....

et faire la vérification de la présence ou non ce CC avant de passer les données à la fonction, c'est une meilleur manière de coder, plus rigoureuse.

argyronet est-ce que j'ai bien compris et si tu as le temps peux-tu nous, ou m'expliquer la différence de traiter "Null" avant la fonction plutôt que dans la fonction. Je comprend ton principe mais j'aimerais savoir pourquoi.

Bonne journée
14/05/2013, 16h54
argyronet
Hier, je t'ai proposé dans un exemple code :
Code:

1 2 3 4 [...] strCC = Nz(Me!txtCC, "") strBcc = Nz(Me!txtBCC, "") [...]
Ce qui te permettait de passer un String comme attendu.

En fait, une fonction doit rester générique.
Si tu as une fonction Age() par exemple, tu ne va pas lui coller un InputBox() pour demander la date de naissance du quidam ni vérifier que la date passée est bien une date ; c'est censé être vérifié avant pour afficher un message. Donc une fonction de ce type ne renvoie que l'âge.
Tu lui passes une date de naissance au format Date afin qu'elle opère à la soustraction du type :

Code:

Age= Now-(DateNaissance\365.25)

Si tu passe un Variant qui risque d'être NULL, tu lèves inéluctablement une erreur...94.

Pour Outlook, c'est pareil, tu dois vérifier avant que la fonction soit appelée que tous les éléments minimum sont bien présents. Et que les facultatifs soient ignorés ou bien passés à vbNullString par xemple.

La fonction exécute ce que tu lui demandes avec les paramètres que tu lui passes mais dans la majeure partie des cas, elle ne doit pas effectuer de conversion pour aboutir à tes fins, surtout en ce qui concerne les NULL.

Disons que c'est ma vision des choses. Tous ne l'adoptent pas et puis ces mêmes se disent du moment que ça marche, hummm !!! ;o)

Argy
14/05/2013, 17h19
Robert1957

Bonjour argyronet,

Citation:

En fait, une fonction doit rester générique
Disons que c'est ma vision des choses. Tous ne l'adoptent pas et puis ces mêmes se disent du moment que ça marche, hummm !!! ;o)

Je comprend maintenant mieux ta réponse et je suis d'accord avec ton principe que la fonction ne doit pas faire le test de validité des données. C'est très logique et je ne m'étais pas penché sur le problème avec cette vision.

Bonne journée
14/05/2013, 18h38
clickandgo

Argyronet, j'ai essayé ton exemple mais cela ne marche pas dans ce cas précis, je ne sais pas pourquoi.

Humm, tout dépend comment son déclarées tes variables...

Bon voici un code pseudo complet que tu adaptes en fonction de tes champs :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
 
Option Explicit
 
Private Sub cmdEnvoyer_Click()
Dim strMsgErreur                                       As String
Dim lngErreur                                          As Long
 
Dim strDestinataires                                   As String
Dim strObjet                                           As String
Dim strTxtMessage                                      As String
Dim strCC                                              As String
Dim strBcc                                             As String
Dim vntAttach                                          As Variant
 
Dim blnEnvoyerSansVoir As Boolean
 
    On Error GoTo L_ErrcmdEnvoyer_Click
 
    strDestinataires = Nz(Me!txtDestinataires, "")
    strObjet = Nz(Me!txtObjet, "")
    strTxtMessage = Nz(Me!TxtMessage, "")
    strCC = Nz(Me!txtCC, "")
    strBcc = Nz(Me!txtBCC, "")
    vntAttach = Split(Me.txtAttach, vbNullChar)
 
    blnEnvoyerSansVoir = Nz(Me!chkEnvoyer, False)
 
    If Len(strDestinataires) < 1Then
        Me!txtDestinataires.SetFocus
        Err.Raise 13, "Destinataire requis", "Euh, entre vous et moi, il est pour qui ce message ?"
    End If
    If Len(strObjet) < 1 Then
        Me!txtObjet.SetFocus
        Err.Raise 13, "Object requis", "Avec un objet du message, ça fait plus sérieux, non !"
    End If
    If Len(strTxtMessage) < 1 Then
        Me!TxtMessage.SetFocus
        Err.Raise 13, "Message requis", "Eh ben eh ben..., Vous voulez envoyer un message vide !"
    End If
 
    If EnvoyerMailOutlook(strMsgErreur, strDestinataires, strObjet, strTxtMessage, strCC, strBcc, vntAttach, blnEnvoyerSansVoir) = False Then
        lngErreur = Split(strMsgErreur, " : ")(0)
        Err.Raise lngErreur, "Envoi échoué", "Ooops la boulette : " & vbCrLf & strMsgErreur, vbExclamation
    Else
        MsgBox "C'est parti !", vbInformation
    End If
 
    On Error GoTo 0
L_ExcmdEnvoyer_Click:
    Exit Sub
 
L_ErrcmdEnvoyer_Click:
    MsgBox Err.Description, vbExclamation, Err.Source
    Resume L_ExcmdEnvoyer_Click
End Sub
 
Public Function EnvoyerMailOutlook(MsgErreur As String, Destinataires As String, Objet As String, TxtMessage As String, CC As String, Bcc As String, Optional Attach As Variant, Optional ByVal Envoyer As Boolean = False) As Boolean
Dim appOutLook                                         As Outlook.Application
Dim oEmail                                             As Outlook.MailItem
Dim I                                                  As Integer
 
 
    On Error GoTo L_ErrEnvoyerMailOutlook
    Set appOutLook = New Outlook.Application
    Set oEmail = appOutLook.CreateItem(olMailItem)
    With oEmail
        .To = Destinataires
        .Subject = Objet
        .HTMLBody = TxtMessage
        .CC = CC
        .Bcc = Bcc
        If Not IsMissing(Attach) Then
            If TypeName(Attach) = "String" Then
                .Attachments.Add Attach
            Else
                For I = 0 To UBound(Attach) - 1
                    .Attachments.Add Attach(I)
                Next
            End If
        End If
        If Envoyer Then
            .Send
        Else
            .Display
        End If
    End With
    EnvoyerMailOutlook = True
 
    On Error GoTo 0
L_ExEnvoyerMailOutlook:
    Set appOutLook = Nothing
    Set oEmail = Nothing
    Exit Function
 
L_ErrEnvoyerMailOutlook:
    EnvoyerMailOutlook = False
    MsgErreur = Err.Number & " - " & Err.Description
    Resume L_ExEnvoyerMailOutlook
End Function

Argy

15/05/2013, 13h04
clickandgo

Merci beaucoup Argyronet, en réalité ça marchait, c'est moi qui m'étais trompé ! :cry:

Mais cependant tu m'as inspiré ! ... :)