Pb dans mon vlookup

Version imprimable

Pb dans mon vlookup

Bonjour a tous,

j'ai fait la macro suivante:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
'Open the directory "S:" to be able to find the correct report
With Application.FileDialog(msoFileDialogFilePicker)
    .InitialFileName = "S:"
    .Show
    'and select the report on which you click
    If .SelectedItems.Count > 0 Then Workbooks.Open (.SelectedItems(1))
End With
 
str = ActiveWorkbook.Name
 
 
With ThisWorkbook.Worksheets("S i")
    For i = 0 To .Columns(.Range("BR3").Column).Find("*", , , , xlByColumns, xlPrevious).Row - 1
        If WorksheetFunction.CountIf(Workbooks(str).Worksheets("Donnees").Range("C1:C100"), (.Range("BS3").Offset(i, -69) = "h s")) Then
            .Range("BS3").Offset(i, 0) = WorksheetFunction.VLookup(.Range("BS3").Offset(i, -70), Workbooks(str).Worksheets("Donnees").Range("C15:C16"), 2, False) / 1000000
        Else
            'rien
        End If
    Next i
End With

en gros, je me positionne en BS3 et je dis à ma macro la condition suivante:
si en cellule BS3 - 69 il y a marqué h s
alors vlookup de la cellule BS3 -70, ... , ..., false

le code semble s executer correctement mais il n y a pas de reponse, sauriez vous ou est le souci?

merci pour votre aide,

Bien cordialement

15/02/2013, 11h09
keygen08

Bonjour

J'aurais ecrit la ligne 12 comme ceci

Code:

With ThisWorkbook.sheets("S" & i)
15/02/2013, 11h16
gFZT82

Bonjour,

Je suis surpris par ta plage de recherche qui se limite à C15:C16.
Si la valeur de la cellule en colonne A est égale à celle de C15, on affecte la valeur de C16 /1000000 à la cellule correspondante en colonne BS, c’est bien çà ?

Cordialement.
15/02/2013, 11h43
bentor22

oui exactement,

mais je fais un vlookup pke y a d autre données qui sont présent dans l autre fichier et je ne veux pas qu il les copie.
15/02/2013, 11h50
bentor22

Bonjour Keygen08,

le probleme n est pas la, tout marche c'est uniquement le vlookup qui marche pas! c bizarre!!!
15/02/2013, 13h02
gFZT82
Ce que je veux te dire, c’est qu’il n’y a pas besoin de faire un VLookup pour cette opération.
Il suffit de faire
Code:

1 2 If .Range("BS3").Offset(i, -70)= Workbooks(str).Worksheets("Donnees").Range("C15") then _ .Range("BS3").Offset(i, 0) = Workbooks(str).Worksheets("Donnees").Range("C16")/ 1000000
Je comprendrais si la recherche s’effectuait sur une plage incluant plusieurs cellules, mais s’il n’y a qu’une cellule (C15), je ne vois pas l’intérêt d’un VLookup.

Cordialement.

Ta solution est tres juste, j'y avais pas pensé.
je trouve ca tres judicieux.

toutefois est ce possible de mettre 2 if i.e:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
with ThisWorkbook.Worksheets("S i")
    For i = 0 To .Columns(.Range("BR3").Column).Find("*", , , , xlByColumns, xlPrevious).Row - 1
        If ThisWorkbook.Worksheets("S i").Range("BS3").Offset(i, -69) = "h s" Then
            If .Range("BS3").Offset(i, -70) = Workbooks(str).Worksheets("Donnees").Range("C15") Then _
               .Range("BS3").Offset(i, 0) = Workbooks(str).Worksheets("Donnees").Range("C16") / 1000000
 
        Else
           'rien
            End If
        End If
        Next i
End With

comment faire avec les 2 if.

d avance merci.

cordialement

Ce qui se traduit par

Code:

1
2
3
4
5
6
7
8
With ThisWorkbook.Worksheets("S i")
    For i = 0 To .Columns(70).Find("*", , , , xlByColumns, xlPrevious).Row - 1
        If ThisWorkbook.Worksheets("S i").Range("B3").Offset(i, 0) = "h s" Then
            If .Range("A3").Offset(i, 0) = Workbooks(Str).Worksheets("Donnees").Range("C15") Then _
               .Range("BS3").Offset(i, 0) = Workbooks(Str).Worksheets("Donnees").Range("C16") / 1000000
        End If
    Next i
End With

Cordialement.

15/02/2013, 15h06
bentor22

merci pour ta réponse, je comprends totalement ton code qui est très juste mais ca ne veut pas donner la reponse demandé!!!
15/02/2013, 15h20
bentor22

merci pour ta réponse, je comprends totalement ton code qui est très juste mais ca ne veut pas donner la reponse demandé!!!

S'il s'agit d'un problème d'analyse, tu peux utiliser des variables intermédiaires et vérifier leur valeur dans la fenêtre Variables locales en déroulant ton programme en pas à pas.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
With ThisWorkbook.Worksheets("S i")
    V1 = .Columns(70).Find("*", , , , xlByColumns, xlPrevious).Row - 1
    For i = 0 To V1
        V2 = ThisWorkbook.Worksheets("S i").Range("B3").Offset(i, 0).Value
        V3 = .Range("A3").Offset(i, 0).Value
        V4 = Workbooks(Str).Worksheets("Donnees").Range("C15").Value
        V5 = Workbooks(Str).Worksheets("Donnees").Range("C16").Value / 1000000
        If V2 = "h s" Then
            If V3 = V4 Then .Range("BS3").Offset(i, 0) = V5
        End If
    Next i
End With

Cordialement.

18/02/2013, 10h06
bentor22

Bonjour, et merci pour ta réponse.

j'ai vérifié comme tu me l as suggéré en regardant les variables intermédiaires et vérifier leur valeur dans la fenêtre Variables locales en déroulant le programme en pas à pas.

et en effet, j'ai constaté ou est l erreur.

quand on dit .range("C15"), je pensais que c etait l ensemble de la colonne O .
mais d apres le programme, c est la valeur de la cellule C 15.
pareil pour .range("C16")

Du coup, sauriez vous comment dire à la macro la chose suivante ( sans le vlookup).

if V2="h s" then
if V4=V5 then .Range("BS3").offset(i,0) = V5

V4 et V5 n'étant pas des cellules mais des colonnes,
V4 etant la colonne O (.range("O") ? )
V5 etant la colonne P

merci pour ton aide.

bien cordialement

Bonjour,

Fais l'essai avec le code ci-dessous.
La valeur relevée en colonne A est recherchée dans la colonne O. Si elle existe, on retourne la valeur adjacente (colonne P) / 1000000 dans la cellule BS.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub test()
With ThisWorkbook.Worksheets("S i")
    V1 = .Columns(70).Find("*", , , , xlByColumns, xlPrevious).Row - 1
    For i = 0 To V1
        V2 = .Range("B3").Offset(i, 0).Value
        V3 = .Range("A3").Offset(i, 0).Value
        If V2 = "h s" Then
            Set V4 = Workbooks(Str).Worksheets("Donnees").Columns(15).Find(V3, LookIn:=xlValues, lookat:=xlWhole)
            If Not V4 Is Nothing Then .Range("BS3").Offset(i, 0) = V4.Offset(0, 1) / 1000000
        End If
    Next i
End With
End Sub

Cordialement.

18/02/2013, 12h01
bentor22

Parfait,

merci enormement pour ton aide.

Ton style est tres clair, tres concis, tres comprehensible.

C'etait un plaisir,

Bonne journée, et encore une fois merci