Choix de l'image lors de l'insertion

Version imprimable

Bonjour,
Je ne trouve pas le code permettant de donner la possibilité à l'utilisateur d'aller cher une image sur l'ordinateur.

Par exemple:
Code:

1 2 3 4 Dim objFeuille As Worksheet, objShape As Shape Set objFeuille = ActiveSheet Set objShape = objFeuille.Shapes.AddPicture("C:\Documents and Settings\All Users\Documents\Mes images\Échantillons d'images\Collines.jpg", msoFalse, msoCTrue, 100, 100, 70, 70)
Permet d'insérer une seule image, comment faire pour ouvrir la fenêtre de navigation svp?

Bonjour,

Voici le code te permettant d'afficher la fenetre Insertion>Image et de l'afficher (ici elle prendra la dimension D3:E8)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub InsertionImage()
    Dim Emplacement As Range
    Dim Img As Object
    Dim ShapeObj As Shape
 
    'Boucle pour supprimer l'ancienne image
    For Each ShapeObj In ActiveSheet.Shapes
        If ShapeObj.Name = "Cible" Then ActiveSheet.Shapes("Cible").Delete
    Next ShapeObj
 
    If Application.Dialogs(xlDialogInsertPicture).Show Then
        'Définit l'emplacement de l'image
        Set Emplacement = Range("D3:E8")
 
        Set Img = ActiveSheet.DrawingObjects(ActiveSheet.Shapes.Count)
 
        With Img.ShapeRange
            'Nommer l'image insérée (Pour la supprimer plus facilement ensuite)
            .Name = "Cible"
            .LockAspectRatio = msoFalse
            .Left = Emplacement.Left
            .Top = Emplacement.Top
            .Height = Emplacement.Height
            .Width = Emplacement.Width
        End With
 
    Else
        MsgBox "Insertion d'image interrompue."
    End If
 
End Sub

Cdt,

29/05/2012, 15h59
YassDumb

Merci beaucoup! c'est exactement ce que je voulais.
A bientôt!