Expression rationnelle macro VBA

Version imprimable

Bonjour,

Je souhaite remplacer une chaine de caractères par une nouvelle chaine modifié, en utilisant les expressions rationnelles de VBA.

Voici un exemple de chaine d'origine:
1, 4, 6-7, 9-10, 13-17, 19, 23, 25

A la fin je souhaite obtenir:
1;4;[6-7];[9-10];[13-17];19;23;25

En gros la virgule + espace est remplacé par un point virgule.
Lorsqu'il y a un intervalle de chiffre, il doit être entouré par des [].

J'ai commencé à faire une ébauche:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Public Sub RegexChaine() Dim RegEx As RegExp Set RegEx = New RegExp With RegEx .IgnoreCase = True .Global = False .Pattern = "(.*)(, )(.*)" End With chaine$ = "1, 4, 6-7, 9-10, 13-17, 19, 23, 25" chaine$ = RegEx.Replace(chaine$, "$1") MsgBox (chaine$) End Sub
Mais je bloque, je n'arrive pas à comprendre le fonctionnement avec le $1

Merci de m'aider.

Expression régulière

Essaie ce code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Public Function RegexChaine(Chaine As String)
    Dim RegEx As RegExp
    Dim Chaine1 As String
    Dim Chaine2 As String
 
 
    Set RegEx = New RegExp
 
    With RegEx
        .IgnoreCase = True
        .Global = True
        .Pattern = ", "
        Chaine1 = RegEx.Replace(Chaine, ";")
 
        .Pattern = "([0-9]*\-[0-9]*)"
        Chaine2 = RegEx.Replace(Chaine1, "[$1]")
    End With
 
    RegexChaine = Chaine2
End Function
 
Sub EssaiRegExp()
    Dim Chaine As String
 
    Chaine = "1, 4, 6-7, 9-10, 13-17, 19, 23, 25"
 
    MsgBox RegexChaine(Chaine), , Chaine
 
End Sub

Je procède en 2 passes : le remplacement des ", " par des ";" puis le remplacement des plages.

PS : quand tu cites du code, mets les balises de code.

04/04/2013, 15h38
jackoneill

Merci ça marche parfaitement!