Inserer valeur verification

Version imprimable

Bonjour,

J'aurais aimé savoir comment serait il possible de faire :

J'ai un Inputbox ou j'entre un text (abcde-01-005) et je dois verifier si cela existe car si cela existe je dois modifier mon texte.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Sub Etiquette() Dim Message Message = InputBox("etiquette choisie", "question") 'Verification de l'étiquette If Message = Message Then Else Message = InputBox("Etiquette Choisie", "question") End If End Sub
En utilisant une formule j'obtiens le resultat que je souhaite

Citation:

=SI(J883=(RECHERCHEV(J883;ETiquette;1;FAUX));"Cela Existe";"Cela n'existe pas")

Mais je me dis que faire via une macro cela serait plus facile pour mes collègues.

Le soucis est que je calle au if et à l'insertion après dans la cellule ou je me trouve. (en gros je bloque dans le vba :()

DOis je partir de la formule que j'ai ou dois je partir vers des tableaux et autres ?

Merci d'avance

Bonjour,

Pour la recherche un exemple :

Code:

1
2
3
4
5
6
7
8
9
10
11
 
Dim MaPlage As Range,  Frecherche As Range, Marecherche as string
marecherche = range("J883").value
Set MaPlage = Range(Cells(2, 1), Cells(100, 1)) ' Plage de recherche 
On Error Resume Next 
Set Frecherche = MaPlage.Find(MaRecherche)
If Frecherche Is Nothing Then
...
Else
...
Endif

Edit1 : Dans ton exemple tu peux boucler sur ton inputbox tant que l'on trouve la recherche.

Edit2 : Un exemple un peu plus complet :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Sub recherche_valeur()
Dim Mess As String, MaPlage As Range, MonPrompt As String
 
MonPrompt = "Entrer la valeur."
Set MaPlage = Range(Cells(2, 1), Cells(100, 1)) ' Plage de recherche
 
Do
    Mess = InputBox(MonPrompt, "Mon Titre", Mess)
    If Mess = Empty Then:     Exit Do:
Loop While recherche(Mess, MaPlage) = True
 
If Mess > Empty Then
    MsgBox "ok"
Else
    MsgBox "ko"
End If
 
Set MaPlage = Nothing
End Sub
 
Function recherche(ByRef Mess As String, ByRef MaPlage As Range) As Boolean
Dim Frecherche As Range
On Error Resume Next
Set Frecherche = MaPlage.Find(Mess)
If Not Frecherche Is Nothing Then
    recherche = True
    Mess = Mess & " déja dans la feuille !"
End If
On Error GoTo 0
Set Frecherche = Nothing
End Function

13/03/2012, 10h28
isarian

Super merci.

nikel.

Par contre, comment je fait pour savoir la cellule où je me trouve?

Pour inserer quelque choses c'est

Code:

Range("B3").Value = "toto"

Mon code sera donc du style

Code:

Range(cellactu).Value = Mess

le tout est comment obtenir cellactu?

Merci d'avance
15/03/2012, 10h44
isarian

Bonjour je me permets de revenir.

Je pense que je peux passer par une boite pour demande la cellule ou je me trouve. (moyen détourné je le sais).

Mais je n'arrive pas à voircomment faire pour que dans le code il prend cette information. :(

Soit c'est simple et je pense compliqué. soit je vois pas du tout.

Merci d'avance.
15/03/2012, 11h33
gFZT82

Bonjour,

Pour avoir l’adresse de la cellule qui contient le texte recherché, tu peux compléter le message dans la fonction Recherche

Code:

Mess = Mess & " est déjà dans la feuille à l'adresse " & Frecherche.Address

Et pour te positionner sur la cellule

Code:

Frecherche.Select

Cordialement.
15/03/2012, 12h00
isarian

Merci.

le soucis est que je ne veux pas me positionner là où existe l'info.

En fait mon fichier excel est un fichier d'inventaire. Donc quand je dois ajouter un nouvel ellement je dois lui mettre une etiquette, qui doit être unique bien entendu. ET donc je souhaiterais que lors de l'encodage je me positionne dans la cellule pour encoder l'etiquette. Ensuite je clique sur la macro et si l'info est ok, il l'insere sinon ben il me demande un autre.

là pour contourner le soucis je fais comme cela. je demande à l'utilisateur d'indiquer où il se trouve

Code:

loc = InputBox(MonPrompt, "Mon Titre", loc)

et donc après je fais

Code:

Range(loc).Value = Mess
15/03/2012, 13h52
aalex_38

Bonjour à tous,

La franchement je ne vois pas très bien ou est le souci, a moins de n'avoir pas tout à fait compris, peut-être pourrai-tu fournir un fichier exemple, si tu es dans la bonne cellule avant de lancer ta macro, tu peux utiliser ACTIVECELL pour connaitre la cellule active ?
15/03/2012, 14h12
isarian

1 pièce(s) jointe(s)

Voilà ci joint un exemple,

Si je me mets en N4 par exemple j'active la macro, qui me demande d'inserer le nom d'etiquette. Si elle ne correspond à aucun de la même colonne, la macro doit l'inserer en N4. Si elle correspond, la macro devra me redemander un autre.

Merci

Re,

En espérant avoir bien compris ;),

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
Sub recherche_valeur()
Dim Ws As Worksheet
Dim DerLig As Long
Dim Mess As String
Dim MaPlage As Range, Frecherche As Range
Dim MonPrompt As String
Dim NOK As Boolean
    Set Ws = Worksheets("Feuil1")
    DerLig = Ws.Range("N" & Ws.Rows.Count).End(xlUp).Row
    Set MaPlage = Ws.Range(Ws.Cells(2, "N"), Ws.Cells(DerLig, "N")) ' Plage de recherche
    While NOK = False
        MonPrompt = "Entrer la valeur."
        Mess = InputBox(MonPrompt, "Mon Titre", Mess)
        If Mess = Empty Then:     Exit Sub:
        Set Frecherche = MaPlage.Find(Mess)
        If Not Frecherche Is Nothing Then
            MsgBox "Cette etiquette existe déjà." & Chr(10) & _
            "Vous devez saisir un autre libellé d'étiquette."
        Else
            Ws.Range("N" & DerLig + 1) = Mess
            NOK = True
        End If
        Set Frecherche = Nothing
    Wend
    Set MaPlage = Nothing
    Set Ws = Nothing
End Sub

Cordialement.

15/03/2012, 15h21
aalex_38

1 pièce(s) jointe(s)

Bonjour,

Pas trop le temps aujourd'hui de mettre au point ta demande, je joint un fichier exemple avec un evenement change dans la feuille.
15/03/2012, 16h28
isarian

Je vous remercie beaucoup. Mais c'est pas encore tout à fait ca.

Il fait bien une recherche sur ma colonne, il encode ce que je tappe dans la message box. Mais il ne l'encode pas à l'endroit ou je me trouve.

Je n'encode pas forcement à la derniere ligne en fait. Je peux l'encode à la ligne 5, ou apres à la ligne 10 et revenir à la ligne 2 , ...

merci à vous,

P.S, aalex_38 c'est pas grave si tu as pas le temps aujourd hui.

Citation:

Il fait bien une recherche sur ma colonne, il encode ce que je tappe dans la message box. Mais il ne l'encode pas à l'endroit ou je me trouve.

Si je traduis bien :
- la recherche est effectuée sur la colonne N.
- l'enregistrement se fait à l'emplacement de la cellule active.

Comment lances-tu la procédure (Bouton de commande, évènement ) ?

Lancement de la procédure avec un bouton de commande (Recherche)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Option Explicit
Private Sub Recherche_Click()
Dim Ws As Worksheet
Dim DerLig As Long
Dim Mess As String
Dim MaPlage As Range, Frecherche As Range
Dim MonPrompt As String
Dim NOK As Boolean
        Set Ws = Worksheets("Feuil1")
        Set MaPlage = Ws.Range(Ws.Cells(2, "N"), Ws.Cells(Ws.Rows.Count, "N")) ' Plage de recherche
        If ActiveCell.Column = 14 Then
            While NOK = False
                MonPrompt = "Entrer la valeur."
                Mess = InputBox(MonPrompt, "Mon Titre", Mess)
                If Mess = Empty Then:     Exit Sub:
                Set Frecherche = MaPlage.Find(Mess)
                If Not Frecherche Is Nothing Then
                    MsgBox "Cette etiquette existe déjà." & Chr(10) & _
                    "Vous devez saisir un autre libellé d'étiquette."
                Else
                    ActiveCell = Mess
                    NOK = True
                End If
                Set Frecherche = Nothing
            Wend
        Else
            MsgBox "La cellule sélectionnée doit se trouver dans la colonne N"
        End If
        Set MaPlage = Nothing
        Set Ws = Nothing
End Sub

Cordialement.

15/03/2012, 18h00
isarian

Citation:

Citation:
Il fait bien une recherche sur ma colonne, il encode ce que je tappe dans la message box. Mais il ne l'encode pas à l'endroit ou je me trouve.

Si je traduis bien :
- la recherche est effectuée sur la colonne N.
- l'enregistrement se fait à l'emplacement de la cellule active.

Comment lances-tu la procédure (Bouton de commande, évènement ) ?

La recherche s'effectue bien sur la colonne N et l'enregistrement sur la cellule active (voilà comment faire quand on connait les mots exact) Merci.

le plus simple se sera via un bouton macro.

Merci je testerais cela demain.
16/03/2012, 10h18
isarian

Super Nikel.

Mille merci.

en fait donc pour ecrire dans la cellule active c'était juste activecell.

Je cherchais trop loin :p

Merci beaucoup
19/03/2012, 19h42
aalex_38

Bonjour a tous,

Pour activecell, je te l'avais dis ici ;)
20/03/2012, 10h28
isarian

Oui désoler j'avais pas percuter. :(

Mille merci.