Procédure select case and like conjuguées

Version imprimable

Bonjour à tous,

J'essaye de créer une base de données qui sera utilisée sous access et renouvellée tous les mois, et mon but est de re-traiter les données en colonne B que je reçois chaque mois (pouvant aller jusqu'a 5-6000 lignes), de manière à pouvoir les utiliser sous access.
Le but est d'afficher une valeur dans la cellule de colonne c en fonction d'une partie du contenu de la cellule de même ligne de colonne b, et comme mes conditions sont nombreuses, j'ai décidé d'écarter les conditions If imbriqués. D'où mon idée d'utiliser Select Case, mais comme ma condition est basée sur une partie de la valeur de la cellule, je dois l'associé à une fonction like.
Voici mon code pour l'instant qui ne marche pas car je sais (désormais) qu'on ne peut pas associer les 2 fonctions.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 Dim sj As Range Dim stdsj As String For Each sj In Range("b2:b20") Select Case sj Case Is = "*CRED MUT*" stdsj = "CREDIT MUTUEL" Case Is = "*CDN*" stsdj = "CREDIT DU NORD" Case Is = "*ALU*" stdsj = "ALCATEL" Case Is = "*BMW*" stdsj = "BMW" Case Is = "*BPCE*" stdsj = "BPCE" Case Is = "*TCH*" stdsj = "TECHNICOLOR" Case Is = "*PEUGEOT*" stdsj = "PEUGEOT" Case Is = "*FRANCE TELECOM*" stdsj = "FRANCE TELECOM" Case Is = "*HSBC*" stdsj = "HSBC" Case Is = "*ING*" stdsj = "ING" Case Is = "*CA*" stdsj = "CREDIT AGRICOLE" Case Is = "*SOCIETE GENERALE*" stdsj = "SOCIETE GENERALE" Case Is = "*GIF*" stdsj = "UBS" Case Is = "*VAG*" stdsj = "VOLKSWAGEN" End Select sj.Offset(0, 1).Value = stdsj Next sj
Je sais que c'est pas possible d'utiliser les 2 procédures en même temps, mais je sèche complétement sur comment faire la procédure autrement, donc si vous avez une idée je suis totalement preneur.

Merci en avance ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub Test()
Dim StDsj As String
Dim Sj As Range
 
For Each Sj In Worksheets("Sheet1").Range("B2:B20")
    Select Case True
        Case Sj Like "*CRED MUT*"
            StDsj = "CREDIT MUTUEL"
        Case Sj Like "*CDN*"
            StDsj = "CREDIT DU NORD"
        Case Sj Like "*ALU*"
            StDsj = "ALCATEL"
        Case Sj Like "*BMW*"
            StDsj = "BMW"
        Case Sj Like "*BPCE*"
            StDsj = "BPCE"
        Case Sj Like "*TCH*"
            StDsj = "TECHNICOLOR"
        Case Sj Like "*PEUGEOT*"
            StDsj = "PEUGEOT"
        Case Sj Like "*FRANCE TELECOM*"
            StDsj = "FRANCE TELECOM"
        Case Sj Like "*HSBC*"
            StDsj = "HSBC"
        Case Sj Like "*ING*"
            StDsj = "ING"
        Case Sj Like "*CA*"
            StDsj = "CREDIT AGRICOLE"
        Case Sj Like "*SOCIETE GENERALE*"
            StDsj = "SOCIETE GENERALE"
        Case Sj Like "*GIF*"
            StDsj = "UBS"
        Case Sj Like "*VAG*"
            StDsj = "VOLKSWAGEN"
    End Select
    Sj.Offset(0, 1).Value = StDsj
    StDsj = ""
Next Sj
End Sub

06/11/2012, 14h42
waaax

Merci beaucoup, je comprends pas trop pourquoi, j'arrivais pas à passer cette syntaxe.
Enfin encore merci tu m'as débloqué.
06/11/2012, 14h54
mercatog

En fait cette écriture est une manière détournée d'utiliser Select Case.
06/11/2012, 15h01
el_slapper

Citation:

Envoyé par mercatog, mon maitre à moi

En fait cette écriture est une manière détournée d'utiliser Select Case.

C'est, en plus, un moyen élégant de ne pas imbriquer les if...else if...else if.... C'est quasiment ma syntaxe préférée en VBA, et elle n'a pas d'équivalent dans bien des langages plus "modernes", genre JAVA ou C# (par contre, en cobol, on a.....).

Quand j'ai une spécification(et ça arrive souvent) qui fait une liste de décisions avec ordre(si on a un client particulier, alors ceci, sinon si on a un client pro sans regroupement, alors celà, sinon si.......), cette liste de décision est souvent présentée sous forme de tableau. Un select case true permet de coder simplement toutes ces conditions successives, et surtout, de le faire en collant à la spec. Ligne à ligne. Quand la spec change, adapter le code devient bien plus facile. Y'a juste à lire la spec. Et la moindre différence saute aux yeux.