Concaténation de tableau via macro

Version imprimable

11/10/2012, 15h58
chtrousselle

1 pièce(s) jointe(s)

Concaténation de tableau via macro

Bonjour,
J'ai un tableau dans une feuille1
et un deuxieme dans une feuille2

Je souhaites mettre les tableaux les uns en dessous des autres dans une feuille3 via une macro.
Pour cela je dois selectionner la taille exacte de chaque tableau (pour ne pas prendre en compte les lignes vides, comment faire ?
J'ai mis un exemple en PJ de ce que je voudrais
Désolé pour mon faible niveau en Macro

Cordialement

Salut, voir ici
ce qui adapté à ton cas donnera ceci, à noter que j'ai laissé comme dernière colonne la colonne J que tu pourras remplacer par C dans ton cas.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Sub ConcatenationFeuilles()
Dim i As Long, T() As Variant
 
    Application.ScreenUpdating = False
    Feuil3.Cells.Clear
    For i = 1 To Sheets.Count
        If Sheets(i).Name <> Feuil3.Name Then
            With Sheets(i)
                T = .Range("A1:J" & .Range("A" & Rows.Count).End(xlUp).Row).Value
                Feuil3.Range("A" & Rows.Count).End(xlUp).Offset(1).Resize(UBound(T, 1), UBound(T, 2)) = T
            End With
        End If
    Next i
    Erase T
    With Feuil3
        .Rows("1:1").Delete Shift:=xlUp
        .Range("D1").Select
    End With
    Application.ScreenUpdating = True
End Sub

Ensuite il faudra sauver ton fichier en xlsm,xlsb bref des formats admettant les macros ce qui n'est pas le cas du format xlsx

Une autre façon d'y parvenir, quand il y a de grande quantité de données à fusionner la méthode ci-dessus est plus rapide.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Sub ConcatenationFeuilles()
Dim i As Long
Dim LastRow As Long
 
    Application.ScreenUpdating = False
    Feuil3.Cells.Clear
 
    For i = 1 To Worksheets.Count
        If Worksheets(i).Name <> Feuil3.Name Then
            LastRow = Feuil3.Range("A" & Rows.Count).End(xlUp).Row + 1
            Worksheets(i).UsedRange.Copy Feuil3.Range("A" & LastRow)
        End If
    Next i
 
    With Feuil3
        .Rows("1:1").Delete Shift:=xlUp
        .Range("D1").Select
    End With
 
    Application.ScreenUpdating = True
End Sub

11/10/2012, 16h59
chtrousselle

Merci beaucoup c'est exactement ça !
Comment choisir que certaine feuille et pas la totalité ?

Merci
11/10/2012, 17h11
kiki29

re, il te faudra modifier If Worksheets(i).Name <> Feuil3.Name Then qui balaye toutes les feuilles sauf celle on l'on effectue la fusion.
par qqch comme ceci, qui ne fusionnera que les feuilles zaza et zozo
If Worksheets(i).Name = "zaza" Or Worksheets(i).Name = "zozo" Then

Merci beaucoup !

J'ai fais comme tu m'as dit

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Sub ConcatenationFeuilles()
Dim i As Long, T() As Variant
 
    Application.ScreenUpdating = False
    Feuil3.Cells.Clear
    For i = 1 To Sheets.Count
        If Worksheets(i).Name = "Feuil1" Or Worksheets(i).Name = "Feuil2" Then
            With Sheets(i)
                T = .Range("A1:P" & .Range("A" & Rows.Count).End(xlUp).Row).Value
                Feuil3.Range("A" & Rows.Count).End(xlUp).Offset(1).Resize(UBound(T, 1), UBound(T, 2)) = T
            End With
        End If
    Next i
    Erase T
    With Feuil3
        .Rows("1:1").Delete Shift:=xlUp
        .Range("D1").Select
    End With
    Application.ScreenUpdating = True
End Sub

mais j'ai l'erreur suivante pour .Range("D1").Select
"La méthode Select de la classe Range a échoué"...

Salut le forum

Tu ne peux sélectionner une cellule que si la feuille est sélectionnée
Code:

1 2 3 4 5 6 7 8 '... With Feuil3 .Activate .Rows("1:1").Delete Shift:=xlUp .Range("D1").Activate End With '...
Mytå_Qc

J'ai le problème suivant :
J'ai renomé mes feuilles en F1 F2 et F3

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Sub ConcatenationFeuilles()
Dim i As Long, T() As Variant
Dim F3 As Worksheet 
 
    Application.ScreenUpdating = False
    F3.Cells.Clear
    For i = 1 To Sheets.Count
        If Worksheets(i).Name = "F1" Or Worksheets(i).Name = "F2" Then
            With Sheets(i)
                T = .Range("A1:P" & .Range("A" & Rows.Count).End(xlUp).Row).Value
                F3.Range("A" & Rows.Count).End(xlUp).Offset(1).Resize(UBound(T, 1), UBound(T, 2)) = T
            End With
        End If
    Next i
    Erase T
    With F3
        .Rows("1:1").Delete Shift:=xlUp
        .Range("D1").Select
    End With
    Application.ScreenUpdating = True
End Sub

Il me dit ne pas connaitre les feuilles alors que je les ai déclaré, une idée ?

Merci

12/10/2012, 12h46
kiki29

Salut, supprime la déclaration F3 As Worksheet
Dans le code fourni F3 est le CodeName de la feuille de fusion, F1 et F2 le nom d'onglet.
Par défaut, à la création d'un classeur, les CodeName et les noms d'onglet sont les mêmes.
L'utilisation du CodeName présente l'avantage de ne pas avoir à retoucher au code VBA si l'utilisateur change les noms d'onglet, déplace ou ajoute des feuilles.