Pb syntaxe range avec variable

Version imprimable

14/03/2012, 16h23
rob1son76

Pb syntaxe range avec variable

Bonjour,

Je voudrai sélectionner plusieurs cellules selon des critères.

Dans une variable "t" je regroupe le nom des cellules que je souhaite sélectionner.
Ca me donne ca par exemple: t= H2,I2,H5,I5

Le problème viens de mon range.
Lorsque je fait range("t") ca ne marche pas j'ai l'erreur la méthode range de l'objet '_Global' a échoué.

J'ai aussi essayé ac pour valeur de t: cells(2,8),cells(2,9)
mais ca ne marche pas non plus.

Pouvez vous m'aider.

merci
14/03/2012, 17h33
jfontaine
Bonjour,

Si tu écris t entre guillemets c'est la plage nommé t que tu mets dans ton Range et non la valeur de ta variable t

Essais comme cela
Code:

1 2 3 t= "H2,I2,H5,I5" Range(t).Select
14/03/2012, 17h54
rob1son76

Salut,

Merci pour ta réponse mais comment je fait pour que ma variable text t prenne en compte les doubles cottes?

Code:

t = t & "H" & i & "," & "I" & i & ","

Ca c'est ma variable t. Si je lui met des doubles cottes avant et après il bug avec les lettres (H et I).

Merci
14/03/2012, 17h57
jfontaine

si t est vide

Code:

t = "H" & i & ",I" & i

si t contient déja une liste d'adresse

Code:

t = t & ",H" & i & ",I" & i
14/03/2012, 18h01
rob1son76

C'est la même chose que ma variable t. Mais différement.
Moi à la fin je remplace la dernière virgule par un espace puis je le supprime.

Mais bon dans nos 2 cas on obtient pas t="H2,H3,I2,I3" mais t=H2,H3,I2,I3 sans les doubles cotte.
14/03/2012, 18h21
jfontaine

on utilise les " pour spécifié que l'ont écrit du texte pour borner le texte
La variable contiendra toujours ce qu'il y a entre les double quote.

J'ai essayé comme tu m'a dis mais ca ne marche tjs pas.
J'ai tjs le mm message d'erreur.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Dim t As String
 
    For i = 2 To 20 'ncertu
 
        If Worksheets("Décomposition Certu").Cells([i], "K").Value Like "% BT" Then
            If Len(t) = 0 Then
            t = "H" & i & ",I" & i
            Else
            t = t & ",H" & i & ",I" & i
            End If
 
        End If
        '-----------------------
        If Worksheets("Décomposition Certu").Cells([i], "V").Value Like "% BT" Then
            If Len(t) = 0 Then
            t = "S" & i & ",T" & i
            Else
            t = t & ",S" & i & ",T" & i
            End If
        End If
 
 
    Next i
    MsgBox (t)
    Range(t).Select

15/03/2012, 11h58
jfontaine

Quel est la valeur de t quand tu as le message d'erreur ?

Vaux mieux de travailler avec des Range parce que en concaténant les cellules ainsi tu sera limité par 30 arguments pour range(X1, X2....,X30)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub Test()
Dim i As Integer
Dim T As Range
 
With Worksheets("Décomposition Certu")
    For i = 2 To 20                              'ncertu
        If .Cells(i, "K").Value Like "% BT" Then
            If T Is Nothing Then
                Set T = .Range("H" & i & ":I" & i)
            Else
                Set T = Union(T, .Range("H" & i & ":I" & i))
            End If
        End If
        '-----------------------
        If .Cells(i, "V").Value Like "% BT" Then
            If T Is Nothing Then
                Set T = .Range("S" & i & ":T" & i)
            Else
                Set T = Union(T, .Range("S" & i & ":T" & i))
            End If
        End If
    Next i
    If Not T Is Nothing Then
        MsgBox T.Address
        T.Interior.ColorIndex = 23
 
        'A LA FIN
        Set T = Nothing
    End If
End With
End Sub

Merci pour vos réponse.
je ne savais pas que le range était limité a 30 argument.
Ca m'arrange pas car il risque d'en avoir une centaine d'arguments.

Mais j'ai fait ma procédure autrement pour avoir ce que je voulais.
Je ne passe pas par un range.

Voici ma fonction:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Function format(ncolonne As Integer, nligne As Integer, nom_F As String)
 
Dim i As Integer
Dim j As Integer
Dim k As Integer
 
For j = 1 To ncolonne
    For i = 2 To nligne
        If Worksheets(nom_F).Cells(1, [j]).Value Like "Unité" Then
            If Worksheets(nom_F).Cells([i], [j]).Value Like "%*" Then
                For k = j - 4 To j
                    If Worksheets(nom_F).Cells(1, [k]).Value Like "Prix unitaire*" Then
                    Cells([i], [k]).Select
                    Selection.NumberFormat = "0.00%"
                    End If
                Next k
            Else
                For k = j - 4 To j
                    If Worksheets(nom_F).Cells(1, [k]).Value Like "Prix unitaire*" Then
                    Cells([i], [k]).Select
                    Selection.NumberFormat = "0.00"
                    End If
                Next k
            End If
 
        End If
    Next i
Next j
End Function

en faite j'en ai 3 mais les 2 autres sont du même genre.

jfontaine, la valeur du t est: H2,I2,S2,T2,H5,I5,H6,I6,S6,T6

C'est un exemple mais c'est la forme qu'il a.

Je vous remercie de vous êtes posés la question pour moi.

Mais j'aimerai bien savoir pourquoi mon range(t).select ne marche pas.
Ce n'est pas le nombre d'argument car j'avais testé avec peu de valeur.