Control si textbox vide

Version imprimable

bonjour au forum,

Je souhaite effectué le control sur des TextBox, si l'une d'elles est vide un message s'affiche et donne le nom du label concerné puis focus et coloration de la TextBox en question. J'arrive a faire une partie mais dans l'état actuel, les deux TextBox sont colorées

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
For Each ctl In Me.Controls
    If TypeOf ctl Is MSForms.TextBox Then
        If ctl.Text = "" Then
'Message disant que Validité est vide
            MsgBox "Saisie incomplète"
                With TxtBoxValidite
                .BorderStyle = 1: .BackColor = RGB(241, 221, 220): .BorderColor = RGB(255, 0, 0)
                .SetFocus
                End With
                With TxtBoxCategorie
                .BorderStyle = 1: .BackColor = RGB(241, 221, 220): .BorderColor = RGB(255, 0, 0)
                .SetFocus
                End With
            Exit Sub
        End If
    End If
Next

Pouvez-vous m'aider svp?

Merci

Stephanie

Bonjour,

Remplace par ceci :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Dim Ctl As Control
 
For Each Ctl In Me.Controls
 
    If TypeOf Ctl Is MSForms.TextBox Then
 
        If Ctl.Text = "" Then
 
            'Message disant que Validité est vide
            MsgBox "Saisie incomplète !"
 
            With Ctl
 
                .BorderStyle = 1
                .BackColor = RGB(241, 221, 220)
                .BorderColor = RGB(255, 0, 0)
                .SetFocus
 
            End With
 
            Exit Sub
 
        Else
 
            'si le contrôle est rempli le remettre comme
            'tu veux qu'il soit...
            With Ctl
 
'                .BorderStyle = 1
'                .BackColor = RGB(241, 221, 220)
'                .BorderColor = RGB(255, 0, 0)
'                .SetFocus
 
            End With
 
        End If
 
    End If
 
Next Ctl

Hervé.

Bonjour Hervé et au forum

Votre solution fonctionne bien mais je suis confronté à un autre problème que je n'avais pas remarqué.

Je fais un premier test en oubliant de remplir TxtBoxCategorie, le message s'affiche puis un second test en oubliant cette fois ci TxtBoxValidite, je constate que dans la liste en feuille3, 2 lignes ont été créée
Colonne K et L
- vide et 12
- légume et vide

Ce que je souhaite obtenir
Colonne K et L
légume 12

Voici le code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Dim ctl As Control
Lign = Sheets("Listes").[K65000].End(xlUp).Row + 1
 
For Each ctl In Me.Controls
    If TypeOf ctl Is MSForms.TextBox Then
        If ctl.Text = "" Then
            'Message disant que Validité est vide
            MsgBox "Saisie incomplète !"
            With ctl
                .BorderStyle = 1
                .BackColor = RGB(241, 221, 220)
                .BorderColor = RGB(255, 0, 0)
                .SetFocus
            End With
            Lign = Sheets("Listes").[K65000].End(xlUp).Row + 1
            Sheets("Listes").Cells(Lign, 11) = TxtBoxCategorie
            Sheets("Listes").Cells(Lign, 12) = TxtBoxValidite
            Exit Sub
        Else
            With ctl
            End With
        End If
    End If
Next ctl

D'où vient le problème ?

Merci

Stephanie

Essaies comme ceci (n'écris sur la feuille que si tous les textbox sont remplis)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Dim Ctl As Control
Dim Lign As Long
Dim Flag As Boolean
 
Lign = Worksheets("Listes").[K65000].End(xlUp).Row + 1
 
For Each Ctl In Me.Controls
    If TypeOf Ctl Is MSForms.TextBox Then
        If Ctl.Text = "" Then
            'Message disant que Validité est vide
            MsgBox "Saisie incomplète !"
            With Ctl
                .BorderStyle = 1
                .BackColor = RGB(241, 221, 220)
                .BorderColor = RGB(255, 0, 0)
                .SetFocus
            End With
            Flag = True
            Exit For
        End If
    End If
Next Ctl
 
If Not Flag Then
    With Worksheets("Listes")
        Lign = .Cells(.Rows.Count, "K").End(xlUp).Row + 1
        .Cells(Lign, 11) = TxtBoxCategorie
        .Cells(Lign, 12) = TxtBoxValidite
    End With
End If

06/11/2012, 12h19
stephadm
Bonjour Hervé, Mercatog et au forum

Ca fonctionne, mais la fenetre se ferme en validant Message

Code:

MsgBox "Saisie incomplète !"

La fenêtre se ferme.

J'ai enlevé aussi

Code:

Lign = Worksheets("Listes").[K65000].End(xlUp).Row + 1

ca fait doublon avec
Code:

1 2 3 4 5 With Worksheets("Listes") Lign = .Cells(.Rows.Count, "K").End(xlUp).Row + 1 .Cells(Lign, 11) = TxtBoxCategorie .Cells(Lign, 12) = TxtBoxValidite End With
Le problème vient surement de

Code:

Unload Me

en fin de macro car si je l'enlève le code de Mercatog fonctionne.

Comment faire pour intégrer la fermeture de l'UserForm à la fin de saisie complète de la fenêtre ?

Merci

Comme ceci?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Dim Ctl As Control
Dim Lign As Long
Dim Flag As Boolean
 
For Each Ctl In Me.Controls
    If TypeOf Ctl Is MSForms.TextBox Then
        If Ctl.Text = "" Then
            'Message disant que Validité est vide
            MsgBox "Saisie incomplète !"
            With Ctl
                .BorderStyle = 1
                .BackColor = RGB(241, 221, 220)
                .BorderColor = RGB(255, 0, 0)
                .SetFocus
            End With
            Flag = True
            Exit For
        End If
    End If
Next Ctl
 
If Not Flag Then
    With Worksheets("Listes")
        Lign = .Cells(.Rows.Count, "K").End(xlUp).Row + 1
        .Cells(Lign, 11) = TxtBoxCategorie
        .Cells(Lign, 12) = TxtBoxValidite
    End With
    Unload Me
End If

06/11/2012, 15h25
stephadm

Bonjour Hervé, Mercatog, et au forum,

Vous m'avez devancé, j'ai trouvé aussi la solution.

Merci à vous.

Stephanie