Rechercher et afficher un text dans un fichier Word avec macro Excel

Version imprimable

Bonjour,
Je suis sur un petit problème technique que je ne comprend pas et que je n'arrive pas à résoudre du coup.

En fait, dans un fichier excel, je souhaite ouvrir un fichier word et chercher du texte contenu dans la cellule A1.

J'ai fait ce code :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Sub Test() Dim appWrd As Word.Application Dim docWord As Word.Document Set appWrd = CreateObject("Word.Application") appWrd.Visible = True Set docWord = appWrd.Documents.Open(ActiveCell.Text, ReadOnly:=True) With docWord.Content.Find .ClearFormatting .Execute Cells(1).Text End With End Sub
Malheureusement, ça ne sélectionne pas le texte trouvé (j'ai même fait
If .Execute(Cells(1).Text) Then MsgBox "OK" et la boîte s'affiche, donc c'est que le texte est trouvé).

Alors que le code suivant mis directement dans Word fonctionne comme attendu.
Code:

1 2 3 4 With Selection.Find .ClearFormatting .Execute Cells(1).Text End With
Quelqu'un aurait-il une idée ?

Merci

P.S : Bien sur, il y a plusieurs fichiers word et le texte à chercher peut être modifié.

26/03/2012, 11h14
kiila

Le text a chercher est sur excel ?? ou sur word ?
26/03/2012, 11h34
ypelissier

Le texte définissant la recherche est dans Excel, et il est à chercher dans le fichier Word.

Salut, extrait de l'aide en ligne [F1] sur Find

Code:

1
2
3
4
5
6
7
8
With Selection.Find
    .Forward = True
    .ClearFormatting
    .MatchWholeWord = True
    .MatchCase = False
    .Wrap = wdFindContinue
    .Execute FindText:="Microsoft"
End With

Merci kiki29, mais ces paramètres n'ont aucun effet :(

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim appWrd As Word.Application
Dim docWord As Word.Document
 
Set appWrd = CreateObject("Word.Application")
appWrd.Visible = True
Set docWord = appWrd.Documents.Open(ActiveCell.Text, ReadOnly:=True)
 
With docWord.Content.Find
    .ClearFormatting
    .MatchWholeWord = True
    .MatchCase = False
    .Execute Cells(1).Text
End With

Quelqu'un a une autre piste ?

Re, ooops erreur basique

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 
Sub Trouver()
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim sStr As String, sNom As String
 
    sStr = Feuil1.Range("A1").Text
    sNom = ThisWorkbook.Path & "\" & "Test.doc"
 
    Set WordApp = New Word.Application
    Set WordDoc = WordApp.Documents.Open(Filename:=sNom, ReadOnly:=True)
 
    WordApp.Visible = True
 
    WordApp.Selection.HomeKey wdStory
 
    With WordApp.Selection.Find
        .Forward = True
        .ClearFormatting
        .MatchWholeWord = True
        .MatchCase = False
        .Execute FindText:=sStr
    End With
 
    Set WordApp = Nothing
End Sub

26/03/2012, 16h51
ypelissier

C'est tout bon, je partais du mauvais objet (le document alors qu'il fallait partir de l'application pour bénéficier de l'objet selection).

Un grand merci pour avoir corrigé cette erreur et méprise.