Variable dans SourceData et TableDestination

Version imprimable

Bonjour tout le monde

je bloque un peu et je trouve pas la syntaxe qui puisse me permettre d'utiliser une variable comme source de données por la création d'un tcd par macro,
en gros j'essaie de boucler sur toutes les feuilles de mon classeur qui on la même mise en forme pour créer des tcd dans des nouvelles feuilles .

merci de m'orienter s'il vous plait

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub CreerTCD()
Dim X, Y As Variant
Dim ws As Worksheet
 For Each ws In ActiveWorkbook.Worksheets
 
Y = ws.Name
X = ws.Name & " " & "TCD"
 
 Worksheets.Add(After:=Worksheets(Worksheets.Count)).Name = X
ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:= _
    [y!A1].CurrentRegion.Address(, , xlR1C1, True)).CreatePivotTable
    TableDestination:="x!R3C1", _
    TableName:="TCD"
 
ActiveWorkbook.Sheets("x").PivotTables("Mon TCD").SmallGrid = False
ActiveWorkbook.Sheets("x").PivotTables("Mon TCD").AddFields RowFields:="ARTICLE", ColumnFields:="ANNEE MOIS" ', PageFields:=""
With ActiveWorkbook.Sheets("x").PivotTables("Mon TCD").PivotFields("km")
    .Orientation = xlDataField
    .Caption = "somme Qte_dem_km"
    .Function = xlSum
    '
End With
 Application.CommandBars("PivotTable").Visible = True
 Next ws
End Sub

13/07/2012, 17h18
Daniel.C

Bonjour,

Peut-être :

X = "'" & ws.Name & " " & "TCD" & "'"

au lieu de :

X = ws.Name & " " & "TCD"

merci pour votre aide mais cela bloque toujours ici et ça me mets objet requis .
Code:

1 2 3 4 ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:= _ [X!A1].CurrentRegion.Address(, , xlR1C1, True)).CreatePivotTable _ TableDestination:="Y!R3C1", _ TableName:="TCD"
le contenu des variables x et y est bon .

13/07/2012, 20h05
Daniel.C

As-tu un message d'erreur ? si oui, lequel et sur quelle ligne ? est-ce que la variable Y comporte un espace ? est-ce que tu n'as pas un autre TCD du nom de "TCD" ?

BONJOUR

l'erreur est a la ligne

Code:

TableName:="TCD"

c'est un run-time erreur 424 objet requis
Code:

1 2 3 4 ActiveWorkbook.PivotCaches.Add(SourceType:=xlDatabase, SourceData:= _ [sheets(Y)!A1].CurrentRegion.Address(, , xlR1C1, True)).CreatePivotTable _ TableDestination:="sheets(X)!R3C1", _ TableName:="TCD"
j'ai trouvé le poste suivant et je sais pas ce que vous en pensez!! :

La but est de placer la feuille et la plage variable dans une variable :

Code:

Sel = Worksheets(NomOp).Range("A1:N" & lasti).Address(True, True, xlR1C1, True)

ce qui donne dans le TCD :
Code:

1 2 3 4 ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _ Sel, Version:=xlPivotTableVersion12). _ CreatePivotTable TableDestination:=Cells(lastj, 1).Offset(2, 0), TableName:= _ "Tableau croisé dynamique1", DefaultVersion:=xlPivotTableVersion12
merci

Bonjour
Je ferai comme ceci (tu t'es mêlé les pinceaux dans l'utilisation de tes variables)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub CreerTCD()
Dim Ws As Worksheet, Wst As Worksheet
Dim X As String, Y As String
 
With ThisWorkbook
    For Each Ws In .Worksheets
        X = Ws.Name
        Y = X & " TCD"
        'Si c'est pas une feuille TCD
        If InStr(X, "TCD") = 0 Then
            'Si la feuille TCD correspondante n'existe pas
            If Not Existe(Y) Then
                Set Wst = .Worksheets.Add(After:=.Worksheets(.Worksheets.Count))
                Wst.Name = Y
                .PivotCaches.Add(SourceType:=xlDatabase, _
                                 SourceData:=Ws.Range("A1").CurrentRegion).CreatePivotTable _
                                 TableDestination:=Wst.Range("A3"), TableName:="TCD" & X
 
                With Wst.PivotTables("TCD" & X)
                    .SmallGrid = False
                    .AddFields RowFields:="ARTICLE", ColumnFields:="ANNEE MOIS"
 
                    With .PivotFields("km")
                        .Orientation = xlDataField
                        .Caption = "somme Qte_dem_km"
                        .Function = xlSum
                    End With
                End With
                Application.CommandBars("PivotTable").Visible = True
            End If
        End If
    Next Ws
End With
End Sub
 
Private Function Existe(ByVal Str As String) As Boolean
Dim Sh As Worksheet
 
For Each Sh In ThisWorkbook.Sheets
    If Sh.Name = Str Then
        Existe = True
        Exit For
    End If
Next Sh
End Function

14/07/2012, 14h39
varik

je vous remercie beaucoup pour votre méthode ainsi que de votre aide . j'avance grâce a vous .
bonne fin de journée