Simplification et sans les .select ?

Version imprimable

Bonjour.

J'ai une macro qui fonctionne très bien, mais j'aimerais la simplifier et faire en sorte qu'elle s'exécute sans séléctionner les feuilles, car ca me fait un vrai strombinoscope à l'écran à chaque fois :mouarf: !

Je vous la met ici :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Nouvel_Enregistrement()
 
 
For i = 1 To Worksheets.Count - 3 '(J'ai quatorze feuilles, mais la macro ne doit s'éxécuter que sur les 11 premières.
 
    With Worksheets(i)
 
    Worksheets(i).Select
        [A3000].End(xlUp).Select    '(selection de la dernière ligne)
        ActiveCell.Rows("1:2").EntireRow.Select '(Sélection des deux dernières lignes)
        Selection.AutoFill Destination:=ActiveCell.Rows("1:4").EntireRow, Type:= _
            xlFillDefault  ' (Copie incrémenter des deux dernière ligne sur les deux suivantes.
        [B3000].End(xlUp).Select '(Selection de la dernière ligne pour la prochaine fois)
 
End With
 
Next i
 
 
End Sub

En vous remerciant par avance.

Sybiou

22/10/2012, 17h10
joe.levrai

Bonjour,

Si le code te convient en l'état, et que tu veux simplement ne pas voir le travail effectué sur les feuilles, tu peux ajouter :

- au tout début de ton code :

Code:

Application.ScreenUpdating = False

- à la fin de ton code :

Code:

Application.ScreenUpdating = True

Ainsi tu bloques l'affichage de ton classeur durant la macro.

Ca n'enlèvera pas les sélections certes, mais ça va éviter les crises d'épilepsies :ccool:
22/10/2012, 19h00
sybiou

Merci Bcp, c'est déja plus confortable.

Reste à voir pour la simplification, je ne mets pas pour autant résolu.

bonne soirée à toi.

Sybiou

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Sub Nouvel_Enregistrement()
Dim LastLig As Long
Dim i As Integer
 
Application.ScreenUpdating = False
For i = 1 To Worksheets.Count - 3                  '(J'ai quatorze feuilles, mais la macro ne doit s'éxécuter que sur les 11 premières.
    With Worksheets(i)
        LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
        .Rows(LastLig).Resize(2).AutoFill .Rows(LastLig).Resize(4)
    End With
Next i
End Sub

22/10/2012, 19h48
sybiou

Un grand merci, M'sieur !

Je mets en résolu.

bonne soirée à tous.

Sybiou