Script marche sous XP et non pas sur Windows 7 ?

Version imprimable

:salut: Dans un PC de mon ami qui a ces caractéristiques suivantes :

Citation:

BIOS ACRSYS - 1
Fabriquant: Acer
Modèle : TravelMate 5742G
Microsoft Windows 7 Professionnel N |C:\Windows|\Device\Harddisk0\Partition2
Version 6.1.7600
Service Pack 0.0

le code suivant m'affiche une erreur de ce type :

Citation:

Ligne : 15
Caract : 1
Erreur : Argument ou appel de procédure incorrect
Code : 800A0005
Source : Erreur d'exécution Microsoft VBScript
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 URL = InputBox("Entrez l'URL pour y extraire son Code Source HTML "&vbcr&vbcr&_ "Exemple ""http://www.google.fr""","Extraction du Code Source © Hackoo © 2013","http://www.google.fr") If URL = "" Then WScript.Quit Titre = "Extraction du Code Source de " & URL Set ie = CreateObject("InternetExplorer.Application") Set objFSO = CreateObject("Scripting.FileSystemObject") ie.Navigate(URL) ie.Visible=false DO WHILE ie.busy LOOP DataHTML = ie.document.documentElement.innerHTML strFileHTML = "CodeSourceHTML.txt" Set objHTMLFile = objFSO.OpenTextFile(strFileHTML,2,True) objHTMLFile.WriteLine(Titre&vbcr&String(120,"*")) objHTMLFile.WriteLine(DataHTML) objHTMLFile.Close ie.Quit Set ie=Nothing Ouvrir(strFileHTML) wscript.Quit Function Ouvrir(File) Set ws=CreateObject("wscript.shell") ws.run "Notepad.exe "& File,1,False end Function
Je n'ai pas bien compris d’où provient cette erreur ? , pourtant le même code sous Windows XP marche très bien :koi:

23/03/2013, 18h18
l_autodidacte
Deux possibilités à mon avis :
1 - Soit que DataHTML est vide, ce qu'on peut vérifier avec MsgBox
2 - Soit que le texte à insérer est de l’Unicode ou en contient(Arabe entre autres) et dans ce dernier cas fais :
Code:

1 2 Const TriStateTrue = -1 ' Pour la prise en charge de l'Unicode Set objHTMLFile = objFSO.OpenTextFile(strFileHTML, 2, True, TriStateTrue)

:salut:
Effectivement ça marche avec de l'unicode
:merci: Problème est :resolu: :plusser: :ccool:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Const TriStateTrue = -1 ' Pour la prise en charge de l'Unicode
URL = InputBox("Entrez l'URL pour y extraire son Code Source HTML "&vbcr&vbcr&_
"Exemple ""http://www.google.fr""","Extraction du Code Source © Hackoo © 2013","http://www.google.fr")
If URL = "" Then WScript.Quit
Titre = "Extraction du Code Source de " & URL
Set ie = CreateObject("InternetExplorer.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject")
ie.Navigate(URL)
ie.Visible=false
DO WHILE ie.busy
LOOP
DataHTML = ie.document.documentElement.innerHTML
strFileHTML = "CodeSourceHTML.txt"
Set objHTMLFile = objFSO.OpenTextFile(strFileHTML, 2, True, TriStateTrue)
objHTMLFile.WriteLine(Titre&vbcr&String(120,"*"))
objHTMLFile.WriteLine(DataHTML)
objHTMLFile.Close
ie.Quit
Set ie=Nothing
 Ouvrir(strFileHTML)
wscript.Quit
 
Function Ouvrir(File)
    Set ws=CreateObject("wscript.shell")
    ws.run "Notepad.exe "& File,1,False
end Function