Créer une feuille par variable

Version imprimable

01/05/2013, 19h31
Belphegor59

Créer une feuille par variable

Bonjour,

J'ai une base de données avec pour chaque ligne :
nom, date de naissance, Variable x, Variable y, Variable z....

Il y a plusieurs lignes avec le même nom et des noms différents.

Je souhaite créer une feuille par nom avec toutes les lignes correspondantes à ce nom dans le même classeur.

Je ne sais pas si je suis très clair..:roll:

Mes connaissances en VBA sont trop faibles, je ne sais pas par quel bout attaquer:oops:

Merci pour votre aide.

Merci d'avance
Amicalement
Jean-François

Bonsoir,

A mettre dans un module

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
 
Sub creer_feuille()
 
Dim cpt_l As Integer, der_lig As Integer, cpt_col As Integer
Dim leNom As String
 
For cpt_l = 1 To Sheets("Feuil1").Range("a" & Rows.Count).End(xlUp).Row
    leNom = Trim(Sheets("Feuil1").Cells(cpt_l, 1))
 
    If feuille_existe(leNom) = False Then 'Si la feuille n'exite pas
        Sheets.Add After:=Sheets(Sheets.Count) 'Ajout d'une feuille
        ActiveSheet.Name = leNom
    End If
 
    'derniere ligne de la feuille créee
    der_lig = Sheets(leNom).Range("a" & Rows.Count).End(xlUp).Row + 1
    Sheets("Feuil1").Activate
    Sheets("Feuil1").Cells(cpt_l, 1).EntireRow.Copy
    Sheets(leNom).Cells(der_lig, 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
 
Next cpt_l
 
End Sub

et la fonction feuille_existe

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
 
 
Function feuille_existe(laFeuille) As Boolean
 
Dim w As Integer
 
feuille_existe = False
 
For w = 1 To Worksheets.Count
    If Sheets(w).Name = laFeuille Then
        feuille_existe = True
        Exit For
    End If
Next w
 
End Function

Cordialement

bonjour,

ça évoque la génération de rapports de TCD vers de nouvelles feuilles.
Est-il vraiment utile de créer une feuille par nom?

voilà un code à tester:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
Option Explicit
 
Sub generer_rapport_Noms()
    Dim nom As String, data As Range, trans As Range
    Dim e As Integer, c As Integer
 
    'précautions
    With Application
        e = .EnableEvents
        c = .Calculation
        .EnableEvents = False
        .ScreenUpdating = False
        .Interactive = False
        .Calculation = xlCalculationManual
    End With
 
    On Error GoTo fin
 
    Sheets.Add 'ajoute une feuille pour les manipulations
    Worksheets("données sources").Range("a1").CurrentRegion.Copy ActiveSheet.Range("a1")
 
    Set trans = ActiveSheet.Range("a1").CurrentRegion
    Set data = trans.Range(Cells(2, 1), Cells(trans.Rows.Count, trans.Columns.Count)) ' épargne la ligne d'en tête
    nom = ActiveSheet.Name
    trans.AutoFilter 1, data.Cells(2, 1)
 
    Do
 
        If trans.End(xlDown).Row <= trans.Rows.Count Then
            Sheets.Add
            ActiveSheet.Name = Mid(WorksheetFunction.Clean(data.Cells(2, 1)), 1, 30) 'précaution pour des noms contenant certains caractères
            trans.CurrentRegion.Copy
            ActiveSheet.Paste
            data.SpecialCells(xlCellTypeVisible).EntireRow.Delete
 
        End If
 
        If trans.Rows.Count > 1 Then trans.AutoFilter 1, data.Cells(2, 1)
 
    Loop Until trans.Rows.Count = 1
 
fin:
    If Err Then MsgBox Err.Description: Err.Clear
 
    Set trans = Nothing
    Worksheets(nom).Delete
 
    With Application
        .ScreenUpdating = True
        .Interactive = True
        .EnableEvents = e
        .Calculation = c
    End With
 
End Sub

02/05/2013, 14h20
Belphegor59

Bonjour,

Merci pour votre aide. Je teste vos solutions dans la journée et je vous tiens au courant.

Pour répondre à NVCfrm : oui la création d'une feuille par nom est obligatoire puisque chaque feuille est destinée à devenir une demande individuelle de renseignements. Sinon, effectivement, un tableau croisé dynamique aurait fait l'afffaire et ça je maîtrise ;).

Bonne journée
Jean-François

Re bonjour,

J'ai testé les deux solutions proposées.

Code de Goldstar: Création d'une feuille par nom mais absence de ligne titre (ligne 1 vide). De plus, création d'une feuille "Nom" qui ne contient que la ligne titre en ligne 2. Nb lignes récupérées par feuille OK.

Code de NVCfrm : Création d'une feuille par nom avec ligne de titre mais toutes les lignes ne sont pas récupérées dans les feuilles créées.

Question annexe : à quel endroit de votre code puis-je intercaler un code de mise en forme des feuilles créées ?

Merci de l'attention que vous portez à mon problème

Amicalement
Jean-François
02/05/2013, 16h00
NVCfrm

Citation:

Envoyé par Belphegor59

Re bonjour,

J'ai testé les deux solutions proposées.

Code de Goldstar: Création d'une feuille par nom mais absence de ligne titre (ligne 1 vide). De plus, création d'une feuille "Nom" qui ne contient que la ligne titre en ligne 2. Nb lignes récupérées par feuille OK.

Code de FVCfrm : Création d'une feuille par nom avec ligne de titre mais toutes les lignes ne sont pas récupérées dans les feuilles créées.

Question annexe : à quel endroit de votre code puis-je intercaler un code de mise en forme des feuilles créées ?

Merci de l'attention que vous portez à mon problème

Amicalement
Jean-François

Salut, j'allais répondre "pas de raisons que des lignes soient ignorées avant de relire le code que j'ai posté. Le bug se situe dans la ligne 39.

Code:

If trans.Rows.Count > 1 Then trans.AutoFilter 1, data.Cells(2, 1)

corriger

Code:

If trans.Rows.Count > 1 Then trans.AutoFilter 1, trans.Cells(2, 1)

pour la question annexe, ce n'est qu'après la création de la feuille.

Et voilà que la question: est-il vraiment nécessaire de créer une feuille par feuille? me revient à nouveau. :D
j'imagine une base comportant quelques milliers de noms différents. une forêt de feuilles à parcourir... au galop :mouarf:
02/05/2013, 18h41
Belphegor59

Re Bonjour

Génial, ça fonctionne parfaitement ! Merci beaucoup.

Ma base de données ne contient au maximum que 60 noms. Comme c'est destiné à faire une demande de renseignements, envoyée par courrier pour réponse écrite, le TCD n'est pas valable.

Amicalement
Jean-François