ouvrir et enregistrer un MsFlexgrid

Version imprimable

Bonjour à tous,

J'ai un MSFlexgrid que j'enregistre en format text avec ce code :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 Private Sub enregistrer_Click() Dim colonne As Integer Dim Ligne As Integer Dim cptligne As Integer Dim cptcolonne As Integer Dim chaine As String Dim emp emp = App.Path Open emp + "nomfichier.txt" For Output As #1 colonne = Me.MSFlexGrid1.Cols Ligne = Me.MSFlexGrid1.Rows For cptligne = 0 To Ligne - 1 For cptcolonne = 0 To colonne - 1 chaine = chaine & Me.MSFlexGrid1.TextMatrix(cptligne, cptcolonne) chaine = chaine & "|" Next cptcolonne Print #1, chaine chaine = "" Next cptligne Close #1 End Sub
Le résultat n'est pas au top^car il y a plein de traits verticaux sur la feuille mais les données sont bien enregistrées. Le gros problème est de pouvoir ouvrir les fichiers enregistrés au format text.
J'ai bricoler un bout de code qui utilise la boite de dialogue ouvrir mais je n'arrive pas à lire et encore moins à écrire le contenu du fichier dans mon MSFlexgrid ( j'utilise le même MSFexgrid qui à créer le fichier pour le r'ouvrir)

voici le code qui ne fonctionne pas :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 Private Sub ouvrir_Click() Dim ff As Integer Dim i As Integer Dim j As Integer Dim A$ Dim MonFichier i = MSFlexGrid1.Rows ff = FreeFile CommonDialog1.ShowOpen MonFichier = CommonDialog1.FileName Open MonFichier For Input As #ff Do While Not EOF(ff) MSFlexGrid1.Rows = i + 1 For j = 0 To 104 If Not EOF(ff) Then Input #ff, A$ MSFlexGrid1.TextMatrix(i, j) = A$ Else Exit Do End If Next j i = i + 1 Loop Close #ff End Sub
il doit me manquer un petit quelque chose que mes maigre connaissances ne me permettent pas de trouver :?

merci pour votre aide toujours précieuse

cordialement

Didier

13/12/2012, 11h32
DAUDET78

Citation:

Envoyé par dmoluc

Le résultat n'est pas au top^car il y a plein de traits verticaux sur la feuille

Ca me semble normal .... c'est toi qui les ajoute

Code:

chaine = chaine & "|"
13/12/2012, 11h38
dmoluc

merci c'est déjà ça : à force de piquer des codes à droites à gauche sans les comprendres totalement, je fais des bétises :oops:

j'ai essayé de faire l'inverse de l'enregistrement en utilisant input, mais je n'arrive toujours pas à ouvrir le fichier
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 Private Sub ouvrir_Click() Dim MonFichier Dim colonne As Integer Dim ligne As Integer Dim cptligne As Integer Dim cptcolonne As Integer Dim chaine As String Dim emp CommonDialog1.ShowOpen MonFichier.Text = CommonDialog1.FileName Open "MonFichier" For Input As #1 colonne = Me.MSFlexGrid1.Cols ligne = Me.MSFlexGrid1.Rows For cptligne = 0 To ligne - 1 For cptcolonne = 0 To colonne - 1 chaine = chaine & Me.MSFlexGrid1.TextMatrix(cptligne, cptcolonne) chaine = chaine & " " Next cptcolonne Print #1, chaine chaine = "" Next cptligne Close #1 End Sub
"CommonDialog1.FileName" contient bien le fichier mais impossible de l'ouvrir, cette ligne de code ne fonctionne pas :

Code:

Open "MonFichier" For Input As #1

quelqu'un aurait une idée, ce serait sympat, merci

13/12/2012, 12h23
DAUDET78

Peut être

Code:

Open MonFichier.text For Input As #1
13/12/2012, 12h39
ProgElecT
Salut
Code:

1 2 3 Dim MonFichier '................ MonFichier.Text = CommonDialog1.FileName
La variable MonFichier n'a pas de propriété Text cette variable n'est pas un objet.
13/12/2012, 12h46
iclic
Bonjour,
Code:

1 2 Open "MonFichier" For Input As #1
Si tu ouvres un fichier en 'INPUT , il faut prendre le code approprié
pour le lire

soit
Code:

1 2 input #1, chaine
Mais attention s'il y a des virgules dans le texte...

ou alors
Code:

1 2 Line input #1, chaine
NB: PRINT, c'est pour écrire et on ouvre alors le fichier en OUTPUT ou APPEND
13/12/2012, 12h47
DAUDET78
Citation:

Envoyé par ProgElecT

cette variable n'est pas un objet.

Bien vu !
Code:

1 2 3 Dim MonFichier as String '........ Open MonFichier For Input As #1
13/12/2012, 13h22
ProgElecT

Pour enregistrer chaque cellules de ton MSFlexGrid, sépares tes colonnes par Chr(1) plutôt que "|", la lecture avec avec Notepad et/ou Word chr(1) n'est pas visible.
Pour remplir ton MSFlexGrid, tu split chaque ligne avec ce même séparateur.

J'en suis arrivé à écrire dans le flexgrid, hélas ça ne lis toujours pas le fichier, la variable chaine est désespérément vide donc j'obtiens un beau tableau vierge

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
 
Private Sub ouvrir_Click()
 
Dim MonFichier As String
Dim colonne As Integer
Dim Ligne As Integer
Dim cptligne As Integer
Dim cptcolonne As Integer, chaine As String
 
CommonDialog1.ShowOpen
 
MonFichier = CommonDialog1.FileName
 
 Open MonFichier For Input As #1
 
Do While Not EOF(1)    ' Effectue la boucle jusqu'à la fin du fichier.
    Line Input #1, chaine         ' Lit la ligne dans la variable.
 
   colonne = Me.MSFlexGrid1.Cols
Ligne = Me.MSFlexGrid1.Rows
For cptligne = 0 To Ligne - 1
For cptcolonne = 0 To colonne - 1
   Me.MSFlexGrid1.TextMatrix(cptligne, cptcolonne) = chaine
Next cptcolonne
 
Next cptligne
Loop
Close #1
 
End Sub

13/12/2012, 13h38
dmoluc

1 pièce(s) jointe(s)

Citation:

Pour enregistrer chaque cellules de ton MSFlexGrid, sépares tes colonnes par Chr(1) plutôt que "|", la lecture avec avec Notepad et/ou Word chr(1) n'est pas visible.
Pour remplir ton MSFlexGrid, tu split chaque ligne avec ce même séparateur.

J'ai suivi ton conseil et maintenant j'obtiens le genre de chose qui est sur l'image ci-jointe .....
13/12/2012, 14h08
dmoluc

1 pièce(s) jointe(s)

si je ne met pas de séparateur , j'ai droit à un jolie tableau tout blanc, sinon un truc du genre de l'image jointe tout à l'heure et ça quelque soit le séparateur que j'emplois ( mais je suis loin de tous les connaitres)
j'ai beau exécuter pas à pas le code, je ne vois toujours pas comment incrémenter ma variable chaine avec le texte ; elle n'aime que les séparateurs :mrgreen:

s'il y a une âme charitable pour regarder ce qui cloche, je joint le projet au format zip

Je dois avoir des problèmes de syntaxe avec le split des séparateur. Maintenant j'arrive bien à écrire dans le flexgrid mais ça me mets toutes la ligne dans chaque cellule de celle-ci :calim2:

code modifier de l'enregistrement du fichier

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Private Sub enregistrer_Click()
 
Dim colonne As Integer
Dim Ligne As Integer
Dim cptligne As Integer
Dim cptcolonne As Integer
Dim chaine As String
Dim emp
 
 
emp = App.Path
 
Open emp + "nomfichier.txt" For Output As #1
colonne = Me.MSFlexGrid1.Cols
Ligne = Me.MSFlexGrid1.Rows
For cptligne = 0 To Ligne - 1
For cptcolonne = 0 To colonne - 1
chaine = chaine & Me.MSFlexGrid1.TextMatrix(cptligne, cptcolonne)
chaine = chaine
Split (chaine & Chr(1)) 'je split sur la colonne
Next cptcolonne
Split (chaine & Chr(1))'je split sur la ligne ( mais sans résultat)
Print #1, chaine
chaine = ""
Next cptligne
 
Close #1
 
End Sub

sinon pour écrire j'en suis arrivé là

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
 
Private Sub ouvrir_Click()
 
Dim MonFichier As String
Dim colonne As Integer
Dim Ligne As Integer
Dim cptligne As Integer
Dim cptcolonne As Integer, chaine As String
 
CommonDialog1.ShowOpen
 
MonFichier = CommonDialog1.FileName
 
 Open MonFichier For Input As #1
 
Do While Not EOF(1)    ' Effectue la boucle jusqu'à la fin du fichier.
 
   colonne = Me.MSFlexGrid1.Cols
Ligne = Me.MSFlexGrid1.Rows
 
For cptligne = 0 To Ligne - 1
Line Input #1, chaine
For cptcolonne = 0 To colonne - 1
   Me.MSFlexGrid1.TextMatrix(cptligne, cptcolonne) = chaine
Next cptcolonne
chaine = ""
Next cptligne
 
Loop
Close #1
 
End Sub

Il ne doit vraiment pas manquer grand chose, mais quoi ?

encore merci pour votre aide....

13/12/2012, 15h13
DarkVader

Bonjour,
J'ai lu (en diagonale) et FlexGrid n'est pas ma tasse de thé, donc pardon si je suis à coté de la plaque
mais, sauf erreur :
1/ il existe la propriété Clear pour vider le FlexGrid
2/ le séparateur de champ est la tabulation et de ligne, vbCrLf
en formattant les données avec ces séparateurs, il est donc possible d'affecter directement les plages de données avec la propriété Clip.
De plus si les fichiers texte formatés ainsi sont directement exploitables tels quels
ils sont aussi beaucoup plus lisibles

Bonne journée.

PS: Ne pas oublier les filtres aux boites de Sélection de fichiers
13/12/2012, 15h29
dmoluc

Quel que soit le séparateur de champ, pas de problème avec les ligne, mais ça ne sépare pas les colonnes et persiste à écrire toute la ligne dans chaque cellule.
je commence un peu à désespérer malgré que je sois têtu. Sans enregistrement le programme ne vaut rien et je manque vraiment de connaissances pour trouver seule la solution .....

encore merci
13/12/2012, 15h43
DarkVader

Citation:

Envoyé par dmoluc

Quel que soit le séparateur de champ, pas de problème avec les ligne, mais ça ne sépare pas les colonnes et persiste à écrire toute la ligne dans chaque cellule.

Si tu le dis :mouarf:

Salut DarkVader , et tous les autres ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub ouvrir_Click()
 
Dim MonFichier As String
Dim colonne As Integer
Dim Ligne As Integer
Dim cptligne As Integer
Dim cptcolonne As Integer, chaine As String
 
Dim TblColonne() As String '<--------------- New -----------------
 
CommonDialog1.ShowOpen
 
MonFichier = CommonDialog1.FileName
 
Open MonFichier For Input As #1
'colonne = Me.MSFlexGrid1.Cols
'Ligne = Me.MSFlexGrid1.Rows
 
Ligne = -1 ' si pas de ligne fixe, sinon Ligne = 0
Do While Not EOF(1)    ' Effectue la boucle jusqu'à la fin du fichier.
    Line Input #1, chaine
    TblColonne = Split(chaine, Chr(1)) '<--------------- New -----------------
    Ligne = Ligne + 1
    For cptcolonne = 0 To colonne - 1
        Me.MSFlexGrid1.TextMatrix(Ligne, cptcolonne) = TblColonne(cptcolonne) '<--------------- New -----------------
    Next cptcolonne
Loop
Close #1
End Sub

Bonjour ProgElecT,
Je ne comprends pas pourquoi Chr(1) et non vbTab !

Ex

Code:

1
2
3
4
5
6
7
8
9
10
11
contentExemple="ValL1C1"+vbtab+"ValL1C2"+vbtab+"ValL1C3"+vbcrlf
contentExemple=contentExemple+"ValL2C1"+vbtab+"ValL2C2"+vbtab+"ValL2C3"+vbcrlf
contentExemple=contentExemple+"ValL3C1"+vbtab+"ValL3C2"+vbtab+"ValL3C3"+vbcrlf
 
with flex1
  .col=1
  .row=1
  .rowsel=3
  .colsel=3
  .clip=contentExemple
end with

à vérifier

13/12/2012, 16h35
dmoluc

Maintenant je n'y comprend plus rien si tant soit peu j'y ai compris quelques chose :calim2:
le code de ProgElecT ne remplis que la première cellule et avec toute la ligne du fichier text après ça bug : TblColonne(colonne) "is out of range"
quand au code de DarkVader j'ai beau l'étudié en long et en large je ne vois pas comment il fonctionne
je crois que je vais aller discuter un peu avec les secrétaires pour voir si en coupant un peu une idée géniale survient, mais je n'y crois pas trop :(

enfin merci pour votre aide

Bon, je suis chez moi, j'ai donc plus de temps, au boulot, il y a toujours quelqu'un qui vous dérange :aie:

A DarkVader
Chr(1) n'est pas visible (équivalent à un espace) dans quasi tous les éditeurs de fichier txt, alors que vbTab suivant l'éditeur, la séparation des données n'est pas toujours des plus claires, je n'ai eu qu'une seul fois à procéder de la sorte.

A dmoluc
Démarres un nouveau projet, dedans tu y places 3 CommandButtons, 1 FlexGrid et 1 CommonDialog.
Le placement, les intitulés sont fait dans le code (Form_Load).

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Option Explicit
Dim T As Long, U As Long, NumFich As Integer
Dim MonFichier As String, Chaine As String, TblCol() As String, SeparateuR As String
 
Private Sub Form_Load()
'positionne les éléments
Command1.Move 120, 60, 1035, 315: Command1.Caption = "Ouvrir"
Command2.Move 1200, 60, 1035, 315: Command2.Caption = "Enregistrer"
Command3.Move 120, 420, 2115, 315: Command2.Caption = "Enregistrer"
MSFlexGrid1.Move 0, 780, 5175, 3075
Me.Height = 4425: Me.Width = 5415
MSFlexGrid1.Rows = 10
MSFlexGrid1.FixedRows = 1
MSFlexGrid1.Cols = 5
MSFlexGrid1.FixedCols = 0
 
'Histoire de remplir le grid
MSFlexGrid1.FormatString = "colonne 1|colonne 2|colonne 3 |colonne 4|colonne 5" 'titrage des colonnes
For T = 1 To MSFlexGrid1.Rows - 1
    For U = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.TextMatrix(T, U) = Chr(64 + T + U) 'remplis chaque cellule
    Next U
Next T
SeparateuR = vbTab '<---------- caractère quelconque, celui que tu veux
End Sub
 
Private Sub Command1_Click()
'Ouvrir
MSFlexGrid1.Clear 'vider toutes les cellules du grid
MSFlexGrid1.Rows = 1: MSFlexGrid1.Cols = 1: T = 1
CommonDialog1.ShowOpen
MonFichier = CommonDialog1.FileName
NumFich = FreeFile
Open MonFichier For Input As #NumFich
Do While Not EOF(NumFich)    ' Effectue la boucle jusqu'à la fin du fichier.
    Line Input #NumFich, Chaine ' récupération de la ligne
    TblCol = Split(Chaine, SeparateuR) 'éclate la ligne en colonne
    If T = 1 Then MSFlexGrid1.Cols = UBound(TblCol) + 1 'dimensionne le nombre de colonne du grid (une seule fois)
    MSFlexGrid1.Rows = MSFlexGrid1.Rows + 1 'ajoute une ligne au grid
    For U = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.TextMatrix(T, U) = TblCol(U) 'rempli chaque colonne
    Next U
    T = T + 1 'préparation pour la suite
Loop
Close NumFich
End Sub
Private Sub Command2_Click()
'Enregistrer
CommonDialog1.ShowSave
MonFichier = CommonDialog1.FileName
NumFich = FreeFile
Open MonFichier For Output As #NumFich
For T = 1 To MSFlexGrid1.Rows - 1
    Chaine = ""
    For U = 0 To MSFlexGrid1.Cols - 1
        Chaine = Chaine & MSFlexGrid1.TextMatrix(T, U)
        'pour ne pas ajouter un séparateur à la dernière colonne
        If U <> MSFlexGrid1.Cols - 1 Then Chaine = Chaine & SeparateuR
    Next U
    Print #NumFich, Chaine 'ecrit la ligne
Next T
Close NumFich
End Sub
Private Sub Command3_Click()
'Vider le FlexGrid
MSFlexGrid1.Clear
End Sub

Au premier lancement, enregistre le FlexGrid (bouton Enregistrer) :mouarf:
Puis effaces le contenu du FlexGrid (bouton Vider le FlexGrid)
Toutes les cellules du FlexGrid sont blanche.
Maintenant, charge ton FlexGrid avec le fichier que tu viens de créer (bouton Ouvrir) re :aie:

C'est bon ? en tous cas chez moi le FlexGrid est bien remplis, sauf la ligne fixe, mais si tu as besoin de récupérer aussi le titrage de colonne ....on en rediscute la prochaine fois ;).

13/12/2012, 20h23
dmoluc

Merci ProgElecT

dire que mes collègues sont épatés par ce que je fais, mais il faut bien dire qu'ils sont vraiment nul en informatique :mouarf: mais là je suis subjugué :ccool: ça c'est du travail de pro. Je ne serait jamais à ce niveau à moins que quelqu'un me paye une formation :roll:
Cet été mon rêve était de faire un tableau excel sans utiliser les formules à cause de mes collègues qui n'arrêtent pas de les effacer et qui ne savent pas les remettre, mais même comme ça il y en a encore qui arrivent à faire planter les tableaux. J'ai donc décider de me lancer en VB6 puisque ça ressemble un peu au vba et je suis vraiment devenu accro (même si comme aujourd'hui j'ai parfois eu envie de lancer l'ordinateur par la fenêtre :aie:)

Demain matin je vais vraiment étudier le code de prêt et l'appliqué à mon projet ; à la maison j'ai windows 7 et ça fait des trucs bizarre, du genre lancer l’installation d'autocad ou de ne pas vouloir rajouté les contrôles supplémentaire et en plus au boulot j'ai le temps en ce moment de plus demain c'est les vacances :ccool:

merci pour ce code que j'étais incapable de trouver seul

Bonsoir et à plus

ProgElecT
Si je puis me permettre, la propriété TextMatrix est à utiliser pour des valeurs limitées en nombre ;
dès qu'il y a beaucoup de valeurs, le traitement avec Clip est me semble-t-il beaucoup plus optimisé

soit

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
Private Sub Command4_Click()
    Dim s As String, a As Long, b As Long
 
    With MSFlexGrid1        
        .Row = 1
        .Col = 0
 
        'Ouvrir
        .Clear 'vider toutes les cellules du grid
        .Rows = 1: MSFlexGrid1.Cols = 1: T = 1
        CommonDialog1.ShowOpen
        MonFichier = CommonDialog1.FileName
        NumFich = FreeFile
        Open MonFichier For Input As #NumFich
 
        Do While Not EOF(NumFich)                   ' Effectue la boucle jusqu'à la fin du fichier.
            Line Input #NumFich, Chaine             ' récupération de la ligne
            TblCol = Split(Chaine, SeparateuR)      ' éclate la ligne en colonne
            If b < UBound(TblCol) + 1 Then 'dimensionne le nombre de colonne du grid (une seule fois)
                b = UBound(TblCol) + 1
            End If
            a = a + 1 'ajoute une ligne au grid
            s = s + IIf(s <> "", vbCrLf, "") + Chaine
        Loop
        Close NumFich
 
        .Rows = a + 1
        .Cols = b        
        .RowSel = a
        .ColSel = b - 1
        .Clip = s
    End With
End Sub
Private Sub Command5_Click()
    Dim s As String, a As Long, b As Long
 
    With MSFlexGrid1
        .Row = 1
        .Col = 0
        .RowSel = .Rows - 1
        .ColSel = .Cols - 1
        s = .Clip
 
        'Enregistrer
        CommonDialog1.ShowSave
        MonFichier = CommonDialog1.FileName
        NumFich = FreeFile
        Open MonFichier For Output As #NumFich
            Print #NumFich, s 'ecrit la ligne
        Close NumFich
    End With
End Sub
 
Private Sub Form_Load()
'positionne les éléments
Command1.Move 120, 60, 1035, 315: Command1.Caption = "Ouvrir"
Command2.Move 1200, 60, 1035, 315: Command2.Caption = "Enregistrer"
Command3.Move 120, 420, 2115, 315: Command3.Caption = "Clear"
 
Command4.Move 2500, 60, 1035, 315: Command4.Caption = "Clip Open"
Command5.Move 3700, 60, 1035, 315: Command5.Caption = "Clip Save"
 
MSFlexGrid1.Move 0, 780, 5175, 3075
Me.Height = 4425: Me.Width = 5415
MSFlexGrid1.Rows = 10
MSFlexGrid1.FixedRows = 1
MSFlexGrid1.Cols = 5
MSFlexGrid1.FixedCols = 0
 
'Histoire de remplir le grid
MSFlexGrid1.FormatString = "colonne 1|colonne 2|colonne 3 |colonne 4|colonne 5" 'titrage des colonnes
For T = 1 To MSFlexGrid1.Rows - 1
    For U = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.TextMatrix(T, U) = Chr(64 + T + U) 'remplis chaque cellule
    Next U
Next T
SeparateuR = vbTab '<---------- caractère quelconque, celui que tu veux
End Sub

C'est fait à l'emporte pièce juste pour démonstration

PS: Pour la mise en forme du fichier texte, c'est un autre sujet :)

13/12/2012, 21h50
ProgElecT

Ok

Merci DarkVader

Personnellement je ne connaissais (jamais fait attention) pas la propriété Clip, qui existe pour un MSHFlexGrid mais pas pour le MSFlexGrid que je n'utilise jamais.
Je n'ai jamais utilisé que MSHFlexGrid.
Je vais donc expérimenter cette nouvelle (pour moi) propriété car j'ai encor pas mal de programmes liés à des BDs qui grossissent de plus en plus chaque années, si la performance et meilleurs cela se justifiera de plus en plus de connaitre sa mise en œuvre.

Motif de l'édit:
J'ai raconté des c....... :oops:, MSFlexGrid supporte aussi Clip
13/12/2012, 22h51
DarkVader

Il est difficilement envisageable qu'un controle de ce type n'ait pas une méthode de capture ou d'affectation
par plage entière comme pour Excel.
Imagine affecter une grille de 10000 cellule (ou plus) cellule par cellule !

D'autre part, le format csv d'origine utilise les séparateurs TAB/CR justement pour permettre une affectation directe dans Excel.
Cela fonctionne aussi avec Access mais avec une matrice transposée

Bonjour ProgElecT, Bonjour DarkVader et aussi Bonjour à tous

Une longue journée s'annonce car impossible de faire fonctionner le code de ProgElect avec mon Flexgrid :cry: Si je l'applique tel quel je n'obtiens qu'une seule colonne remplie, mais avec toute la ligne dans chaque cellule.
En bricolant un peu le code ça fonctionne pour la première cellule avant d'avoir l'erreur "out of range" à "TblCol(U)"
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 Private Sub ouvrir_Click() MSFlexGrid1.Clear 'vider toutes les cellules du grid CommonDialog1.ShowOpen MonFichier = CommonDialog1.FileName NumFich = FreeFile Open MonFichier For Input As #NumFich Do While Not EOF(NumFich) ' Effectue la boucle jusqu'à la fin du fichier. Line Input #NumFich, Chaine ' récupération de la ligne For U = 0 To MSFlexGrid1.Cols - 1 TblCol = Split(Chaine, SeparateuR) 'éclate la ligne en colonne MSFlexGrid1.TextMatrix(T, U) = TblCol(U) 'rempli chaque colonne Next U Loop Close NumFich End Sub
Je suppose qu'il doit y avoir des problèmes de format d'enregistrement. Vous parlez de fichier .csv ! Cela fonctionnerai-t-il mieux sous ce format ? Je l'utilise pour transférer les semis de point dans autocad et dans excel et cela met bien les données dans les bonnes cases...
Le flexgrid que j'ai créer remplace un tableau excel, c'est à dire que suivant les entrées et les calculs, il n'y a pas des données dans toutes les cellules ! Cela pose-t-il problème ? De plus je ne souhaite pas recréer le tableau à l'ouverture d'un fichier mais bien réutiliser celui qui existe déjà, sinon ça va faire des trucs bizares :mouarf:
Quel est la Différence entre un MSHFlexgrid et un MSFlexgrid car j'ai choisi le MSFlexgrid au pif en voyant que je pouvais faire des tableaux avec ?

Je vais bosser toutes les infos que vous m'avez envoyées en espérant que ce ne sera pas pour rien

encore merci pour votre aide...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
 
Private Sub ouvrir_Click()
    Dim s As String, a As Long, b As Long
 SeparateuR = "|"
    With MSFlexGrid1
        .Row = 1
        .Col = 0
 
        'Ouvrir
        .Clear 'vider toutes les cellules du grid
        .Rows = 1: MSFlexGrid1.Cols = 1: T = 1
        CommonDialog1.ShowOpen
        MonFichier = CommonDialog1.FileName
        NumFich = FreeFile
        Open MonFichier For Input As #NumFich
 
        Do While Not EOF(NumFich)                   ' Effectue la boucle jusqu'à la fin du fichier.
            Line Input #NumFich, Chaine             ' récupération de la ligne
            TblCol = Split(Chaine, SeparateuR)      ' éclate la ligne en colonne
            If b < UBound(TblCol) + 1 Then 'dimensionne le nombre de colonne du grid (une seule fois)
                b = UBound(TblCol) + 1
            End If
            a = a + 1 'ajoute une ligne au grid
            s = s + IIf(s <> "", SeparateuR, "") + Chaine
        Loop
        Close NumFich
 
        .Rows = a + 1
        .Cols = b
        .RowSel = a
        .ColSel = b - 1
        .Clip = s
    End With
End Sub

en modifiant légèrement le code de Darkvader j'arrive maintenant à recréer le tableau avec toutes ces lignes et colonnes mais sans rien écrire dedans ; il y a encore quelque chose qui m'échape :cry:
Le fichier csv ne s'enregistre pas correctement, mais le fichier text se présente bien, alors pourquoi je n'arrive plus l'écrire, même dans une seule cellule ?
décidément ce n'est pas facile :aie:

14/12/2012, 13h10
ProgElecT

Salut
Pas d'internet ce matin, d’où la réponse tardive

Citation:

Envoyé par dmoluc

....
Une longue journée s'annonce car impossible de faire fonctionner le code de ProgElect avec mon Flexgrid
.....

Là oui c'est inquiétant, car hier j'ai attendu d'être chez moi pour écrire le bout de code, que j'ai bien sûr fait fonctionner sans problème.
De plus tu as fait l'essai avec la syntaxe Clip.

Le programme que je t'ai proposé et fonctionnel, le fait qu'il ne fonctionne pas chez toi laisse penser que tu as un vrai problème VB6, as tu d'autres programmes VB6 qui te semble dysfonctionner, si oui, une réinstalle/récupération de VB6 serait peut être la solution.
De mon coté, je ne voie pas d'autres proposition à te faire.

Bon courage ...
14/12/2012, 13h48
Jipété
Salut,

je m'incruste pour une microscopique correction :mrgreen:

Citation:

Envoyé par ProgElecT

(...) Puis effaces le contenu du FlexGrid (bouton Vider le FlexGrid)

Donc remplacer
Citation:
Envoyé par ProgElecT

Code:

1 2 Command3.Move 120, 420, 2115, 315: Command2.Caption = "Enregistrer"
par
Code:

1 2 Command3.Move 120, 420, 2115, 315: Command3.Caption = "Vider le FlexGrid"
Et chez moi ça fonctionne tip-top ton code ! :ccool:
14/12/2012, 20h09
dmoluc

Bonsoir à tous

Je ne bosse pas le vendredi après midi et j'étais partis en balade, d'ou mon abscence de réponse

le problème c'est que le code fonctionne impeccable si je l'utilise sous ça forme originelle, mais dés que je l'intègre à mon projet, plus rien ne fonctionne, le mieux que j'ai réussis à faire en bataillant, c'est recréer lle tableau mais impossible d'écrire dedans .
Le code intégré sans modification ne créer qu'une seule colonne et écrit toute la ligne du tableau dans chaque cellule.

Il est fort possible que j'ai un problème avec VB6, la version que j'ai est en Anglais, n'est sans doute pas complète car l'aide est absente (mais bon comme mon anglais est limité ) mais difficile de trouver moins cher :mrgreen:
je vais fouillé un peu voir si je peux trouver VB6 en Français et complet. J'ai bien visual studio 2010 mais je ne comprend rien à VB.net :?

Peu être que je devrais reprendre le programme du début avant qu'il ne soit trop avancé car il y a des truc qui fonctionne mal ; par exemple impossible d'afficher les boutons agrandir et réduire la fenêtre et les propriétés de ceux-ci sont pourtant à true

enfin en attendant encore merci pour votre aide et votre patience

A +
14/12/2012, 22h33
ProgElecT

Citation:

Envoyé par dmoluc

Bonsoir à tous
......
le problème c'est que le code fonctionne impeccable si je l'utilise sous ça forme originelle, mais dés que je l'intègre à mon projet, plus rien ne fonctionne
.......
A +

Donc c'est ton projet qui doit poser problème, non pas VB6.
Pour l'aide Visual Basic 6 et VBScript - MSDN
Si ton projet n'est pas trop confidentiel, fais un .ZIP et mets nous le en pièce jointe (trombone, 5éme bouton ligne du haut de l'éditeur de message), car si un projet lambda comme je te l'ai proposé fonctionne, c'est bien un dysfonctionnement dans ton code qui te crée ces problèmes.
15/12/2012, 11h11
DarkVader

dmoluc ne suit pas la classe mais aussi, à sa décharge, en me relisant
j'ai remarqué avoir recopié bêtement ton code ProgElecT
et notamment la ligne

Code:

SeparateuR = vbTab '<---------- caractère quelconque, celui que tu veux

qui aurait du être

Code:

SeparateuR = vbTab '<---------- ne fonctionne qu'avec ce caractère

ce qu'il aurait du relever s'il avait lu et compris mes précédents posts concernant le format csv
15/12/2012, 12h29
dmoluc

1 pièce(s) jointe(s)

Bonjour à tous,

j'ai installé une nouvelle version de vb en Français (du coup je suis un peu perdu dans les appellations:roll: de menu )
j'ai refais le projet et pas pour rien, car maintenant ça fonctionne pour les colonnes, mais plus pour les lignes :cry: (avant il n'y avait que les lignes qui fonctionnées)
je joint le projet qui n'est absolument pas confidentiel ; c'est juste un diagramme de gant qui est très loin d'être achevé

encore merci pour votre aide

cordialement
15/12/2012, 16h01
dmoluc

a force de bidouillage j'y suis enfin parvenu ; j'avais mélanger le nouveau projet et l'ancien, sinon le code à ProgElect fonctionne parfaitement
Encore un grand merci à ProgElect et à Darkvader, vous m'avez tirer une belle épine du pied :ccool:

A +

Salut

dmoluc ,ta pièce jointe est inexploitable, la suite du message pourra toutes fois éventuellement t’intéresser.

Après de multiples essais, par passion mais aussi pour améliorer mes propres programmes.

Je propose ce code modifié, avec la prise en compte des remarques avisées de DarkVader
3 CommandButtons, 1 FlexGrid , 1 CommonDialog, 2 OptionButtons (indexé 0 et 1) et 2 Labels

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
Option Explicit
Dim T As Long, U As Long, NumFich As Integer
Dim MonFichier As String, Chaine As String, TblCol() As String, SeparateuR As String
Dim DebuTmp As Single, FinTmp As Single
 
Private Sub Form_Load()
'positionne les élements
Command1.Move 120, 60, 1035, 315: Command1.Caption = "Ouvrir"
Command2.Move 1200, 60, 1035, 315: Command2.Caption = "Enregistrer"
Command3.Move 120, 420, 2115, 315: Command3.Caption = "Vider le FlexGrid"
MSFlexGrid1.Move 0, 1140, 5175, 3075
MSFlexGrid1.Rows = 10
MSFlexGrid1.FixedRows = 1
MSFlexGrid1.Cols = 5
MSFlexGrid1.FixedCols = 0
Me.Height = 4800: Me.Width = 5415
 
Option1(0).Move 2400, 60, 1455, 255: Option1(0).Caption = ".TextMatrix(L,C)": Option1(0).ToolTipText = "Ouverture ou enregistrement"
Option1(1).Move 3960, 60, 795, 255: Option1(1).Caption = ".Clip": Option1(1).ToolTipText = "Ouverture ou enregistrement"
Label1.Move 2460, 480
Label1.Caption = "": Label1.AutoSize = True
Label2.Move 60, 900
Label2.Caption = "": Label2.AutoSize = True
 
'Histoire de remplir le grid
MSFlexGrid1.FormatString = "colonne 1|colonne 2|colonne 3 |colonne 4|colonne 5" 'titrage des colonnes
For T = 1 To MSFlexGrid1.Rows - 1
    For U = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.TextMatrix(T, U) = Chr(64 + T + U) 'remplis chaque celulle
    Next U
Next T
SeparateuR = vbTab
End Sub
Private Sub Command1_Click()
'Ouvrir
If Option1(0).Value = True Then
    CommonDialog1.DialogTitle = "Ouvrir un fichier méthode .TextMatrix"
    Else
    CommonDialog1.DialogTitle = "Ouvrir un fichier méthode .Clip"
End If
CommonDialog1.CancelError = True
On Error Resume Next
CommonDialog1.ShowOpen
If Err = cdlCancel Then Exit Sub
Err.Clear
MonFichier = CommonDialog1.FileName
NumFich = FreeFile
Open MonFichier For Input As #NumFich
Label1.Caption = "en cours"
DebuTmp = Timer
If Option1(0).Value = True Then
    '------------------ par méthode .TextMatrix(numéro Ligne,numéro Colonne) -----------------------------------
    MSFlexGrid1.Clear 'vider toutes les celulles du grid
    MSFlexGrid1.Rows = 1: MSFlexGrid1.Cols = 1: T = 1
    Do While Not EOF(NumFich) ' Effectue la boucle jusqu'à la fin du fichier.
        Line Input #NumFich, Chaine ' recuperation de la ligne
        TblCol = Split(Chaine, SeparateuR) 'eclate la ligne en colonne
        If T = 1 Then MSFlexGrid1.Cols = UBound(TblCol) + 1 'dimensionne le nombre de colonne du grid (une seule fois)
        MSFlexGrid1.Rows = MSFlexGrid1.Rows + 1 'ajoute une ligne au grid
        For U = 0 To MSFlexGrid1.Cols - 1 'pour rempli chaque colonne
            MSFlexGrid1.TextMatrix(T, U) = TblCol(U)
        Next U
        T = T + 1 'préparation pour la suite
    Loop
    Close NumFich
    Me.Refresh 'pour les gros fichiers
    Else
    '------------------ par méthode .Clip -----------------------------------
    Chaine = Input(FileLen(MonFichier), NumFich) 'récupération de l’entièreté du fichier
    Close #NumFich
    If Chaine = "" Then
        MsgBox "le fichier est vide", vbCritical
        Exit Sub
    End If
 
    If Right(Chaine, 2) = vbNewLine Then Chaine = Left(Chaine, Len(Chaine) - 2)
    'pour Debuguer
    'For T = 1 To 16
    '    Debug.Print Mid(Chaine, T, 1) & " ascii = " & Asc(Mid(Chaine, T, 1))
    'Next T
    'Chaine = Replace(Chaine, Chr(13), vbCr)
    With MSFlexGrid1
        .Clear
        .Rows = (UBound(Split(Chaine, vbNewLine))) + 2 'vbNewLine = separateur de ligne
        .Cols = (UBound(Split(Split(Chaine, vbNewLine)(0), vbTab))) + 1 'vbTab = separateur de colonne
        .RowSel = .Rows - 1
        .ColSel = .Cols - 1
        .Clip = Chaine
        .Row = 1 'pour dé-sélectionner les cellules
    End With
End If
FinTmp = Timer
Label1.Caption = FinTmp - DebuTmp
Label2.Caption = MonFichier
End Sub
Private Sub Command2_Click()
'Enregistrer
If Option1(0).Value = True Then
    CommonDialog1.DialogTitle = "Enregistrer le FlexGrid méthode .TextMatrix"
    Else
    CommonDialog1.DialogTitle = "Enregistrer le FlexGrid méthode .Clip"
End If
CommonDialog1.CancelError = True
On Error Resume Next
CommonDialog1.ShowSave
If Err = cdlCancel Then Exit Sub
Err.Clear
MonFichier = CommonDialog1.FileName
NumFich = FreeFile
Open MonFichier For Output As #NumFich
Label1.Caption = "en cours"
DebuTmp = Timer
If Option1(0).Value = True Then
    '------------------ par méthode .TextMatrix(numéro Ligne,numéro Colonne) -----------------------------------
    For T = 1 To MSFlexGrid1.Rows - 1
        Chaine = ""
        For U = 0 To MSFlexGrid1.Cols - 1
            Chaine = Chaine & MSFlexGrid1.TextMatrix(T, U)
            'pour ne pas ajouter un separateur à la derniére colonne
            If U <> MSFlexGrid1.Cols - 1 Then Chaine = Chaine & SeparateuR
        Next U
        Print #NumFich, Chaine 'écrit la ligne
    Next T
    Else
    '------------------ par méthode .Clip -----------------------------------
    With MSFlexGrid1
        .Row = 1
        .Col = 0
        .RowSel = .Rows - 1
        .ColSel = .Cols - 1
        Chaine = .Clip
        Print #NumFich, Chaine 'écrit la ligne
        .Row = 1 'pour dé-sélectionner les cellules
    End With
End If
Close NumFich
FinTmp = Timer
Label1.Caption = FinTmp - DebuTmp
Label2.Caption = MonFichier
Me.SetFocus: Me.Refresh 'pour les gros fichiers
End Sub
Private Sub Command3_Click()
'Vider le FlexGrid
MSFlexGrid1.Clear
End Sub

Avec un fichier de 108K (10.000 ligne de 5 colonnes)

:fleche: par méthode .TextMatrix(numéro Ligne,numéro Colonne)
ouverture 3,28 à 4,43 Sc
enregistrement 1,87 Sc

:fleche: par méthode .Clip
ouverture 0,047 Sc :ccool:
enregistrement 5,41 à 6,50 Sc :calim2:

Les temps indiqués non pas grand interet, par contre la comparaison d'une méthode à l'autre est parlante.

A l'enregistrement par la méthode TextMatrix(numéro Ligne,numéro Colonne)fait que pour chaque enregistrement de ligne du FlexGrid,
un saut de ligne vbCrLf et ajouté par l'écriture dût au Print #NumFich, Chaine.
A l'enregistrement par méthode .Clip, le séparateur de ligne est un vbCr

Ma conclusion (sauf votre démentit suivant vos essais)
l'ouverture du fichier est plus rapide avec la méthode .Clip (il n'y a pas photo)
l'enregistrement est plus rapide avec la méthode .TextMatrix(numéro Ligne,numéro Colonne)
Donc ouvrir en méthode .Clip mais sauvegarder en méthode .TextMatrix

15/12/2012, 20h45
dmoluc

2 pièce(s) jointe(s)

merci pour cette étude intéressante, je vais l'étudiée avec intérêt
je me suis mélanger en zipant mon projet, des morceaux du premier avec des bout du second
je l'ai remis et cette fois j'ai vérifier que c'était le bon et en plus il marche. Je n'ai plus qu'à trouver un moyen pour recréer les couleur du tableau, sauter les weekend et jour férié dans mon coloriage et le reste sera du gâteau
J'ai déjà fais ce programme sous excel en bien plus compliquer, mais comme avec ton exemple je bute sur la longueur d'exécution des macros.
Sur des user form, je calcul le rendement des machines , la durée de la tâche, le personnel, le matériel, les fourniture, je choisi la date de début et hop tout s'écrit automatiquement sur le tableau. Le hic c'est qu'il faut au moins 3 bonnes minutes, voir plus. Du travail d'amateur :cry:
Avec VB6 j'ai choisi de faire plus simple. Le logiciel de calcul de rendement est terminé et pas intégré au planning et pour renseigner le personnel, matériel, etc... je vais créer une forme pour chaque action.

Pour le moment je n'ai pas encore remarquer de problème de lenteur d'exécution, mais mon PC perso est une bête de course, avec le portable du boulot il faudra que je vérifie .

Je mets aussi l'usine à gaz que j'ai créer sous excel mais c'est pas super

http://cjoint.com/?BLpuRF92vJZ

A plus et encore merci pour tout ton travail de passionné, moi aussi je m'acharne mais je n'ai pas les connaissances

A+