Excel commande word

Version imprimable

Bonjour,

Voici que je souhaite obtenir :

J'ai des fiches avec des photos + descriptions de petites voitures. Ces fiches sont en format Word.
J'ai fait une boucle, qui répertorie toutes les fiches, les ouvre, copie/colle le document word et extrait le contenu pour le mettre sous format tableau : colonne/ligne.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
Sub MAJ()
    Dim Chemin As String
    Dim Fichier As String
    Dim WordApp As Word.Application
    Dim WordDoc As Word.Document
 
    Dim DerniereLignefichiers As Integer
    Dim DerniereLignefiches As Integer
 
    Dim i As Integer
    Dim j As Integer
    Dim k As Integer
 
 
    'efface données Liste
    DerniereLignefiches = Sheets("Liste").Range("A65536").End(xlUp).Row
    Range(Cells(2, 1), Cells(DerniereLignefiches, 68)).Select
    Selection.ClearContents
    Range("A2").Select
 
     'efface données Fichiers
     Sheets("Fichiers").Select
    Cells.Select
    Selection.ClearContents
    Range("A1").Select
 
    'Efface données Temp
     Sheets("Temp").Select
    Cells.Select
    Selection.Delete Shift:=xlUp
    Range("A1").Select
 
 
    'lecture des fichiers
 
    'Définit le répertoire contenant les fichiers
    Chemin = ThisWorkbook.Path & "\Fiches"
 
    Fichier = Dir(Chemin & "\*.doc")
 
 
 
    Do While Len(Fichier) > 0
       i = i + 1
 
        Sheets("Fichiers").Cells(i, 1) = Fichier
         Fichier = Dir()
    Loop
 
 
    ' Lecture / Ecriture des fiches
 
 
    DerniereLignefichiers = Sheets("Fichiers").Range("A65536").End(xlUp).Row
 
    'Boucle sur fichiers
    For j = 1 To DerniereLignefichiers
 
 
 
    Fichier = ThisWorkbook.Path & "\Fiches\" & Sheets("Fichiers").Cells(j, 1)
 
    'creation session Word
    Set WordApp = New Word.Application
    'pour que word reste masqué pendant l'opération
    WordApp.Visible = False
    'ouverture du fichier Word
    Set WordDoc = WordApp.Documents.Open(Fichier)
 
    'copie le premier tableau Word
    WordDoc.Range.Copy
 
    'Enleve message alerte
    Application.DisplayAlerts = False
 
    'colle
    Sheets("Temp").Paste
        Stop
    'ferme le document Word sans sauvegarde
    WordDoc.Close False
    'ferme l'application Word
    WordApp.Quit
 
    'ajout dans "fiches"
    DerniereLignefiches = Sheets("Liste").Range("A65536").End(xlUp).Row
 
    k = j 'DerniereLignefiches + 1 'incrémente
 
‘Différentes formules’ pour récupérer les cases de word’’’’’’’
 
  'Efface données Temp
     Sheets("Temp").Select
    Cells.Select
    Selection.Delete Shift:=xlUp
    Range("A1").Select
 
    Next
 
    MsgBox ("Fini")
End Sub

.

J'aimerai qu'en même temps, c'est à dire lorsque le document word est ouvert, que le VBA l'enregistre au format PDF. J'ai trouvé sur la FAQ le code pour Word, mais il ne fonctionne pas sous Excel. et dans la FAQ Excel, lorsque je fais

Code:

1
2
 ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _

, il me met, "membre de méthode ou de données introuvable".

De même, j'aimerai qu'il enregistre la fiche au format "html", car ça me permet de retrouver les photos de la fiche....(méthode plus rapide que celle que j'avais trouvé dans mon dernier post...:aie:)

Ensuite le code, fermerait le PDF, le html.

Pensez-vous qu'il soit donc possible de "commander" Word lorsqu'on est sous Excel, et si oui, comment dois-je procéder ?

Une idée ?

En fait, je pourrais reformuler ma question :

lorsque je suis dans une macro Excel, j'ai la possibilité d'ouvrir Word, mais puis-je faire tourner une macro Word ?

Merci,
A+

Bonjour,

Teste ceci :

Code:

1
2
3
4
5
6
7
8
9
10
Sub test()
'nécessite d'activer la référence "Microsoft Word xx.x Object Library"
Dim wApp As Word.Application, wDoc As Word.Document
 
Set wApp = New Word.Application
wApp.Visible = True
Set wDoc = wApp.Documents.Open("Chemin_Complet\Nom_Fichier_Word.doc")
 
wApp.Run "NomMacroWord"
End Sub

22/09/2012, 13h27
ericdev67

Merci Fring :ccool:,

Mais si je comprends bien, cela signifie que ma macro soit présente dans ma fiche...et là, j'en ai environ 500...donc il faudrait que je copie/colle la macro dans chacune des fiches....
Il n'y aurait pas un autre "moyen" ?

J'en vois bien 1 : ouvrir un fichier Word (admettons "Fichier avec macro"), dans lequel je mets la macro, et ensuite,je fais une boucle : j'ouvre ma fiche, je fais tourner la macro sur la fiche, je la ferme, j'ouvre la suivante, même opération et ainsi de suite....mais est-ce possible ?

Merci,
A+
22/09/2012, 17h39
fring

Citation:

Envoyé par ericdev67

Mais si je comprends bien, cela signifie que ma macro soit présente dans ma fiche...

Non mais je répondais à ta question...

Citation:

Envoyé par ericdev67

puis-je faire tourner une macro Word ?

Tu peux piloter Word depuis Excel, tu as quelques exemples ICI
22/09/2012, 19h17
ericdev67

Merci Fring,

Comme tu l'as peut-être constaté dans mon code, j'avais déjà utilisé l'excellent tuto du non moins excellent Silkyroad :ccool: (ces tutos m'ont souvent beaucoup aidé...) : connexion à Word, ouverture, et récupération des données. J'ai pris l'option copié/collé.
En fait, là où je coince, c'est que : le document Word est ouvert, il faudrait que je puisse faire tourner une macro Word (enregistrement du .doc en PDF, et enregistrement du .doc en .HTML) , tu m'as déjà montré comment faire tourner la macro à partir d'excel, mais comme je le disais, dans mon Doc ouvert, il n'y a pas initialement de macro...il faudrait donc (peut-être que j'ai un .doc ouvert avec les macros et qui fasse tourner les macros sur le .doc ouvert....

Merci,
A+

Pour imprimer un doc Word en PDF, tu peux t'inspirer là --> Impression Document Word en PDF

En reprenant mon petit test ci-dessus, pour enregistrer le doc au format HTML ça donne :
Code:

1 2 3 4 5 6 7 8 9 10 Sub test() 'nécessite d'activer la référence "Microsoft Word xx.x Object Library" Dim wApp As Word.Application, wDoc As Word.Document Set wApp = New Word.Application wApp.Visible = True Set wDoc = wApp.Documents.Open("Chemin_Complet\Nom_Fichier_Word.doc") wDoc.SaveAs Filename:="Chemin_Complet\Nom_Fichier.html", FileFormat:=wdFormatHTML End Sub

24/09/2012, 17h32
ericdev67

Une fois de plus, je te remercie Fring,

J'ai essayé pour le format HTML, ça fonctionne super :ccool:, par contre, je peux pas faire tourner le code de KIKI29, car dans mon OUTILS/references/, je n'ai pas Distiller.....(et j'ai essayé avec tout : PDFCreator, PDFFilter, Acrobat, ...) et donc le code se met en erreur au niveau

Code:

PDFDist As PdfDistiller

, car il ne "connait" pas l'instruction....

Une idée ?

Merci,
A+

Distiller fait partie de la version complète (et payante) d'Adobe.

Si tu as Office 2007 (ou plus récent) tu peux directement convertir le document Word en Pdf sans passer par un autre logiciel
Code:

1 2 3 4 5 6 7 8 9 10 Sub testPDF() 'nécessite d'activer la référence "Microsoft Word xx.x Object Library" Dim wApp As Word.Application, wDoc As Word.Document Set wApp = New Word.Application wApp.Visible = True Set wDoc = wApp.Documents.Open("Chemin_Complet\Nom_Fichier_Word.doc") wDoc.ExportAsFixedFormat OutputFileName:="Chemin_Complet\Nom_Fichier.pdf", ExportFormat:=wdExportFormatPDF End Sub

25/09/2012, 18h57
ericdev67

Merci Fring,

J'ai mis un peu de temps à répondre car j'ai voulu tester ton code sur différentes versions Excel que j'avais (perso/boulot)....et j'ai beau cocher dans outils/préférences, les modules PDFCreator, PDF...,Abode, etc..., à chaque fois le code s'arrête à la ligne

Code:

ExportFormat:=wdExportFormatPDF

, en disant : "fonctionnalité non installée", alors que j'ai coché tous les modules disponibles.....

Une idée ?

Merci,
A+
25/09/2012, 20h00
kiki29

Salut il te faut Office 2007 SP2 minimum pour avoir en natif le format PDF. Sinon tu dois installer par exemple PDFCreator ( gratuit ) pour pouvoir générer du PDF.
25/09/2012, 20h04
ericdev67

Merci kiki29,

au boulot (sous excel 2003-2007), dans Outil/référence, j'ai coché PDFcreator, et ça n'a pas fonctionné.......PDFcreator est bien installé (puisqu'en imprimante virtuelle, je peux bien créer/imprimer un document en PDF.....).

Je ne comprends pas......:aie:

A+

Salut, utilise l'enregistreur de macros en sélectionnant l'imprimante PDFCreator et regarde le code généré. Cela donne brut de fonderie qqch comme

Code:

1
2
3
4
5
6
    ActivePrinter = "PDFCreator"
    Application.PrintOut FileName:="", Range:=wdPrintAllDocument, Item:= _
        wdPrintDocumentContent, Copies:=1, Pages:="", PageType:=wdPrintAllPages, _
        ManualDuplexPrint:=False, Collate:=True, Background:=True, PrintToFile:= _
        False, PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
        PrintZoomPaperHeight:=0

25/09/2012, 20h14
ericdev67

Merci kiki29,

au boulot (sous excel 2003-2007), dans Outil/référence, j'ai coché PDFcreator, et ça n'a pas fonctionné.......PDFcreator est bien installé (puisqu'en imprimante virtuelle, je peux bien créer/imprimer un document en PDF.....). A la maison, je n'ai pas le module PDFcreator, (excel 2012 MAC), donc, j'ai coché tous les modules pouvant "ressembler" à PDF (PDFview,....et Abode.....)

Je ne comprends pas......:aie:

A+
25/09/2012, 20h18
kiki29

Re, désolé, aucune idée pour le Mac, je n'en ai pas utilisé depuis plus de 10 ans.
25/09/2012, 20h26
ericdev67

Merci kiki29,

Il y a eu un problème lorsque j'ai voulu éditer mon message.....donc ta réponse s'est croisée avec mes éditions....

Effectivement, je pense que sous MAC, les problèmes s'aggravent.....je teste ta technique demain au boulot, et ferai un copier/coller de l'éditeur de macro.....

Je te tiens informé.

Merci pour tes bons conseils et encore félicitations pour tes tuto (dont les codes m'ont plusieurs fois aidé....:P )

Merci,

A+ :ccool:
25/09/2012, 20h40
kiki29

Re, une erreur 500 sur le serveur ....
sinon merci en espérant que tu as voté pour ces bribes de code ?
Une recherche sur Office 2012 PDF sur le Web t'apporterait peut-être une réponse
26/09/2012, 20h05
ericdev67

Ok kiki29,

J'ai eu des pb de connexion, d'où le manque de votes, mais résolu depuis....;)

Je teste et te tiens informé :ccool:

A+

Merci kiki29,

J'ai essayé avec l'assistant macro + ton code, ça ne fonctionne pas... : j'ai ma macro excel (qui ouvre un document word), et quand je fais ton code et/ou l'assistant, il n'exporte pas vers PDF, car il reste sous excel.....alors qu'il faudrait qu'il aille sous word.....

En fait le code de Fring paraissait "idéal", car, à partir d'excel, il enregistre/exporte en PDF. Ca fonctionne super bien avec l'enregistrement sous format HTML, mais son code (du moins, avec les Outils/références à ma dispo), ne fonctionne pas pour PDF.....

J'ai l'impression qu'il va falloir que j'ouvre en permanence un document Word, dans lequel je mets un code pour un export en PDF, et que dans ma macro excel, je fasse appel à la macro de word.....

Qu'en pensez vous ?

C'est vraiment dommage.....mais je me demande si l'instruction

Code:

wDoc.ExportAsFixedFormat OutputFileName:="Chemin_Complet\Nom_Fichier.pdf", ExportFormat:=wdExportFormatPDF

puisse être modifiée, car c'est apparemment

Code:

wdExportFormatPDF

qui pose problème.....il n'y a pas une autre instruction possible ?

Merci,

A+
26/09/2012, 20h38
fring

Citation:

Envoyé par ericdev67

En fait le code de Fring paraissait "idéal", car, à partir d'excel, il enregistre/exporte en PDF. Ca fonctionne super bien avec l'enregistrement sous format HTML, mais son code (du moins, avec les Outils/références à ma dispo), ne fonctionne pas pour PDF.....

Je vois que tu as Excel 2007, avec Office 2007 (ou +) tu n'as besoin d'aucune référence, c'est natif (à condition bien sûr d'utiliser également Word 2007).
J'ai testé avant de te proposer le code et l'enregistrement du doc au format pdf fonctionne très bien et ce à partir d'Excel, sans aucune macro dans Word.
26/09/2012, 22h15
kiki29

Salut, à titre de curiosité VBA Excel 2011 Mac, il faut passer par de l'AppleScript

merci fring,

j'ai essayé , mais ça ne fonctionne pas....malgré que j'ai les références word et pdfcreator...ci joint le bout de code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
ficheHT = ThisWorkbook.Path & "\Fiches format HTML\"
    fichePD = ThisWorkbook.Path & "\Fiches format PDF\"
 
    'creation session Word
    Set WordApp = New Word.Application
    'pour que word reste masqué pendant l'opération
    'WordApp.Visible = False
    WordApp.Visible = True
    'ouverture du fichier Word
    Set WordDoc = WordApp.Documents.Open(Fichier)
 
    'copie le premier tableau Word
    WordDoc.Range.Copy
 
    'Enleve message alerte
    Application.DisplayAlerts = False
 
    'colle
    Sheets("Temp").Paste
 
    WordDoc.SaveAs Filename:=ficheHT & nomfiche & ".html", FileFormat:=wdFormatHTML
 
   Stop
 
    WordDoc.ExportAsFixedFormat OutputFileName:=fichePD & nomfiche & ".pdf", ExportFormat:=wdExportFormatPDF

il fonctionne bien jusqu' au "stop" (pour voir si tout est nickel avant..).et ensuite, il s'arrête en disant "Propriété ou méthode non gérée par cet objet"....
comprends pas...
si tu pouvais me dire où ça coince...
merci :ccool:
À+

merci kiki29,
je vais rester sous windows car j'ai déjà pu constater des pb de compatibilité avec Mac

Merci pour le lien ;)

A+

je préfère mettre une partie du code, avec les déclarations de variables et leurs valeurs, peut-être que c'est là où il y a un problème.....

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
    Dim nomfiche As String
    Dim fiche As String
    Dim ficheHT As String
    Dim fichePD As String
 
 
    'défini les chemins
    Fichier = ThisWorkbook.Path & "\Fiches\" & Sheets("Fichiers").Cells(j, 1)
    Sheets("Fichiers").Select
    Range(Cells(j, 2), Cells(j, 2)).Select
    ActiveCell.FormulaR1C1 = "=LEFT(RC[-1],FIND(""."",RC[-1])-1)"
    nomfiche = Sheets("Fichiers").Cells(j, 2)
    fiche = ThisWorkbook.Path & "\Fiches\" & Sheets("Fichiers").Cells(j, 2)
 
    ficheHT = ThisWorkbook.Path & "\Fiches format HTML\"
    fichePD = ThisWorkbook.Path & "\Fiches format PDF\"
 
    'creation session Word
    Set WordApp = New Word.Application
    'pour que word reste masqué pendant l'opération
    'WordApp.Visible = False
    WordApp.Visible = True
    'ouverture du fichier Word
    Set WordDoc = WordApp.Documents.Open(Fichier)
 
    'copie le premier tableau Word
    WordDoc.Range.Copy
 
    'Enleve message alerte
    Application.DisplayAlerts = False
 
    'colle
    Sheets("Temp").Paste
 
    WordDoc.SaveAs Filename:=ficheHT & nomfiche & ".html", FileFormat:=wdFormatHTML
 
   ' WordDoc.SaveAs Filename:=fichePD & nomfiche & ".html", FileFormat:=wdFormatHTML
 
   ' Set wdoc = wApp.Documents.Open("Chemin_Complet\Nom_Fichier_Word.doc")
 
   Stop
 
    WordDoc.ExportAsFixedFormat OutputFileName:=fichePD & nomfiche & ".pdf", ExportFormat:=wdExportFormatPDF

Merci,
A+

J'ai retapé le code complètement (peut-être y avait-il une erreur dans le copier/collé)....je lance le code et il me dit

"L'exportation a échoué car cette fonctionnalité n'est pas installée"

alors que la référence "Microsoft Word 12.0 Object Library" est installée....

Comprends pas ce qui se passe.......:aie:

Merci pour votre aide

28/09/2012, 22h37
fring

En manuel, dans Word, tu n'arrives pas enregistrer un document au format PDF non plus ?
29/09/2012, 08h17
ericdev67

Merci Fring,

En manuel, sous word ou excel, je ne peux pas enregistrer en PDF, il faut que je fasse "imprimer" et que je sélectionne l'imprimante virtuelle "PDFCreator".....

Et en te répondant, je commence à comprendre ce qui a pu se passer : étant donné que ma version de Excel n'offre pas la possibilité "d'enregistrer sous... PDF" , ton code ne peut pas fonctionner....alors qu'avec HTML, ça fonctionne puisqu'il apparait dans "enregistrer sous....HTML"

Donc, en fait, il faudrait passer par l'imprimante virtuelle....c'est à dire que l'"Export"

Code:

WordDoc.ExportAsFixedFormat OutputFileName:=fichePD & nomfiche & ".pdf", ExportFormat:=wdExportFormatPDF

doit être remplacé par "PRINT"....

Mais si c'est ça, j'aurai besoin que tu m'aides car hier j'ai fait F2 pour trouver des instructions concernant PDF, et je n'ai rien trouvé.....qui a fonctionné....:aie:

Merci,

A+
29/09/2012, 08h26
kiki29

Salut, bis repetita placent ... Cette formulation est pour Excel PC 2007+.
Utilise l'enregistreur de macros en sélectionnant l'imprimante PDFCreator et tu auras le code correspondant.
29/09/2012, 08h46
ericdev67

Merci kiki29,

J'avais déjà suivi ton conseil, (avec l'enregistreur de macro), je sais donc comment écrire mon imprimante virtuelle. Par contre c'est le code qui pose problème : la macro word ne peut pas être mise dans VBA excel, et donc, soit je crée et j'ouvre en permanence un fichier word avec la macro d'impression en PDF et je la fait tourner pour ma fiche, soit il a une autre solution (et c'est celle-là que je cherche.....:mouarf:)

Merci,
A+

Salut, voir ceci : exécuter macro Word à partir d'excel

Re, ici cela fonctionne

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
 
Sub Imprimer_DocWordDepuisExcel()
Dim AppWord As Object
Dim sChemin As String
Dim sPrinterDefault As String
 
    sChemin = ThisWorkbook.Path & "\" & "Test.doc"
 
    Set AppWord = CreateObject("Word.Application")
    sPrinterDefault = AppWord.ActivePrinter
 
    AppWord.ActivePrinter = "PDFCreator"
 
    With AppWord.Documents.Open(sChemin)
        .PrintOut Background:=False, Copies:=1
        .Close False
    End With
 
    AppWord.ActivePrinter = sPrinterDefault
    AppWord.Quit
 
    Set AppWord = Nothing
End Sub

29/09/2012, 11h50
ericdev67

super kiki29,

exactement ce que je cherchais à faire !!!

j'ai juste une dernière petite galère...: au moment de l'impression en imprimante virtuelle, je suis obligé de valider = "enregistrer " + définir chemin du fichier pdf

j'ai essayé de mettre

Code:

application .displayalert =true

ça ne fonctionne pas...idem avec "false "....

il n'y à pas moyen de valider automatiquement et d'indiquer le chemin de l'emplacement du pdf ??

merci,
À+
29/09/2012, 12h01
kiki29

Salut, il te faut paramétrer PDFCreator
Aller dans le dossier d'installation

• Lancer le moniteur d'impression PDFCreator.exe

Puis dans Menu Imprimante
• Options
• Enregistrement Automatique

Cocher
• Utiliser l'enregistrement automatique
• Utiliser ce répertoire pour l'enregistrement automatique
chez moi tous les PDF ( Adobe Acrobat, PDFCreator ) vont dans
C:\Documents and Settings\Philippe\Mes documents\PdfOut\
• Cliquer sur le bouton Enregistrer
29/09/2012, 12h30
ericdev67

ça fonctionne pile - poil !!!:ccool:

merci kiki29 :ccool:

dois-je en conclure qu' on ne peut pas mettre ces "arguments " (enregistrement et chemin) dans le code VBA et que donc, il faut modifier "manuellement " le chemin ?

merci,
À+

Salut, oui cela est faisable, livré brut de fonderie.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
Option Explicit
 
Sub Imprimer_PDFCreator_SelFichier()
Dim sDossier As String
Dim FD As FileDialog, sNomPDF As String
 
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "Documents Word", "*.doc*", 1
        If .Show <> -1 Then Exit Sub
        DoEvents
    End With
 
    sNomPDF = "Test Word.pdf"
    sDossier = ThisWorkbook.Path & "\"
    PdfCreator FD.SelectedItems(1), sNomPDF, sDossier
End Sub
 
Private Sub PdfCreator(sNomFichier As String, sNomFichierOutPDF As String, sDossier As String)
Dim jobPDF As Object
Dim AppWord As Object
Dim sPrinterDefault As String
 
    Set jobPDF = CreateObject("PDFCreator.clsPDFCreator")
    Set AppWord = CreateObject("Word.Application")
 
    With jobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sDossier
        .cOption("AutosaveFilename") = sNomFichierOutPDF
 
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx,
        '   5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With
 
    sPrinterDefault = AppWord.ActivePrinter
    AppWord.ActivePrinter = "PDFCreator"
 
    With AppWord.Documents.Open(sNomFichier)
        .PrintOut Background:=False, copies:=1
        .Close False
    End With
 
    DoEvents
 
    With AppWord
        .ActivePrinter = sPrinterDefault
        .Quit
    End With
 
    Set AppWord = Nothing
 
    Do Until jobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
 
    jobPDF.cPrinterStop = False
    Do Until jobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
 
    jobPDF.cClose
    Set jobPDF = Nothing
End Sub
 
Private Sub KillPDFCreator()
Dim RetVal As Long
    RetVal = Shell("Taskkill /im PDFCreator.exe /f", 0)
End Sub

A titre purement documentaire : Imprimez vos documents Word au format PDF à l'aide de PDFCreator

29/09/2012, 19h27
ericdev67

Merci kiki29 :ccool:

le code fonctionne super bien, même si d'après toi il est livré brut de fonderie....;)

Je suis arrivé à l'enregistrer avec le nom et dans le dossier que je souhaitais, en changeant sNomPDF et sDossier

Par contre, je ne suis pas arrivé à modifier le "FD" : il ne faudrait que le code demande où chercher le document (=ouverture de la boite dialogue), mais qu'il l'ouvre "automatiquement".....j'ai essayé de mettre

Code:

.Filters.Add "Chemin_Complet\Nom_Fichier",".doc", 1

, mais ça ne fonctionne pas, puisque d'après ce que j'ai compris FD "ouvre" la boite dialogue windows de recherche de fichier....

Merci de m'indiquer la voie à suivre....

(et merci de m'avoir donné le lien de Heureux-oli, j'avais déjà regardé le tuto, mais je n'ai pas tout compris concernant les codes....mais je vais m'y replonger...:D)

A+
29/09/2012, 19h42
kiki29

Re,

Code:

ChDir ThisWorkbook.Path

ou autre

Merci kiki29,

J'ai essayé de mettre
Code:

1 2 3 4 5 6 7 8 Set FD = Application.FileDialog(msoFileDialogFilePicker) With FD .AllowMultiSelect = False .Filters.Clear .Filters.Add ChDir ThisWorkbook.Path, 1 If .Show <> -1 Then Exit Sub DoEvents End With
Ca ne fonctionne pas,
J'ai essayé

Code:

set FD= ChDir ThisWorkbook.Path

marche pas....Je comprends bien le "chdir", mais je ne sais pas où le mettre dans ton code......

Une dernière aide ?

Je te remercie :ccool:

A+

Re, tu fais n'importe quoi, l'aide en ligne |F1] n'est pas faite pour rien.

Code:

1
2
3
4
5
6
7
8
.....
Dim FD As FileDialog, sNomPDF As String
 
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = ThisWorkbook.Path
        .AllowMultiSelect = False
        .....

Merci kiki29,

J'ai repris ton code et l'ai modifié suivant tes conseils :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
Option Explicit
 
Sub Imprimer_PDFCreator_SelFichier()
Dim sDossier As String
Dim FD As FileDialog, sNomPDF As String
 
 
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = ThisWorkbook.Path & "\Fiches\" & Sheets("Fichiers").Cells(1, 1)
        .AllowMultiSelect = False
        '.Filters.Clear
        '.Filters.Add "document word", "*.doc", 1
        'If .Show <> -1 Then Exit Sub
        DoEvents
    End With
 
    sNomPDF = Sheets("Fichiers").Cells(1, 2) & ".pdf"
    sDossier = ThisWorkbook.Path & "\Fiches format PDF\"
    PDFCreator FD.SelectedItems(1), sNomPDF, sDossier
End Sub
 
Private Sub PDFCreator(sNomFichier As String, sNomFichierOutPDF As String, sDossier As String)
Dim jobPDF As Object
Dim AppWord As Object
Dim sPrinterDefault As String
 
    Set jobPDF = CreateObject("PDFCreator.clsPDFCreator")
    Set AppWord = CreateObject("Word.Application")
 
    With jobPDF
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Initialisation de PDFCreator impossible", vbCritical + vbOKOnly, "PDFCreator"
            Exit Sub
        End If
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
        .cOption("AutosaveDirectory") = sDossier
        .cOption("AutosaveFilename") = sNomFichierOutPDF
 
        '   0=PDF, 1=Png, 2=jpg, 3=bmp, 4=pcx,
        '   5=tif, 6=ps, 7=eps, 8=txt
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With
 
    sPrinterDefault = AppWord.ActivePrinter
    AppWord.ActivePrinter = "PDFCreator"
 
    With AppWord.Documents.Open(sNomFichier)
        .PrintOut Background:=False, copies:=1
        .Close False
    End With
 
    DoEvents
 
    With AppWord
        .ActivePrinter = sPrinterDefault
        .Quit
    End With
 
    Set AppWord = Nothing
 
    Do Until jobPDF.cCountOfPrintjobs = 1
        DoEvents
    Loop
 
    jobPDF.cPrinterStop = False
    Do Until jobPDF.cCountOfPrintjobs = 0
        DoEvents
    Loop
 
    jobPDF.cClose
    Set jobPDF = Nothing
End Sub
 
Private Sub KillPDFCreator()
Dim RetVal As Long
    RetVal = Shell("Taskkill /im PDFCreator.exe /f", 0)
End Sub

(je vais l'inclure dans mon code initial, et donc, il y aura une boucle type

Code:

for j = 1 to derniereligne

et donc cells(1,2) deviendra cells (j,2)....)

Lorsque j'ai tatonné pour modifier le code, après molt essais ça a fonctionné. J'ai sauvegardé, j'ai éteint/rallumé l'ordi et ce matin, lorsque je veux faire tourner le code il s'arrête à

Code:

PdfCreator FD.SelectedItems(1), sNomPDF, sDossier

avec pour message d'erreur "argument ou appel de procédure incorrect".....et là, je ne comprends plus rien....hier soir cela fonctionnait très bien, je n'ai rien changé hormis avoir éteint l'ordi...

Une idée ?

Merci,
A+

Re,

Je viens de faire plusieurs essais (en m'inspirant du F2....), et en modifiant

Code:

PDFCreator FD.SelectedItems(1), sNomPDF, sDossier

par

Code:

1
2
dim sNomfichier as string
PDFCreator sNomfichier, sNomPDF, sDossier

Cela fonctionne...:D

Mais je ne sais pas si ce "remplacement" entre

Code:

FD.SelectedItems(1)

et "sNomfichier" a une conséquence.....

J'ai fait un test en l'incluant dans mon code, tout fonctionne, mais.....je préfère m'assurer que je ne fais pas une énième bêtise......:aie:

Merci,

A+

(je propose aussi de modifier l'intitulé du post et rajouter "impression en pdf"...)

05/10/2012, 07h35
ericdev67

Excel commande Word et impression PDF

Apparemment, le code ne pose pas de problème, je vous remercie tous pour vos conseils, soutien, apports.

J'ai modifié l'intitulé afin qu'il se rapproche au plus près du post.....

A+ pour de prochaines aventures.....:ccool: