Chercher valeur sélectionnée

Version imprimable

16/07/2012, 10h42
xtecpasteque

Chercher valeur sélectionnée

bonjour,

Je suis débutant sur excel et je voudrais écrire un code permettant de :

Je rentre une valeur dans une textbox, par exemple 10
en appuyant sur un bouton valider, sa m'affiche dans une listbox toutes les valeurs inférieurs et égal à 10 qui sont déja entrées dans une feuille excel

par exemple :

les valeurs dans mon classeur :
opération1 5 jours
opération2 48 jours
opération3 9 jours

Merci de votre aide

Il doit donc m'afficher dans la listebox
opération1 5 jours
opération3 9 jours

1 pièce(s) jointe(s)

Bonjour,

Mets le code suivant dans le module de l'userform. J'ai considéré que "opération x" est en colonne A et le nombre en colonne B (sans "jours") :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub CommandButton1_Click()
    Dim c As Range, Plage As Range
    With Sheets("BD")
        Set Plage = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp))
    End With
    With Me.ListBox1
        .Clear
        For Each c In Plage
            If Me.TextBox1.Text <> "" And IsNumeric(Me.TextBox1.Text) Then
                If c.Offset(, 1) <= CInt(Me.TextBox1.Text) Then
                    .AddItem c.Value
                    .List(.ListCount - 1, 1) = c.Offset(, 1).Value
                End If
            End If
        Next c
    End With
End Sub
 
Private Sub UserForm_Activate()
    Me.ListBox1.Clear
    Me.TextBox1.Text = ""
End Sub

Regarde le classeur de test en PJ.

16/07/2012, 11h42
Daniel.C

1 pièce(s) jointe(s)

Ce classeur-ci est plus explicite.
16/07/2012, 11h51
xtecpasteque

merci , sa marche super !
16/07/2012, 13h10
xtecpasteque

rebonjour

J'essaye depuis tous a l'heure de transformer votre code mais je n'y arrive pas

enfaite je vous ai demandé une petite simplification mais ce n'est pas mon réel besoin

Voici ce que je voudrais que sa fasse :

Chaque outil possède des opérations différentes, il y en a plusieurs sur chaque outils

outil1 opération1 5jours opération2 48 jours opération3 5jours
outil2 opération1 7jours opération2 25 jours
outil3 opération1 5jours opération2 12 jours opération3 7jours

si je selectionne donc 10 jours dans ma textbox :
voici ce que je voudrais que sa s'affiche dans ma listbox

outil1 opération1 5jours
outil1 opération3 5jours
outil3 opération1 5jours
outil3 opération3 7jours
outil2 opération1 7jours
16/07/2012, 13h20
Daniel.C

Ça serait sympa si tu présentais tout de suite tes données telles qu'elles sont réellement,ça m'évite du travail...
C'est pas clair s'il y a un espace ou pas entre le nombre et le mot "jours". De plus est-ce que tu pourrais agencer tes données de la manière suivante :

outil1 opération1 5jours
outil1 opération2 48jours
outil1 opération3 5jours
outil3 opération1 5jours
outil3 opération2 12jours
outil3 opération3 7jours
outil2 opération1 7jours
outil2 opération2 25jours
16/07/2012, 13h43
xtecpasteque

1 pièce(s) jointe(s)

Voici un fichier exemple de mon besoin

Il peut avoir 6 opérations sur chaque outils

je voudrais que mes données soit rangées dans l'ordre croissant des opérations et non des outils.

Les jours pour le trie ont un fond rouge ( colonne 5,10,15,20,25 et 30), il faut que les données à coté soient inscrites dans la listbox. ( Matériels Opération Date de début Périodicité Prochain contrôle Jours alerte

exemple :
je met 5 jours dans ma textbox

listbox :
matériel1 essai1 16/07/2012 5 21/07/2012 5
matériel1 essai3 16/07/2012 5 21/07/2012 5
matériel3 essai1 16/07/2012 6 22/07/2012 6

1 pièce(s) jointe(s)

Voici le code du module de l'userform correspondant au classeur joint (j'utilise les colonnes A:F) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub CommandButton1_Click()
    Dim c As Range, Plage As Range, LB As ListBox
    If Me.TextBox1.Text = "" Or Not IsNumeric(Me.TextBox1.Text) Then Exit Sub
    With Sheets("Sheet1")
        .[A:F].ClearContents
        ligne = 0
        Set Plage = .Range(.[H3], .Cells(.Rows.Count, 8).End(xlUp))
        Me.ListBox1.Clear
        For Each c In Plage
            For i = 2 To .Cells(c.Row, .Columns.Count).End(xlToLeft).Column - 4 Step 5
                If c.Offset(, i + 2) <= CInt(Me.TextBox1.Text) And c.Offset(, i + 2) > 0 Then
                    ligne = ligne + 1
                    .Cells(ligne, 1) = c.Value
                    .Cells(ligne, 2) = c.Offset(, i).Value
                    .Cells(ligne, 3) = c.Offset(, i + 1).Value
                    .Cells(ligne, 4) = c.Offset(, i + 2).Value
                    .Cells(ligne, 5) = c.Offset(, i + 3).Value
                    .Cells(ligne, 6) = c.Offset(, i + 4).Value
                End If
            Next i
        Next c
        .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 6).Sort .Range("B1"), xlAscending, _
        key2:=.Range("A1"), order2:=xlAscending, Header:=xlNo
        Set Plage = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp))
        For Each c In Plage
             Me.ListBox1.AddItem c.Value
             Me.ListBox1.List(Me.ListBox1.ListCount - 1, 1) = c.Offset(, 1).Value
             Me.ListBox1.List(Me.ListBox1.ListCount - 1, 2) = c.Offset(, 2).Value
             Me.ListBox1.List(Me.ListBox1.ListCount - 1, 3) = c.Offset(, 3).Value
             Me.ListBox1.List(Me.ListBox1.ListCount - 1, 4) = c.Offset(, 4).Value
             Me.ListBox1.List(Me.ListBox1.ListCount - 1, 5) = c.Offset(, 5).Value
        Next c
        .[A:F].ClearContents
    End With
End Sub
 
Private Sub UserForm_Activate()
    Me.ListBox1.Clear
    Me.TextBox1.Text = ""
End Sub

17/07/2012, 08h48
xtecpasteque

merci !