[Lazarus] StringGrid : comment faire pour savoir si on a réellement cliqué dans une cellule survolée

StringGrid : comment faire pour savoir si on a réellement cliqué dans une cellule survolée

Bonsoir,

Quand on clique dans un StringGrid, en dehors des cellules, disons à droite de la dernière, MouseToCell renvoie les coordonnées de la dernière cellule, et MouseToGridZone ne renvoie pas gzInvalid : comment faire pour savoir si on a réellement cliqué dans une cellule survolée ?

Grâce à une comparaison des coordonnées de la souris et des limites du rectangle de la cellule renvoyée, je sais si elle est en dehors lors du MouseDown.

Ça me permet de ne pas lancer un traitement lors d'un DoubleClick en dehors d'une cellule, mais dans ce cas, comment bloquer l'entrée en mode édition de la cellule extrême dont il renvoie les coordonnées indûment ?

Bonjour,

Si j'ai bien compris, le problème est de neutraliser le placement "résiduel" avec le Click et le DblClick si le curseur est hors cellule ?

Si tel est le cas, on pourrait

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
procedure TForm1.StringGrid1MouseDown(Sender : TObject; Button : TMouseButton;
  Shift : TShiftState; X, Y : Integer);
{uses  LCLintf;}
var
 P : TPoint;
 Rect : TRect;
begin
 with StringGrid1 do begin
  Rect.TopLeft := CellRect(FixedCols,FixedRows).TopLeft;       
  Rect.BottomRight := CellRect(ColCount -1, Rowcount -1).BottomRight;
  P.X := X;
  P.Y := Y;
 end;
 if not PtInRect(Rect, P) then Abort;
end;

Si on place ce code dans une autre méhode qui ne contient pas "X,Y : Integer" ou par exemple dans procedure TForm1.StringGrid1(Dbl)Click(Sender : TObject); , alors on peut renseigner P ainsi

Code:

1
2
  GetCursorPos(P) ;
  P:=StringGrid1.ScreenToClient(P);

Mais à mon avis, le premier code est suffisant... Si on est hors cellule, le OnDbClick est court-circuité par le Abort du MouseDown : le StringGrid1DblClick n'est pas exécuté (cf code complet ci-dessous). Mais le OnClick l'est... et dans les 2 cas, le non-placement "quand il le faut" dans la cellule est géré correctement.

Cordialement. Gilles

PS : Code complet de la Form pour test

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, Grids,
  LCLintf, StdCtrls;
 
type
 
  { TForm1 }
  TForm1 = class(TForm)
    laDblClick : TLabel;
    laClick : TLabel;
    StringGrid1 : TStringGrid;
    procedure FormCreate(Sender : TObject);
    procedure StringGrid1Click(Sender : TObject);
    procedure StringGrid1DblClick(Sender : TObject);
    procedure StringGrid1MouseDown(Sender : TObject; Button : TMouseButton;
      Shift : TShiftState; X, Y : Integer);
 
  private
    { private declarations }
  public
    { public declarations }
  end;
 
var
  Form1 : TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
procedure TForm1.StringGrid1Click(Sender : TObject);
begin
 laClick.caption := 'Click';
end;
 
procedure TForm1.FormCreate(Sender : TObject);
begin
 laClick.caption := '';
 laDblClick.caption := '';
end;
 
procedure TForm1.StringGrid1DblClick(Sender : TObject);
begin
 laDblClick.caption := 'DblClick';
end;
 
procedure TForm1.StringGrid1MouseDown(Sender : TObject; Button : TMouseButton;
  Shift : TShiftState; X, Y : Integer);
var
 P : TPoint;
 Rect : TRect;
begin
 laClick.caption := '';
 laDblClick.caption := '';
 with StringGrid1 do begin
  Rect.TopLeft := CellRect(FixedCols,FixedRows).TopLeft;
  Rect.BottomRight := CellRect(ColCount -1, Rowcount -1).BottomRight;
  P.X := X;
  P.Y := Y;
 end;
 if not PtInRect(Rect, P) then Abort;
end;
 
end.

Chapeau !

Bien vu. :ccool:

Je ne l'ai pas testé, mais ça semble parfaitement répondre au problème.