Affichage doc Word depuis macro Excel

Version imprimable

Bonjour je suis nouveau :D (voila ça c'est dit)

Contexte :

Je suis en train de travailler un fichier excel pour en faire un genre de formulaire dont le but est d'aider à classifier un produit selon sa nature, son usage, etc... il s'agit de contrôles à l'exportations (4 grands groupes).

Une fois la classification établie, un bouton ouvre un fichier Word dans lequel se trouve 4 paragraphes (1 par groupe) à copier coller sur les documents classifiés. Il y a 1 paragraphe par page, et donc selon le groupe choisis, j'ouvre à la page correspondante (1 à 4)

Extrait du code: (j'ai référencé la bibliotèque Word et déclaré les variables en dehors de la procédure)
Code:

1 2 3 4 5 6 7 8 9 10 11 Private Sub DisplayMarking(thisPage As Integer) Set wordApp = New Word.Application wordApp.Visible = True Set wordDoc = wordApp.Documents.Open _ (ActiveWorkbook.Path & "\documentWord.docx", False, True) wordApp.Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage End Sub
Problèmes :

ça ouvre un nouveau document chaque fois que je clique, est-il possible, si il est déjà ouvert, de ne pas en ouvrir un nouveau mais juste de se repositionner à la bonne page?

Si oui, alors il faut que je trouve comment mettre ensuite Word au premier plan.
[résolu] "wordApp.Activate"

Paufinage : lorsqu'on change de page sous word (tout en bas à gauche)ça ajuste correctement l'affichage (haut de la page pile poil sous le ruban. J'ai récupéré la macro avec l'enregistreur mais rien n'y fait.. la macro n'ajuste pas l'affichage (on voit un bout de la page d'avant c'est môche) ..je sais je suis un gros maniac :lol: bref connaissez vous le subterfuge ?

Merci de m'avoir lu.

Bonjour,

Je ne suis pas calé en VBA Word pour le point 3. Pour les autres essaie (non testé) :

Code:

1
2
3
4
5
6
7
8
9
10
11
    If WordApp = "" Then Set WordApp = New Word.Application
    WordApp.Visible = True
    If WordDoc = "" Then
        Set WordDoc = WordApp.Documents.Open _
        (ActiveWorkbook.Path & "\documentWord.docx", False, True)
    ElseIf WordDoc.Name <> "documentWord.docx" Then
        Set WordDoc = WordApp.Documents.Open _
        (ActiveWorkbook.Path & "\documentWord.docx", False, True)
    End If
    WordApp.Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage
    Application.ActivateMicrosoftApp xlMicrosoftWord

Merci bien, alors je viens de tester et j'ai des erreurs :

Si le document Word n'est pas encore ouvert
erreur '91' : "variable objet ou variable de bloc with non définie" sur [If wordApp = ""]

Si le document est ouvert
Pas d'erreur et ça fonctionne correctement : pas de nouvelle ouverture de fichier, selection de la bonne page..

Si le document a été ouvert puis fermé
erreur '462' : "le serveur distant n'existe pas ou n'est pas disponible" ça me met la même erreur sur la comparaison de wordDoc si j'enlève [If wordApp = ""]

Enfait quand je ferme le classeur word je ne sais pas ce que devienne les objets wordApp et wordDoc.. c'est surtout ça qui m'endicape :cry:
J'ai essayé de faire des tests avec Is Nothing (mais je connais pas trop), pareil ça merdouille.

Ensuite pour Application.ActivateMicrosoftApp xlMicrosoftWord : ça n'a pas le résultat escompté : ça ouvre une nouvelle application word.

J'ai étudié un peu la syntaxe et j'ai trouvé un truc qui fonctionne : wordApp.Activate (tout simplement :) ) donc point 2 résolu.

[EDITION]
Y a du nouveau! j'ai reussi à faire fonctionner le "Is Nothing"
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 If wordApp Is Nothing Then Set wordApp = New Word.Application With wordApp .Visible = True If wordDoc Is Nothing Then Set wordDoc = .Documents.Open _ (ActiveWorkbook.Path & "\Textes marquages Exp Ctrl.docx", False, True) End If .Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage .Activate End With
Avec ça maintenant ça fonctionne à l'ouverture du word (plus d'erreur '91')
Par contre j'ai toujours l'erreur lorsque le word est fermé puis qu'il faut le réouvrir.. c'est bizarre dans le débugage la variable n'affiche rien du tout, comme si elle n'existait plus. :?

Sinon je n'ai pas compris pourquoi tester le nom du document, il n'y a qu'un seul cas possible. :) ?

J'ai modifié et apparemment, je n'ai plus d'erreur :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test1()
    Dim WordApp As Object, WordDoc As Object
    If WordApp Is Nothing Then Set WordApp = New Word.Application
    WordApp.Visible = True
    If WordDoc Is Nothing Then
        Set WordDoc = WordApp.Documents.Open _
        (ActiveWorkbook.Path & "\doctest.docx", False, True)
    ElseIf WordDoc.Name <> "doctest.docx" Then
        Set WordDoc = WordApp.Documents.Open _
        (ActiveWorkbook.Path & "\documentWord.docx", False, True)
    End If
    WordApp.Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage
    Set WordDoc = Nothing
End Sub

Important, quand tu fermes le document il faut mettre :

Code:

1
2
    WordDoc.Close
    Set WordDoc = Nothing

23/11/2012, 19h24
KekeStreet

Je n'ai toujours pas compris le but du "elseif", dans quel cas on l'utilise ?

Pour "Set WordDoc = Nothing" à la fin, ça pose problème : si l'utilisateur ne ferme pas le fichier ça en r'ouvre un nouveau.

Comme tu l'indiques : il faut mettre la variable à nothing quand on ferme le document, mais le document sera toujours fermé par l'utilisateur (petite croix) et jamais par la macro. Alors comment fait-on ? comment je sais que l'utilisateur viens de fermer le document ?

Personne n'a d'idée pour le point 3 ?

Citation:

Pour "Set WordDoc = Nothing" à la fin, ça pose problème : si l'utilisateur ne ferme pas le fichier ça en r'ouvre un nouveau.

Teste ce code qui semble fonctionner (modifie le nom de fichier) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test1()
    If WordApp Is Nothing Then Set WordApp = New Word.Application
    WordApp.Visible = True
    On Error Resume Next
    WordDoc.Activate
    If Err.Number <> 0 Then
        Err.Clear
        Set WordDoc = WordApp.Documents.Open _
        (ActiveWorkbook.Path & "\doctest.docx", False, True)
    End If
    On Error GoTo 0
    Set Var = WordDoc
    WordApp.Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage
End Sub

26/11/2012, 15h00
KekeStreet

Merci pour ton aide, cependant ça ne fonctionne toujours pas chez moi :? : erreur d'execution 462, serveur distant n'existe pas ou n'est pas disponible. c'est la ligne avant le "On Error Resume Next" qui plante, et je ne suis pas parvenu à adapter.

Je pense que pour trouver comment faire il faut savoir ce que devient la variable wordApp une fois que le word est fermée avec la petite croix (le débugage ne m'affiche rien du tout).

Ou alors trouver comment réinitialiser les deux variables, les remettre à zero en cas d'erreur.
26/11/2012, 15h34
Daniel.C

Quelle quiche !

J'ai oublié de te dire qu'il fallait mettre au début d'un module standard :

Code:

Public WordApp As Object, WordDoc As Object

Ceci dit, c'est à adapter à ton appli, car je ne fais que conjecturer sur le code que tu n'as pas posté.

Le seul doute que j'ai c'est la ligne Set Var = wordDoc (je ne comprend pas)

Ma Feuil1 :

Code:

1
2
3
4
5
6
7
8
9
10
11
Private Sub ButtonDualMarking_Click()
    Module1.DisplayMarking (1)
End Sub
 
Private Sub ButtonMilMarking_Click()
    Module1.DisplayMarking (2)
End Sub
 
Private Sub ButtonItarMarking_Click()
    Module1.DisplayMarking (4)
End Sub

Mon Module1 :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Public wordApp As Object
Public wordDoc As Object
 
Sub DisplayMarking(thisPage As Integer)
 
    If wordApp Is Nothing Then Set wordApp = New Word.Application
    wordApp.Visible = True
    On Error Resume Next
    wordDoc.Activate
    If Err.Number <> 0 Then
        Err.Clear
        Set wordDoc = wordApp.Documents.Open _
        (ActiveWorkbook.Path & "\Textes marquages Exp Ctrl.docx", False, True)
    End If
    On Error GoTo 0
    Set Var = wordDoc
    wordApp.Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage
 
End Sub

là y a tout. l'erreur intervient sur wordApp.visible = true
J'avais essayé un peu la gestion d'erreur, je m'y était pris comme ça :
Avec des mix entre les instructions de ErreurHandler, j'ai testé pas mal de trucs différents, j'en ai mis quelques uns là mais rien n'a marché :cry:. (et j'avais déclaré mes objets un peu différemment).

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Public wordApp As Word.Application
Public wordDoc As Word.Document
 
Sub DisplayMarking(thisPage As Integer)
 
    On Error GoTo ErrorHandler
    If wordApp Is Nothing Then Set wordApp = New Word.Application
 
    With wordApp
        .Visible = True
 
        If wordDoc Is Nothing Then
            Set wordDoc = .Documents.Open _
            (ActiveWorkbook.Path & "\Textes marquages Exp Ctrl.docx", False, True)
        End If
 
        .Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage
        .Activate
    End With
 
    Exit Sub
 
ErrorHandler:
    End
    Set wordApp = Empty
    Set wordApp = New Word.Application
    wordApp.Visible = True
    Resume Next
 
End Sub

Salut,
essaye comme cela !

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Public wordApp As Word.Application
Public wordDoc As Word.Document
 
 
 
Private Sub CommandButton1_Click()
Module1.DisplayMarking (1)
End Sub
 
Sub DisplayMarking(thisPage As Integer)
 
    On Error Resume Next
    Set wordApp = GetObject(, "Word.Application")
    If Err Then Set wordApp = New Word.Application
    Err.Clear
    On Error GoTo 0
    With wordApp
        .Visible = True
 
        Set wordDoc = .Documents.Open _
                      (ActiveWorkbook.Path & "\Textes marquages Exp Ctrl.docx", False, True)
 
        .Selection.Goto What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=thisPage
        .Activate
    End With
 
End Sub

Quand tu écris

Citation:

trouve 4 paragraphes (1 par groupe) à copier coller sur les documents classifiés.

ca veut dire quoi copier /coller pour toi ? tu imprimes cette page puis tu la colles physiquement ?

As tu absolument besoin de récupérer ce texte de Word, ne pourrais tu pas avoir un onglet (xl) contenant ces infos ?

27/11/2012, 11h52
KekeStreet

Nickel! ça fonctionne comme je le souhaitais :D merci

J'ai même rajouté une petite gestion d'erreur pour si le fichier n'est pas dans le répertoire et qu'il ne peut pas être ouvert.

Au fait pour la gestion d'erreur (je débute dans ce dommaine) si on en as plusieurs à gérer (voir beaucoup) c'est mieux de faires des On Error Resume Next/On Error Goto0 à chaque fois (donc complication du code) ou la methode avec On Error Goto ErrorHandler et la gestion tout à la fin marche ?

fascinant la gestion d'erreurs :mouarf: ! Je vais en mettre partout maintenant.

Citation:

ca veut dire quoi copier /coller pour toi ? tu imprimes cette page puis tu la colles physiquement ?

Non, copier/coller numérique.

En fait les mecs qui conceptionnent les produits n'y connaissent pas grand chose au controle d'exportation alors je créé des outils "d'assistance à la classification" on va dire.

Selon la classification il faut mettre un certain paragraphe sur les documents, donc la dernière étape (une fois la classification déterminée) c'est que le gars clique sur un bouton, ça lui affiche le bon paragraphe tout de suite, il fait copier/coller et il est content :D

Excel ouep ça aurait marché mais avec Word y a directement la mise en page, la mise en forme et tout qui va bien..