Importer données dans fichier Excel via macro VBA

Version imprimable

09/07/2012, 22h01
JEREMY01

2 pièce(s) jointe(s)

Importer données dans fichier Excel via macro VBA

Bonjour à tous,

après avoir parcouru les forums, je franchis le pas et pose ma question car je n'y arrive décidément pas.

Voici le problème :

j'ai un fichier issue d'une requête (données issues d'un système d'information : données source.xls). Ce fichier contient une liste de demandes créées sur trois colonnes :

- n° demande
- date d'ouverture de la demande
- destinataire demande

Je cherche à lire les données contenues dans ce fichier et les importer dans un tableau Excel (tableau cible.xls) pour :

- compter le nombre de demandes adressées à chaque destinataire
- pour chaque destinataire, la date de la demande la plus ancienne

Les deux fichiers sont joints.

La difficulté que je rencontre est que le "nom" du destinataire est différent dans chacun des fichiers :

EG00X dans le tableau cible contre "DPF - EG00X - 'nom département'".

Il faut donc que la macro recherche la valeur "EG00X" dans la chaîne de caractère "DPF - EG00X - 'nom département'" pour ensuite affecter les bonnes valeurs.

J'espère que mes propos sont clairs et vous remercient d'avance pour le temps que vous pourrez m'accorder !

Jérémy
09/07/2012, 22h24
jfontaine

Bonjour,

pour le comptage, tu peux utiliser une formule plutôt que VBA

Exemple :

Code:

=NB.SI(C2:C9;"*EG002*")
09/07/2012, 22h31
JEREMY01

Merci pour la réponse rapide.

Pour le comptage, effectivement nb.si fonctionnait très bien.

Mais j'ai abandonné Excel car le fichier source est actualisé toutes les semaines (et pas de mise à jour sans que le fichier source ne soit ouvert...). De plus, le nombre de lignes évolue constamment en fonction du nombre de demandes.

Dans ce cas, penches toi sur l'instruction Find de l'objet Range

Exemple

Code:

1
2
3
4
5
6
7
Dim rg As Range
 
Set rg = Sheets("Données source").Range("C:C").Find(what:="EG002", lookat:=xlPart)
 
If Not rg Is Nothing Then
    MsgBox rg.Address
End If

Bonjour,

j'ai chargé votre code et la msgBox affiche "$C$2" alors que je souhaiterai que la macro compte le nombre de fois qu'apparaît "EG002" dans la colonne C et inscrive cette valeur dans le tableau cible.

Je souhaitais passer par une boucle afin de coller les valeurs dans le tableau cible (voir ci-dessous) mais je ne sais pas comment traduire le fait que mes données source doivent "contenir" le nom indiqué dans le tableau cible.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 For i = 2 To 97 (il s'agit des lignes de mon tableau cible) somme = 0 (le compteur est défini) For j = 2 To dernière ligne (il s'agit des lignes de mes données source) If Sheets("Données source").Cells(j, 3).Value "contient" Sheets("Tableau cible").Cells(i, 1).Value Then somme = somme + 1 End If Next j Sheets("Tableau cible").Cells(i, 2).Value = somme Next i
Merci

Bonjour,

Voici une solution utilisant une collection.
La collection permet d’avoir une liste de destinataires sans doublon.
A partir de cette collection, on effectue le comptage des demandes et le relevé de la date la plus ancienne.
On recherche ensuite le destinataire dans le tableau cible et on renseigne le cumul et la date.
Le code ne prévoit pas l’ouverture des fichiers. Avant de lancer la procédure, les 2 classeurs doivent donc être ouverts.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
Sub Creer_Liste_SansDoublons()
Dim WsSource As Worksheet, WsCible As Worksheet
Dim PlageS As Range, PlageC As Range, Cel As Range, c As Range, d As Range
Dim Collec As Collection
Dim DerLig As Long, i As Long, Compteur As Long
Dim Nom As String, firstAddress As String
Dim DateOuv As Date
    Set WsSource = Workbooks("Données source.xls").Worksheets("Données source")
    Set WsCible = Workbooks("Tableau cible.xls").Worksheets("Tableau cible")
    Set Collec = New Collection
    On Error Resume Next
    Set PlageS = WsSource.Range("C2:C" & WsSource.Range("C" & WsSource.Rows.Count).End(xlUp).Row)
    For Each Cel In PlageS
        Nom = Trim(Split(Cel, "-")(1))
        If Nom <> "" Then Collec.Add Nom, CStr(Nom)
    Next Cel
    On Error GoTo 0
    For i = 1 To Collec.Count
        Compteur = 0
        DateOuv = Date
        Set c = PlageS.Find(Collec.Item(i), LookIn:=xlValues, Lookat:=xlPart)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                If c.Offset(0, -1) < DateOuv Then DateOuv = c.Offset(0, -1)
                Compteur = Compteur + 1
                Set c = PlageS.FindNext(c)
            Loop While Not c Is Nothing And c.Address <> firstAddress
            Set PlageC = WsCible.Range("A2:A" & WsCible.Range("A" & WsCible.Rows.Count).End(xlUp).Row)
            Set d = PlageC.Find(Collec.Item(i), LookIn:=xlValues, Lookat:=xlWhole)
                If Not c Is Nothing Then
                    d.Offset(0, 1) = Compteur
                    d.Offset(0, 2) = DateOuv
                End If
        End If
        Set PlageC = Nothing
        Set d = Nothing
        Set c = Nothing
    Next i
    Set PlageS = Nothing
    Set Collec = Nothing
    Set WsSource = Nothing
    Set WsCible = Nothing
End Sub

Cordialement.

10/07/2012, 23h13
JEREMY01

Bonsoir,

merci, c'est absolument parfait !

Par rapport à votre code, j'ai juste eu à ajouter une action d'ouverture / fermeture du fichier source pour éviter d'avoir à l'ouvrir manuellement...

Jérémy