Tableau de control en VBA excel

Version imprimable

Bonjour,
Je travaille actuellement sur une userForm dans Excel qui doit s’adapter aux besoins de l’utilisateur.
En fonction des données entrées dans une TextBox, je dois générer un groupe de contrôle comprenant :1 label ,2 ComboBox,1 CheckBox
J’ai essayé plusieurs méthodes sans succès.
Je me suis orienté vers la création d’un tableau contenant mes 4 éléments. Mais cela ne fonctionne pas.
Faut-il changer de stratégie ou est-ce que mon code est faux ?

~~--------------------------~~
Code: (example)
Code:

1 2 3 4 5 6 7 8 9 10 Option Explicit Dim MonTabDeLabel(1) As Object ’ est-ce le bon type? Private Sub UserForm_Click() Set MonTabDeLabel(0) = FrmParametre.LblAddNewLine Set MonTabDeLabel(1) = FrmParametre.LblAddNewLine MonTabDeLabel(0).Caption = "toto" & "1" MonTabDeLabel(1).Caption = "toto" & "2" End Sub
‘A mon regret l’index 0 et 1 pilote le même label alors que je voudrai que ce soit des instances différentes.

Merci pour vos réponses , vos idées ou exemple de code.

Bonsoir,

Le problème dans le code précédent, c'est que MonTabDeLabel(0) et MonTabDeLabel(1) ont une référence sur le même objet LblAddNewLine.
Du coup, toute modification sur l'indice 0 du tableau se retrouve sur l'indice 1 (vu que c'est le même objet).

Pour créer dynamiquement des objects depuis le code, en fonction des valeurs entrées par l'utilisateur :

(1) . Ajout un module de classe à nommer LigneComposants avec le code ci-dessous.

Code:

1
2
3
4
Public LineLabel As Object
Public LineCBBox1 As ComboBox
Public LineCBBox2 As ComboBox
Public LineCheckBox As Object

(2) Dans la userform, ajoute le code ci-dessous.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Option Explicit
 
Dim Line() As LigneComposants
 
Private Sub AddLine(etiquette As String, ByRef cb1List() As String, ByRef cb2List() As String)
    ReDim Preserve Line(UBound(Line) + 1)
    Dim i As Integer
    Dim lNumber As Integer
    lNumber = UBound(Line)
    Dim Rowoffset As Integer
    Rowoffset = 1
    Set Line(UBound(Line)) = New LigneComposants
    With Line(UBound(Line))
       Set .LineCheckBox = Me.Controls.Add("FORMS.CHECKBOX.1", "CkeckBox" & lNumber, True)
       With .LineCheckBox
            .Top = 1 + 20 * lNumber
            .Left = Rowoffset + 1
            .Width = 20
            Rowoffset = .Left + .Width
       End With
       Set .LineLabel = Me.Controls.Add("FORMS.LABEL.1", "Label" & lNumber, True)
       With .LineLabel
            .Top = 20 * lNumber + 4
            .Left = Rowoffset + 1
            .Width = 30
            .Caption = etiquette
            Rowoffset = .Left + .Width
       End With
       Set .LineCBBox1 = Me.Controls.Add("FORMS.COMBOBOX.1", "CB_BOXv1" & lNumber, True)
       With .LineCBBox1
            .Top = 1 + 20 * lNumber
            .Left = Rowoffset + 1
            For i = 0 To UBound(cb1List)
                .AddItem (cb1List(i))
            Next i
            .Text = cb1List(0)
            Rowoffset = .Left + .Width
       End With
       Set .LineCBBox2 = Me.Controls.Add("FORMS.COMBOBOX.1", "CB_BOXv2" & lNumber, True)
       With .LineCBBox2
            .Top = 1 + 20 * lNumber
            .Left = Rowoffset + 1
            For i = 0 To UBound(cb2List)
                .AddItem (cb2List(i))
            Next i
            .Text = cb2List(0)
            Rowoffset = .Left + .Width
       End With
    End With
 
End Sub
 
Private Sub UserForm_Initialize()
    ReDim Line(0)
End Sub

(3) Pour ajouter une ligne appelle la routine AddLine, en passant en paramètres :
- le label à afficher,
- la liste de valeur pour la première des combobox
- la liste de valeur pour la seconde des combobox

16/03/2012, 10h34
totoletoto

Merci

Merci pour la réponse, je n’ai pas le temps de coder ce weekend:cry: , je regarde ca pour le milieu de la semaine.Je ferai un retour à ce moment là.:ccool:
Bonne journée
16/03/2012, 14h42
totoletoto

allons plus loin...

Je n’ai pas réussi à attendre. J’ai testé ce code et il fait bien ce que je veux MERCI. Maintenant je me pose une autre question. Comment utiliser les « Event » des nouveaux controls ?
Exemple:
..._Change()
..._Enter()
...
bonne journée
17/03/2012, 18h16
BlueMonkey

Bonjour,

Dans ma version d'Excel je ne vois pas de méthode pour associer dynamiquement un évènement à un contrôle. :(
Peut être que sous XLS2007, il y a des méthodes comme AddHandler (existant en VB.net)