Selectionner une cellule vide en fonction des colonnes et lignes remplies

Version imprimable

15/03/2013, 10h44
h12enri

Selectionner une cellule vide en fonction des colonnes et lignes remplies

Bonjour à tous,

J'ai un tableau que je remplis de colonne en colonne, donc je remplis d'abord la colonne A entièrement (depuis A6 jusque A17), puis je passe à la B (pareil, de B6 à B17), etc...

Ce que je souhaiterai parvenir à faire, c'est une macro qui me sélectionne directement la première cellule vide que je dois remplir.

Example : Imaginons que la colonne A est entièrement remplie, et que j'ai déjà rempli B6 et B7. J'aimerai que ce soit la cellule B8 qui soit sélectionnée.

Pour info, mon range va de A6 à I17 et je l'ai nommé "Wtr_C".

Je trouve bien le moyen de sélectionner la dernière cellule vide d'une colonne ou d'une ligne mais je ne sais pas comment combiner les 2 pour d'abord progresser de colonne en colonne puis de ligne en ligne.
Ce doit surement être quelque chose comme "1. sélectionner la première colonne non-complète; et 2. dans cette colonne, sélectionner la première cellule vide", non ?
Mais comment traduire cela en VBA ?

Merci pour votre aide :)
- Henri
15/03/2013, 11h12
CristofMartins
Bonjour,
as-tu pensé a faire un test?
exemple :
Code:

1 2 3 if cellule = "" then ... end if

Bonjour,

Code:

1
2
3
4
5
6
7
8
9
Sub Test()
Dim Col As Integer
    For Col = 1 To 9
        If Cells(6, Col).End(xlDown).Row < 17 Then
            Cells(6, Col).End(xlDown).Offset(1, 0).Select
            Exit For
        End If
    Next Col
End Sub

Cordialement.

Bonjour
Une proposition

Code:

1
2
3
4
5
6
7
8
9
10
Sub test()
Dim Rng As Range
Set Rng = Range("Wtr_C").Cells.SpecialCells(xlCellTypeBlanks)
Select Case Rng.Areas.Count
    Case 1
        Rng(1, 1).Select
    Case Else
        Rng.Areas(2)(1, 1).Select
End Select
End Sub

Cordialement

15/03/2013, 11h57
h12enri

Excellent !
Merci beaucoup à tous les 2. Vos propositions me plaisent tout particulièrement :D
Bravo bravo

Re bonjour à tous,
Dans le cas ou la zone peut être entièrement remplie :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub test_2()
Dim Rng As Range
On Error Resume Next
Set Rng = Range("Wtr_C").Cells.SpecialCells(xlCellTypeBlanks)
If Err Then
    Err.Clear
    MsgBox "La zone est remplie", 64, "Tableau rempli"
    Exit Sub
End If
Select Case Rng.Areas.Count
    Case 1
        Rng(1, 1).Select
    Case Else
        Rng.Areas(2)(1, 1).Select
End Select
End Sub

Cordialement

Pour le fun

Code:

1
2
3
4
Sub Test()
    Range("Wtr_C").Cells(Application.CountA(Range("Wtr_C")) Mod 12 + 1, _
    Int(Application.CountA(Range("Wtr_C")) / 12) + 1).Select
End Sub

Cordialement.