Intégration d'un résultat d'une Requête SQL dans un fichier .HTA

Version imprimable

Bonjour à tous,
étant débutant en Vbs ainsi qu'en Hta j'aurai besoin de vos lumières afin d'intégrer dans un programme en Hta le résultat d'une requête Sql.
Voici ma requête :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 Dim ChaineConnection Dim NombreDeChamps Dim Colonne Dim FichierResultat Set Connect = CreateObject("ADODB.Connection") Set Sqlresult = CreateObject("ADODB.Recordset") ChaineConnection = "Provider=SQLOLEDB.1;Password=***;User ID=***;Data Source=SOURCE,1433" Connect.ConnectionString = ChaineConnection Connect.Open req = "select [NOM_IMPRIMANTE] from [" & Catalogue &"].[dbo].[PERSO_ORDI_IMP] WHERE [NOM_ORDINATEUR]='" & NomduPoste &"'" Sqlresult.Open req, connect
Voilà où j'en suis ;) . Maintenant je ne sais pas comment afficher mon résultat dans mon Hta.

Salut bienvenue sur DVP

Pour une liste d'imprimante, l'objet SELECT qui ressemble à un ComboBox ou un ListBox me semble opportun.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
<HTML>
	<HEAD>
	<TITLE> Un HTA </TITLE>
		<HTA:APPLICATION
         ApplicationName = "Demo"
         Id="Demo"
		>
   </HEAD>
<SCRIPT language="VBScript" type="text/VBScript" >
'------------------------------------------------------------------------------------------------------------------
Sub Window_Onload()
	Dim ChaineConnection
	Dim NombreDeChamps 
	Dim Colonne
	Dim FichierResultat
 
 
	Set Connect = CreateObject("ADODB.Connection")
	Set Sqlresult = CreateObject("ADODB.Recordset")
 
	ChaineConnection = "Provider=SQLOLEDB.1;Password=***;User ID=***;Data Source=SOURCE,1433"
	Connect.ConnectionString = ChaineConnection
	Connect.Open 
 
	req = "select [NOM_IMPRIMANTE] from [" & Catalogue &"].[dbo].[PERSO_ORDI_IMP] WHERE [NOM_ORDINATEUR]='" & NomduPoste &"'"
 
	Sqlresult.Open req, connect
 
    Dim oOption, V '<----------------
    'vide la liste
    For V = LstImpr.length To 0 Step -1: LstImpr.Remove (V): Next
    V=0
	While Not Sqlresult.EOF
		'ajoute les noms à la liste 
		Set oOption = window.Document.createElement("OPTION")
		oOption.Text = Sqlresult.fields("NOM_IMPRIMANTE")
		oOption.Value = "Option " & V
		LstImpr.Add (oOption)
        V = V + 1
		Sqlresult.MoveNext
    Wend
	Sqlresult.Close: Set Sqlresult = Nothing
	Connect.Close: Set Connect = Nothing
    If V = 0 Then
        Set oOption = window.Document.createElement("OPTION")
        oOption.Text = "Auncune IMPRIMANTE disponnible"
        oOption.Value = V
        LstImpr.Add (oOption)
        LstImpr.disabled = "disabled"
        Else
        LstImpr.disabled = ""
		MsgBox V & " imprimante(s) trouvée(s)"
	End If
End Sub
'------------------------------------------------------------------------------------------------------------------
 </SCRIPT>
	<body>
		<SELECT name="LstImpr" Id="LstImpr" disabled="disabled"> </SELECT>
   </Body>
</HTML>

inspiré du tutoriel Donner une interface à vos script VBS , HTA : Html Application et de mes premières applications.

15/02/2012, 10h42
androo

Merci pour ta réponse. Je vais tester immédiatement :mouarf:

édit : Çà fonctionne parfaitement ! Merci

Par contre si je peux abuser de ta gentillesse :zoubi: j'aurai plutot aimé afficher le resultat sans devoir utiliser le Select ( afficher le nombre d imprimante directement )

Salut

Pour le nombre, avant de fermer la connexion et le RecorSet, MsgBox Sqlresult.Fields.Count ou

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
<HTML>
	<HEAD>
	<TITLE> Un HTA </TITLE>
		<HTA:APPLICATION
         ApplicationName = "essais"
         Id="essais"
		 BorderStyle="normal"
		>
	</HEAD>
	<SCRIPT language="VBScript" type="text/VBScript" >
		Sub Window_Onload()
			'Number.outerText="5" pour confirmer l'essais
			Number.outerText=Sqlresult.Fields.Count
		End Sub
	</SCRIPT>
	<Body>
		<DIV Id="Number"> </DIV>
	</Body>
</HTML>

15/02/2012, 11h41
androo

Je me suis mal exprimé désolé :oops:

En fait j'aimerai éviter d'utiliser l'ascenseur pour pouvoir voir le nom de mes imprimantes, si possible les afficher directement sans devoir les sélectionner.

En tout cas encore merci pour ton aide

Code:

<SELECT name="LstImpr" Id="LstImpr" disabled="disabled" SIZE=4 > </SELECT>

par contre je ne sais pas si ce paramétré peut être actualisé dynamiquement dans ta Sub VBScript

Code:

1
2
3
4
5
6
7
8
9
10
11
    If V = 0 Then
        Set oOption = window.Document.createElement("OPTION")
        oOption.Text = "Auncune IMPRIMANTE disponnible"
        oOption.Value = V
        LstImpr.Add (oOption)
        LstImpr.disabled = "disabled"
        Else
        LstImpr.disabled = ""
		'MsgBox V & " imprimante(s) trouvée(s)"
        LstImpr.SIZE = V+1 ' <--------------------------- ICI ???
    End If

15/02/2012, 14h16
androo

Que dire de plus à part : Tu es un Chef Francis ! :ccool:
Je tagg en Résolu car c'est exactement ce qu'il me fallait
Merci à toi