Recherche multicritères avec listbox

Version imprimable

05/02/2012, 18h08
glc29

Recherche multicritères avec listbox

Bonjour,

Je suis en train de créer un formulaire de recherche.
J'ai pour l'instant une textbox, plusieurs checkbox et plusieurs listbox.

En gros je souhaite que quand j'appuie sur RECHERCHER, la macro recherche toutes les lignes qui contiennent la valeur de la textbox dans la colonne A ET qui contiennent la valeur true dans la colonne B ET qui contiennent l'une des valeur sélectionnée dans la listbox1 dans la colonne C.

Avec mes compétences actuelles, je ne sais pas faire ce type de recherche, et encore moins en ce qui concerne la listbox.

Pouvez vous m'aidez, ou au moins m'aiguiller à ce propos ?

Merci
06/02/2012, 10h03
pijaku

Bonjour,

Pour réaliser ce type de recherche, un facteur important est le nombre de lignes de données à "analyser". En effet, tu disposes de deux méthodes différentes : la recherche dans la feuille (soit avec la méthode find, soit une boucle sur toutes les lignes) ou la recherche "en mémoire", grâce à une variable tableau.

Méthode Find :
Tu cherches dans ta colonne A la valeur contenue dans ton textbox,
Si tu la trouves, tu regardes en B et C si les valeurs correspondent respectivement à ton checkbox et à ta listbox,
si oui : tu as trouvé,
si non : find Next

Méthode de boucle :
Tu boucles sur toutes les lignes de ta BdD, et si Ax = TextBox1, Bx = CheckBox1 et Cx = listBox alors... tua s trouvé

Méthode de variable tableau :
identique à la boucle, mais au lieu de travailler sur ta feuille, tu travailles en mémoire et donc le résultat est plus rapidement trouvé.

Dis nous combien de données tu traites et ensemble nous t'aiguillerons sur la bonne méthode.
06/02/2012, 18h11
glc29

Bonjour,

J'ai grosso modo 1500 lignes actuellement, et chaque année mon fichier grossira de 700 à 1000 lignes.
Chacune de ces lignes sont renseignées sur 15 colonnes.

La méthode boucle me semble bien appropriée (qu'en dites vous?), d'autant plus que je pense être capable de la coder...

Par contre je ne sais pas encore manipuler les données sélectionnées dans une listbox.:oops:

Bonjour,

Citation:

Envoyé par glc29

En gros je souhaite que quand j'appuie sur RECHERCHER, la macro recherche toutes les lignes qui contiennent la valeur de la textbox dans la colonne A ET qui contiennent la valeur true dans la colonne B ET qui contiennent l'une des valeur sélectionnée dans la listbox1 dans la colonne C.

Déjà cela sous entends que plusieurs valeurs peuvent être choisies dans la ListBox1...

Méthode de boucle dans la feuille :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub CommandButton1_Click()
Dim Lig As Long, DrLig As Long
Dim Lignes(), Choix(), valeur
Dim Message As String
Dim Cpt As Integer
Dim i As Byte
 
'boucle sur les éléments de la listbox pour remplir la var tableau des choix
    'cf : http://silkyroad.developpez.com/VBA/ControlesUserForm/#LII-G
For i = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(i) = True Then
        ReDim Preserve Choix(Cpt)
        Choix(Cpt) = ListBox1.List(i)
        Cpt = Cpt + 1
    End If
Next i
Cpt = 0
DrLig = Range("A" & Rows.Count).End(xlUp).Row
For Lig = 2 To DrLig
    If Range("A" & Lig).Value = TextBox1.Value And Range("B" & Lig) = "True" Then
        For Each valeur In Choix
            If Range("C" & Lig) = valeur Then
                ReDim Preserve Lignes(Cpt)
                Lignes(Cpt) = Lig
                Cpt = Cpt + 1
                Exit For
            End If
        Next
    End If
Next Lig
Message = "Valeurs trouvées lignes : " & Chr(10)
For i = LBound(Lignes) To UBound(Lignes)
    Message = Message & Lignes(i) & Chr(10)
Next
MsgBox Message
End Sub

Mais comme tu va très vite dépasser les 5-10 000 lignes, la seconde méthode :
remarque : les deux sont sensiblement identiques, la différence n'est réelle que pour :
- la maintenance de la procédure qui risque d'être plus complexe si tu ne maîtrise pas les variables tableau (inconvénient...)
- la rapidité d'exécution sur des feuilles de 10 - 15 000 lignes (avantage...)

Méthode de boucle sur variable tableau (travail en mémoire) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Dim Lig As Long, DrLig As Long
Dim Lignes(), Choix(), TablDonnées(), valeur
Dim Message As String
Dim Cpt As Integer
Dim i As Byte
 
'boucle sur les éléments de la listbox pour remplir la var tableau des choix
    'cf : http://silkyroad.developpez.com/VBA/ControlesUserForm/#LII-G
For i = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(i) = True Then
        ReDim Preserve Choix(Cpt)
        Choix(Cpt) = ListBox1.List(i)
        Cpt = Cpt + 1
    End If
Next i
Cpt = 0
'Remplissage de la var tableau contenant toutes les données contenues dans la feuille
DrLig = Range("A" & Rows.Count).End(xlUp).Row
TablDonnées = Application.Transpose(Range("A2:C" & DrLig).Value)
For Lig = 2 To DrLig
    If TablDonnées(1, Lig - 1) = TextBox1.Value And TablDonnées(2, Lig - 1) = "True" Then
        For Each valeur In Choix
            If TablDonnées(3, Lig - 1) = valeur Then
                ReDim Preserve Lignes(Cpt)
                Lignes(Cpt) = Lig
                Cpt = Cpt + 1
                Exit For
            End If
        Next
    End If
Next Lig
Message = "Valeurs trouvées lignes : " & Chr(10)
For i = LBound(Lignes) To UBound(Lignes)
    Message = Message & Lignes(i) & Chr(10)
Next
MsgBox Message
End Sub

Teste les deux méthodes et reviens nous dire ce qui convient ... ou pas!...