Ajouter un bouton au menu standard avec une macro

Version imprimable

26/07/2012, 18h04
loulag07

Ajouter un bouton au menu standard avec une macro

Bonjour,
J'ai trouvé beaucoup d'articles décrivant comment ajouter un bouton en utilisant Barre d'outils > Personnaliser >...
Ou comment créer un bouton lançant une macro dans la feuille XL.

Mais je cherchre à mettre un bouton qui exécute une macro dans le menu standard "Insertion".

Comment dois je faire ?

Je vous remercie.
26/07/2012, 18h16
kiki29

Salut, voir ici ?
27/07/2012, 10h36
loulag07

Merci. J'ai bien été voir ce tutoriel avant de poster cette discussion sur le forum mais je ne souhaite qu'ajouter un bonton au menu "Insertion" classique

J'imagine utiliser

Code:

CommandBars("MaBarre").Controls.Add(msoControlButton)

Mais comment trouver le nom de "MaBarre" ? Elle s'appelle "Insert" ?

Merci

Bonjour,

Dans un module normal

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
 
Sub créationMenu()
Dim menuOutils As CommandBarControl, monMenu As CommandBarControl
 
supprimeMenu
Set menuOutils = Application.CommandBars.FindControl(, 30005)
 
If menuOutils Is Nothing Then Exit Sub
 
Set monMenu = menuOutils.Controls.Add(msoControlButton, 1, , , True)
 
    With monMenu
        .Caption = "Ma Macro"
        .Tag = "menuAjoute"
        .OnAction = ThisWorkbook.Name & "!sc"
        .FaceId = 3360
        .Style = msoButtonIconAndCaption
    End With
 
 
End Sub
 
Sub supprimeMenu()
    On Error Resume Next
    Application.CommandBars.FindControl(Tag:="menuAjoute").Delete
End Sub
Sub sc()
    MsgBox "Bonjour"
End Sub

Dans le module ThisWorkBook

Code:

1
2
3
4
5
6
7
8
9
Option Explicit
 
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    supprimeMenu
End Sub
 
Private Sub Workbook_Open()
    créationMenu
End Sub

On ajoute un bouton en bas du menu Insertion, ce bouton fait fonctionner la macro appelée sc

Est ce ce que vous voulez?

JP

27/07/2012, 15h01
loulag07

Parfait !!

Si en action je passe ta macro sc.

Par contre si je souhaite passer ma macro qui passe en paramètre objWorkbook as Workbook ça ne fonctionne pas je ne cormprends pas pourquoi.

Tu l'auras remarqué je suis novice en matière de programmation vba

Merci
30/07/2012, 14h15
JPierreM

Bonjour,

Plus de détails seraient bien venus ou savoir ce que vous voulez exactement, joindre la macro à appeler

JP
30/07/2012, 14h41
fring

Bonjour,

Un exemple ICI pour passer des paramètres avec OnAction

Je souhaite passer l'objet Workbook
Ma macro met à jour l'entête de page des feuilles du document EXCEL.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Public Sub subEventbeforeFooter(objWorkbook As Workbook)
 
    Dim strHeaderText As String
    Dim strOrigine As String
    Dim objWorksheet As Worksheet
 
    Application.StatusBar = "Mise à jour des entêtes en cours..."
 
 
    For Each objWorksheet In objWorkbook.Worksheets
 
            strHeaderText = Left("référence", 30)
            objWorksheet.PageSetup.LeftHeader = strHeaderText
 
            strHeaderText = Left("titre", 210)
            objWorksheet.PageSetup.CenterHeader = strHeaderText
 
            strHeaderText = Left("version", 10)
            objWorksheet.PageSetup.RightHeader = strHeaderText
 
        Next objWorksheet
    End If
 
    Application.StatusBar = ""
    Application.EnableCancelKey = xlDisabled
 
 
End Sub

J'ai essayé

Code:

.OnAction = "!subEventbeforeFooter" & Workbooks

Mais il me répond qu' il ne connait pas ma fonction

Bonjour,

Si j'ai bien compris il s'agit à partir d'un certain classeur de réaliser la mise en page sur un autre classeur

Dans le module ThisworkBook rien de changé

Dans le module standard

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Option Explicit
 
Sub créationMenu()
Dim menuOutils As CommandBarControl, monMenu As CommandBarControl
Dim objWorkbook As String
 
supprimeMenu
 
Set menuOutils = Application.CommandBars.FindControl(, 30005)
 
If menuOutils Is Nothing Then Exit Sub
 
Set monMenu = menuOutils.Controls.Add(msoControlButton, 1, , , True)
 
objWorkbook = "classeur_Exemple.xls"
 
    With monMenu
        .Caption = "Ma Macro"
        .Tag = "menuAjoute"
        .OnAction = "'subEventbeforeFooter """ & objWorkbook & """'"
        .FaceId = 3360
        .Style = msoButtonIconAndCaption
    End With
 
 
End Sub
 
Sub supprimeMenu()
    On Error Resume Next
    Application.CommandBars.FindControl(Tag:="menuAjoute").Delete
End Sub
 
Public Sub subEventbeforeFooter(objWorkbook As String)
    Dim strHeaderText As String
    Dim strOrigine As String
    Dim objWorksheet As Worksheet
 
    Application.StatusBar = "Mise à jour des entêtes en cours..."
 
    For Each objWorksheet In Workbooks(objWorkbook).Worksheets
 
            strHeaderText = Left("référence", 30)
            objWorksheet.PageSetup.LeftHeader = strHeaderText
 
            strHeaderText = Left("titre", 210)
            objWorksheet.PageSetup.CenterHeader = strHeaderText
 
            strHeaderText = Left("version", 10)
            objWorksheet.PageSetup.RightHeader = strHeaderText
 
        Next objWorksheet
    'End If
    Application.StatusBar = ""
    Application.EnableCancelKey = xlDisabled
 
End Sub

Cette façon de faire est trop restrictive car on ne peut faire la mise en page que sur le classeur dont le nom est passé en argument à la macro subEventbeforeFooter. Ce nom étant défini dans la macro créationMenu on ne peut pas revenir en arrière chaque fois. Je pense qu'il serait plus intéressant de récupérer le nom du classeur à mettre en page directement dans la macro subEventbeforeFooter par l'intermédiaire d'un inputBox ou autre. Peut être même passer par le classeur de macros perso pour que cela fonctionne sur tous les classeurs.

JP