Objets controls et multipage

Bonjour à tous,

je dispose d'un multipage sur un userform.

Certaines pages sont masquées

Je souhaite réaliser un contrôle sur les textbox présents sur les pages VISIBLES.

Le but étant de vérifier qu'il existe au moins un textbox par page visible qui soit rempli

J'ai donc commencé à "bricoler" le code ci-après, en intégrant une variable "p" qui s'incrémente à chaque textbox vide des pages visibles
(et si p = le nombre de textbox dont je dispose, j'en déduirais que rien n'est rempli, j'adapterai ensuite cette variable ça c'est pas un souci...)

Malheureusement, je rencontre l'erreur suivante : propriété ou méthode non gérée par cet objet. Ca plante à la ligne 13 qui est en dessous.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 Private Sub CommandButton1_Click() Dim objControlMultiPage As Control Dim objControlPage As Control Dim objControlTxt As Control Dim p As Integer p = 0 For Each objControlMultiPage In UserForm4.Controls If TypeOf objControlMultiPage Is MSForms.MultiPage Then For Each objControlPage In objControlMultiPage If TypeOf objControlPage Is MSForms.Page Then If objControlPage.Visible = True Then For Each objControlTxt In objControlPage If TypeOf objControlTxt Is MSForms.TextBox Then If objControlTxt.Text = "" Then p = p + 1 End If End If Next objControlTxt End If End If Next objControlPage End If Next objControlMultiPage MsgBox p End Sub
Je pense employer à tort un valeur "control" pour les pages de mon multipage

Merci par avance de me remettre dans le droit chemin.

Essaye comme cela :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub CommandButton1_Click()
 
    Dim objControlMultiPage As Object
    Dim objControlPage As Object
    Dim objControlTxt As Control
    Dim p As Integer
 
    p = 0
 
    For Each objControlMultiPage In Me.Controls
        If TypeOf objControlMultiPage Is MultiPage Then
            For Each objControlPage In objControlMultiPage.Pages
                If TypeOf objControlPage Is MSForms.Page Then
                    If objControlPage.Visible = True Then
                        For Each objControlTxt In objControlPage.Controls
                            If TypeOf objControlTxt Is MSForms.TextBox Then
                                If objControlTxt.Text = "" Then
                                    p = p + 1
                                End If
                            End If
                        Next objControlTxt
                    End If
                End If
            Next objControlPage
        End If
    Next objControlMultiPage
 
    MsgBox p
End Sub

Bonjour Oliv-

Et ça a l'air tellement simple présenté comme ça.... :ccool:

Merci beaucoup, je vais devoir sérieusement bûcher sur ces notions de "contrôles" et "objets"

Ta correction de code fonctionne à la perfection

Bonne journée à la communauté !