Modifier un graphique à l'aide d'une macro

Si j'ai bien compris, il suffit d'ajouter une nouvelle série avec une valeur constante (choisie par l'utilisateur)

Exemple avec un graphique incorporé dans la feuille de calcule Feuil1

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub InsertLigne()
Dim i As Integer
Dim Nb As Double
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")                        'Adapte le nom de la feuille contenant l'objet graphique
    If .ChartObjects.Count >= 1 Then
        With .ChartObjects(1).Chart
            'On supprime toutes les séries sauf la série 1
            If .SeriesCollection.Count > 1 Then
                For i = .SeriesCollection.Count To 2 Step -1
                    .SeriesCollection(i).Delete
                Next i
            End If
            'L'utilisateur saisit la valeur pour laquelle il  veut tracer la ligne sur le graphique
            Nb = Val(InputBox("Entrer la valeur de la ligne"))
            If Nb <> 0 Then .SeriesCollection.NewSeries.Values = Tb(Nb, .SeriesCollection(1).Points.Count)
        End With
    End If
End With
End Sub
 
Private Function Tb(ByVal Nbre As Double, ByVal N As Integer) As Double()
Dim i As Integer
Dim Res() As Double
 
ReDim Res(1 To N)
For i = 1 To N
    Res(i) = Nbre
Next i
Tb = Res
End Function