recuperation de nom de fichier avec xslt

Version imprimable

Bonjour

J'ai un fichier xml qui contient un ensemble de liens vers des images dont voici un petit exemple simplifié:

Code:

1
2
3
4
5
6
7
8
9
 
<ud id="TitreDuDocumentUD1PremierParagraphe-0C07571A" xsi:noNamespaceSchemaLocation="ud.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <image href="file:/C:/Users/graphics/arbortextsolution.gif"/>    
    <image href="file:/C:/Users/graphics/boatdraw.tif"/>
    <section id="TitreDeLaPremièreSectionPremierPara-0C0759EE">
        <titre>Titre de la première section</titre>        
        <image href="file:/C:/Users/graphics/satellite.tif"/>       
    </section>  
</ud>

je souhaiterai récuperer le nom de chacune des images pour le mettre dans un attribut en appliquant une feuille de style xslt.

le resultat devrait ressembler a cela :

Code:

1
2
3
4
5
6
7
8
9
 
<ud id="TitreDuDocumentUD1PremierParagraphe-0C07571A" xsi:noNamespaceSchemaLocation="ud.xsd" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <image href="file:/C:/Users/graphics/arbortextsolution.gif" fileName="arbortextsolution.gif"/>    
    <image href="file:/C:/Users/graphics/boatdraw.tif" fileName="boatdraw.tif"/>
    <section id="TitreDeLaPremièreSectionPremierPara-0C0759EE">
        <titre>Titre de la première section</titre>        
        <image href="file:/C:/Users/graphics/satellite.tif" fileName="satellite.tif"/>        
    </section>  
</ud>

merci

Vous n'avez rien à montrer en xslt, ce que vous avez fait?!

Voici un template qui peut le faire (xslt 2.0 comme énoncé).

Code:

1
2
3
4
5
6
7
8
9
<xsl:template match="image[@href]">
    <xsl:copy>
        <xsl:apply-templates select="@*" />
        <xsl:attribute name="filename">
            <xsl:value-of select="tokenize(@href,'/')[last()]" />
        </xsl:attribute>
        <xsl:apply-templates select="*|text()|comment()|processing-instruction()" />
    </xsl:copy>
</xsl:template>

re bonjour,

Merci pour votre réponse, Je l'ai testé mais la fonction tokenize n'a pas été reconnu, j'utilise xproc pour appliquer la feuille de style.

Donc finalement j'ai opté pour une solution recursive avec un substring-after puique je ne peux pas utiliser la fonction tokenize.

Voici ma solution :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
 
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
 
    <xsl:template name="extraction">
        <xsl:param name="fileHref"/>
        <xsl:choose>
            <xsl:when test="contains($fileHref,'/')">
                <xsl:call-template name="extraction">
                    <xsl:with-param name="fileHref" select="substring-after($fileHref,'/')"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$fileHref"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
 
    <xsl:template match="image/@fileName">
        <xsl:variable name="fileHref" select="parent::node()/@href"/>
        <xsl:attribute name="fileName"> 
        <xsl:variable name="attr">           
            <xsl:call-template name="extraction">
                <xsl:with-param name="fileHref" select="$fileHref"/>
            </xsl:call-template>
        </xsl:variable>        
            <xsl:value-of select="$attr"/>            
        </xsl:attribute>         
    </xsl:template>    
</xsl:stylesheet>

Ps : j'ai crée l'attribut "fileName" directement sous xproc et non pas avec la feuille de style

25/05/2012, 12h56
thelvin

tokenize() fait partie de XPath 2.0, utilisé donc dans XSLT 2.0, ou alors EXSLT, qui n'est pas reconnu par beaucoup d'outils. Dans ces cas-là, le template récursif est la seule solution réaliste.