Envoie de fichier Excel

Version imprimable

21/09/2012, 10h09
bigokou

Envoie de fichier Excel

Bonjour je me presente big bigokou pour les intimes voila je démarre sur vba et j essaie de créer des codes en auto didact c est pas facile mais j arrive a me debrouiller la je suis bloqué car j aimerais avoir de l aide pour envoye des fichier excel trier par correspondant budgétaire et l'élement déclencheur serait à relancer qui peut m aider????:cry::cry::cry::cry::cry:
21/09/2012, 11h30
Daniel.C

Bonjour,

Peux-tu donner un exemple de ce que tu veux faire ?
21/09/2012, 12h37
bigokou

bonjour merci de me repondre je voudrais par exemple selectionne pour pascal roehr toutes les factures qui sont à relancer et lui envoye un mail avec un message, ainsi que pour tous les autres correspondant ...:oops::oops:
21/09/2012, 14h47
Daniel.C

1. Quelle est ta version d'Excel ?
2. Quel est ton logiciel de messagerie ?
21/09/2012, 15h07
bigokou

excel 2007 et outlook 2007

Regarde le code suivant. Pour chaque message, les factures sont dans un classeur en pièce jointe. C'est plus compliqué de les incorporer dans le texte du message.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub EnvoiMail()
    Dim C As Range, Plage As Range, Factures As Range, Plage2 As Range
    Dim OlApp As Object, M As Object, Wbk As Workbook
    Set OlApp = CreateObject("Outlook.application")
    With Sheets("DOMAINE")
        Set Plage = .Range(.[A2], .Cells(.Rows.Count, 1).End(xlUp))
    End With
    With Sheets("Justif")
        Set Factures = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 11)
        For Each C In Plage
            .AutoFilterMode = False
            Factures.AutoFilter 5, C.Value
            Factures.AutoFilter 10, "à relancer"
            Set Plage2 = Factures.Offset(1).Resize(Factures.Rows.Count - 1, 1)
            If Application.Subtotal(103, Plage2) > 0 Then
                Set Plage2 = Factures.SpecialCells(xlCellTypeVisible)
                Set M = OlApp.CreateItem(olMailItem)
                Set Wbk = Workbooks.Add(1)
                Plage2.Copy Wbk.Sheets(1).[A1]
                On Error Resume Next
                Kill ThisWorkbook.Path & "\" & "temp.xls"
                Wbk.SaveAs ThisWorkbook.Path & "\" & "temp", FileFormat:=xlExcel8
                Wbk.Close False
                On Error GoTo 0
                With M
                    .Subject = "Objet"
                    .Body = "Message"
                    .Recipients.Add C.Offset(, 2).Value
                    .attachments.Add ThisWorkbook.Path & "\" & "temp.xls"
                    '.Display
                    .Send
                End With
                Kill ThisWorkbook.Path & "\" & "temp.xls"
            End If
        Next C
    End With
End Sub

24/09/2012, 09h27
bigokou

ok super ca marche mais il sarrete pas!!!!:?:?:?:?:?
24/09/2012, 09h56
Daniel.C

Est-ce que tu peux expliquer ce qui ne s'arrête pas ?
24/09/2012, 10h00
bigokou

ok lorsque je lance ma macro il me prend bien en compte les facture a relancer puis il envoie les mail sauf que lorsqu il a fini de d envoyer les mails il continue a tourne dans le fichier sa ne s arrete pas il faut que j arrete la macro et il se bloque sur cette ligne de code

Factures.AutoFilter 10, "à relancer"

Merci à toi c est vraiment super sympa de m aider

Bien, le problème vient indirectement du fait que tu as défini le tableau "MyPlage" jusqu'à la dernière ligne de la feuille. Tu n'as pas besoin de le faire. Définis-le jusqu'à la dernière ligne de données et il se dimensionnera automatiquement quand tu ajouteras ou supprimeras des lignes. Quoi qu'il en soit, j'ai modifié la macro, donc tu n'as pas besoin de modifier autre chose :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub EnvoiMail()
    Dim C As Range, Plage As Range, Factures As Range, Plage2 As Range
    Dim OlApp As Object, M As Object, Wbk As Workbook
    Set OlApp = CreateObject("Outlook.application")
    With Sheets("DOMAINE")
        Set Plage = .Range(.[A2], .[A:A].Find("*", , , , xlByRows, xlPrevious))
    End With
    With Sheets("Justif")
        Set Factures = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 11)
        For Each C In Plage
            .AutoFilterMode = False
            Factures.AutoFilter 5, C.Value
            Factures.AutoFilter 10, "à relancer"
            Set Plage2 = Factures.Offset(1).Resize(Factures.Rows.Count - 1, 1)
            If Application.Subtotal(103, Plage2) > 0 Then
                Set Plage2 = Factures.SpecialCells(xlCellTypeVisible)
                Set M = OlApp.CreateItem(olMailItem)
                Set Wbk = Workbooks.Add(1)
                Plage2.Copy Wbk.Sheets(1).[A1]
                On Error Resume Next
                Kill ThisWorkbook.Path & "\" & "temp.xls"
                Application.DisplayAlerts = False
                Wbk.SaveAs ThisWorkbook.Path & "\" & "temp", FileFormat:=xlExcel8
                Application.DisplayAlerts = True
                Wbk.Close False
                On Error GoTo 0
                With M
                    .Subject = "Objet"
                    .Body = "Message"
                    .Recipients.Add C.Offset(, 2).Value
                    .attachments.Add ThisWorkbook.Path & "\" & "temp.xls"
                    '.Display
                    '.Send
                End With
                Kill ThisWorkbook.Path & "\" & "temp.xls"
            End If
        Next C
        .AutoFilterMode = False
    End With
End Sub

24/09/2012, 11h39
bigokou

désolé mais la par contre il envoie rien
24/09/2012, 11h57
Daniel.C

Oui, bien sûr, pour tester, j'avais mis en commentaire :

Code:

'.Send

Il faut retirer l'apostrophe qui est devant :

Code:

.Send
24/09/2012, 12h01
bigokou

ou avais la tete merci c niquel mais j ai encore un dernier sourcis c est que je veux mettre un message dans body mais lorsque je le mets ca bloque
24/09/2012, 15h09
Daniel.C

Tu ne peux mettre que du texte -ou alors c'est plus compliqué. Que veux-tu mettre ?
24/09/2012, 15h27
bigokou

ca y est merci j ai reussi a mettre un texte avec les chr13 et chr10 merci quand meme mais si tu pouvais m aider sur l autre la je bloque carement merci beaucoup en tout cas c est cool
24/09/2012, 17h24
Daniel.C

L'autre quoi ?