Quelle différence entre ces deux constantes ?

Version imprimable

10/12/2011, 16h46
Vincent Heude

Quelle différence entre ces deux constantes ?

Bonjour à tous

Dans 4D Write, quelle est la différence entre ces 2 constantes :
WR nb insertions numéro page
et
WR nb pages

Je suis toujours à la recherche d'une méthode permettant l'affichage d'un numéro de page (de 1 à n) sachant que la 1ère page de la zonewrite de mon 1er enregistrement est 1 et la dernière page de mon dernier enregistrement est n.

Aujourd'hui, 4D Write n'a pas prévu ce type de besoin alors même que 4D est une base de données RELATIONNELLES et que le concepteur de 4D Write aurait pu imaginer qu'un utilisateur puisse mettre dans un enregistrement, une zone Write et que l'ensemble de ces zones soient utilisées pour en éditer (imprimer) un document unique dont les pages seraient numérotées de 1 à n !!

Merci d'avance pour vos idées

voici une piste, je ne sais pas si cela fonctionnera sur de gros document :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
$vt_path:=Selectionner dossier("Destination ?")
Si ($vt_path#"")
	$vt_path:=$vt_path+"zeDoc.pdf"
 
	TOUT SELECTIONNER([DOCUMENTS])
	$vl_write:=WR Hors ecran 
	$vl_doc:=WR Hors ecran 
	WR FIXER OPTION IMPRESSION ($vl_doc;wr option destination ;wr vers fichier PDF ;0;$vt_path)
 
	Boucle ($i;1;Enregistrements trouves([DOCUMENTS]))
		LIEN RETOUR([DOCUMENTS]doc_id)
 
		TRIER([CHAPITRES];[CHAPITRES]chap_id;>)
 
		Boucle ($j;1;Enregistrements trouves([CHAPITRES]))
			WR BLOB VERS ZONE ($vl_write;[CHAPITRES]chap_texte_)
			WR EXECUTER COMMANDE ($vl_write;wr cmd tout sélectionner )
			WR EXECUTER COMMANDE ($vl_write;wr cmd copier )
 
			WR EXECUTER COMMANDE ($vl_doc;wr cmd coller )
			WR EXECUTER COMMANDE ($vl_doc;wr cmd insérer saut de page )
			ENREGISTREMENT SUIVANT([CHAPITRES])
		Fin de boucle 
 
		WR FIXER CADRE ($vl_doc;wr pied de page droit )
		WR INSERER TEXTE ($vl_doc;"Page ")
		WR INSERER NUMERO DE PAGE ($vl_doc;wr 123 ;wr numéro de page )
		WR INSERER TEXTE ($vl_doc;" sur ")
		WR INSERER NUMERO DE PAGE ($vl_doc;wr 123 ;wr nombre de pages )
 
		WR IMPRIMER ($vl_doc;wr impression valeurs ;0;1)
 
		ENREGISTREMENT SUIVANT([DOCUMENTS])
	Fin de boucle 
 
	WR DETRUIRE HORS ECRAN ($vl_write)
	WR DETRUIRE HORS ECRAN ($vl_doc)
Fin de si

sinon, sans passer par le pied de page :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
 
TOUT SELECTIONNER([DOCUMENTS])
$vl_write:=WR Hors ecran 
 
Boucle ($i;1;Enregistrements trouves([DOCUMENTS]))
	LIEN RETOUR([DOCUMENTS]doc_id)
 
	Boucle ($j;1;Enregistrements trouves([CHAPITRES]))
		WR BLOB VERS ZONE ($vl_write;[CHAPITRES]chap_texte_)
		[CHAPITRES]chap_nb_pages:=WR Compter ($vl_write;wr nb pages )
		STOCKER ENREGISTREMENT([CHAPITRES])
		ENREGISTREMENT SUIVANT([CHAPITRES])
	Fin de boucle 
 
	LIEN RETOUR([DOCUMENTS]doc_id)
	$z:=1
	$vl_nbp:=Somme([CHAPITRES]chap_nb_pages)
	TRIER([CHAPITRES];[CHAPITRES]chap_id;>)
 
	Boucle ($j;1;Enregistrements trouves([CHAPITRES]))
 
		WR BLOB VERS ZONE ($vl_write;[CHAPITRES]chap_texte_)
 
		Boucle ($k;1;[CHAPITRES]chap_nb_pages)
 
			WR FIXER POSITION CURSEUR ($vl_write;$k;1;1;1)
			WR INSERER TEXTE ($vl_write;"Page "+Chaine($z)+" sur "+Chaine($vl_nbp))
 
			$z:=$z+1
		Fin de boucle 
 
		WR IMPRIMER ($vl_write;wr impression valeurs ;0;1)
		ENREGISTREMENT SUIVANT([CHAPITRES])
	Fin de boucle 
 
	ENREGISTREMENT SUIVANT([DOCUMENTS])
Fin de boucle 
 
WR DETRUIRE HORS ECRAN ($vl_write)

http://zefif.free.fr//info/structwrite.png

test effectué sur 1000 pages sans problème :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
CREER ENREGISTREMENT([DOCUMENTS])
[DOCUMENTS]doc_name:="doc "+Chaine([DOCUMENTS]doc_id)
STOCKER ENREGISTREMENT([DOCUMENTS])
 
Boucle ($i;1;100)
	CREER ENREGISTREMENT([CHAPITRES])
	[CHAPITRES]doc_id:=[DOCUMENTS]doc_id
	[CHAPITRES]chap_titre:=[DOCUMENTS]doc_name+" - Chap "+Chaine([CHAPITRES]chap_id)
	$vl_write:=WR Hors ecran 
	Boucle ($J;1;10)
		WR INSERER TEXTE ($vl_write;[CHAPITRES]chap_titre+" page "+Chaine($j))
		WR EXECUTER COMMANDE ($vl_write;wr cmd insérer saut de page )
	Fin de boucle 
 
	[CHAPITRES]chap_texte_:=WR Zone vers blob ($vl_write;1)
	[CHAPITRES]chap_nb_pages:=WR Compter ($vl_write;wr nb pages )
	WR DETRUIRE HORS ECRAN ($vl_write)
	STOCKER ENREGISTREMENT([CHAPITRES])
Fin de boucle

11/12/2011, 15h02
Vincent Heude

Bonjour Philippe

merci pour tes propositions.
En relisant mon post et tes réponses, je me rends compte que je n'ai pas été aussi clair que ce que je le pensais et je m'en excuse.

Si j'ai bien compris, ton code permet de créer temporairement une ZoneWrite hors écran, d'y concaténer toutes les ZonesWrite des # chapitres, de numéroter l'ensemble par "insérer numéro de page" et de l'imprimer.

Donc, ton code est super car il garantit que, dans le cas d'une impression de l'ensemble des chapitres, la numérotation sera cohérente et fiable au moment ou je lance l'impression globale.

C'est en cela que je n'ai pas été clair : en effet, l'utilisateur doit pouvoir n'imprimer que le chapitre x, y ou z mais que la numérotation dans le pied de page tienne bien compte de la position de ces chapitres à l'intérieur de tous les chapitres de la base [Documents]. La numérotation doit donc bien être présente de façon permanente dans chaque page des ZoneWrite.
Même si elle ne se fait pas à la volée dès qu'une nouvelle page est créée. Cela peut se faire à la validation de l'enregistrement par exemple

Pour le moment, j'ai réussi à extraire (grâce à une addition de "WR Compter") et sauvegarder dans la table [Chapitres] un nombre qui représente le n° de la 1ère page (stocké dans le champ [Chapitres]De_Page) et celui de la dernière page (stocké dans le champ [Chapitres]A_Page) de chaque ZW de [Chapitres].
Mais je ne sais pas utiliser ces données pour incrémenter une variable qui serait dans le pied de page. Du genre :
si on est en page 2 de la ZW du chapitre n
alors MaVarPage:= de_Page +1
Etc...

Et je ne trouve pas de commande qui me permette de lire le n° de page dans laquelle on se trouve ou qui permette de faire une boucle testant toutes les pages d'une ZW.

L'idéal serait que :
WR INSERER NUMERO DE PAGE ($vl_doc;wr 123 ;wr nombre de pages ) renvoie une valeur...
11/12/2011, 18h16
ZeFiF

si tu utilises ma méthode en mode "bourrin" ça pourrait peut être le faire.

Tu commences par tout numéroter et tu n'imprimes que la sélection de l'utilisateur...

j'ai bon ?
12/12/2011, 14h07
Vincent Heude

si tu utilises ma méthode en mode "bourrin" ça pourrait peut être le faire.

Ca veut dire quoi "en mode bourrin" ?
12/12/2011, 14h24
ZeFiF

c'est une méthode (décrite dans mon message) qui consiste à tout calculer avant de faire une action.
C'est le contraire de procéder enregistrement par enregistrement.

L'approche est donc globale et non parcellaire.

au lieu de dire approche globale qui fait très prétentieux mais qui place bien dans une conversation avec un client du genre directeur financier, avec mes pairs j'utilise le vocable "méthode bourrin" qui indique que c'est simple et efficace sans chercher de complications alors qu'on pourrait objecter que c'est employer un rouleau compresseur pour écraser un caillou.

C'est toutefois une méthode qui peut s'avérer inadaptée en cas de gros volume de données ou de traitements lourds à opérer.

Le mieux étant parfois l'ennemi du bien, cette méthode peut être comprise comme moins élégante que l'approche parcellaire toutefois il y a matière à débat.

mhhh.... ça n'a pas l'air de t'inspirer grandement mon élan philosophique.
Aujourd'hui il fait grand soleil en Alsace : ça donne soif ! :ccool:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
$vt_path:=Selectionner dossier("Destination ?")
Si ($vt_path#"")
 
	$vt_path:=$vt_path+"zeDoc.pdf"
 
	TOUT SELECTIONNER([DOCUMENTS])
	$vl_write:=WR Hors ecran 
	$vl_doc:=WR Hors ecran 
	WR FIXER OPTION IMPRESSION ($vl_doc;wr option destination ;wr vers fichier PDF ;0;$vt_path)
 
	Boucle ($i;1;Enregistrements trouves([DOCUMENTS]))
		LIEN RETOUR([DOCUMENTS]doc_id)
 
		TRIER([CHAPITRES];[CHAPITRES]chap_id;>)
 
		Boucle ($j;1;Enregistrements trouves([CHAPITRES]))
			WR BLOB VERS ZONE ($vl_write;[CHAPITRES]chap_texte_)
			[CHAPITRES]chap_nb_pages:=WR Compter ($vl_write;wr nb pages )
			STOCKER ENREGISTREMENT([CHAPITRES])
 
			WR EXECUTER COMMANDE ($vl_write;wr cmd tout sélectionner )
			WR EXECUTER COMMANDE ($vl_write;wr cmd copier )
 
			WR EXECUTER COMMANDE ($vl_doc;wr cmd coller )
			WR EXECUTER COMMANDE ($vl_doc;wr cmd insérer saut de page )
			ENREGISTREMENT SUIVANT([CHAPITRES])
		Fin de boucle 
 
		WR FIXER CADRE ($vl_doc;wr pied de page droit )
		WR INSERER TEXTE ($vl_doc;"Page ")
		WR INSERER NUMERO DE PAGE ($vl_doc;wr 123 ;wr numéro de page )
		WR INSERER TEXTE ($vl_doc;" sur ")
		WR INSERER NUMERO DE PAGE ($vl_doc;wr 123 ;wr nombre de pages )
 
 
		Si (Nombre de parametres=0)
			$ve_de:=1
			$ve_a:=WR Compter ($vl_doc;wr nb pages )
		Sinon 
 
			CHERCHER([CHAPITRES];[CHAPITRES]chap_id<$1)
			$ve_de:=Somme([CHAPITRES]chap_nb_pages)
			CHERCHER([CHAPITRES];[CHAPITRES]chap_id=$1)
			$ve_a:=$ve_de+[CHAPITRES]chap_nb_pages
			$ve_a:=$ve_a-1
			$ve_de:=$ve_de+1
		Fin de si 
 
		WR FIXER OPTION IMPRESSION ($vl_doc;wr option pages de ;$ve_de)
		WR FIXER OPTION IMPRESSION ($vl_doc;wr option pages à ;$ve_a)
		WR IMPRIMER ($vl_doc;wr impression valeurs ;0;1)
 
		ENREGISTREMENT SUIVANT([DOCUMENTS])
	Fin de boucle 
 
	WR DETRUIRE HORS ECRAN ($vl_write)
	WR DETRUIRE HORS ECRAN ($vl_doc)
 
	Si (Tester chemin acces($vt_path)=Est un document )
		OUVRIR URL WEB($vt_path)
	Fin de si 
Fin de si

12/12/2011, 16h16
Vincent Heude

Va pour la méthode "bourrin" surtout que les applications que les utilisateurs pourront développer ne devraient jamais dépasser 500 pages tous chapitre confondus.

Mais je ne comprends pas comment ils vont faire s'ils désirent imprimer le chapitre 5 seulement (par exemple).
En effet, toutes les pages de tous les chapitres étant concaténées dans une seule ZW hors écran, comment vont-ils choisir puisque la notion de chapitre n'existe plus. Seuls des numéros de pages pourraient permettre de limiter l'impression (de page x à page y). Mais ils ne les connaîtront pas car ils ne sont pas écrits dans les pieds de page.

j'en reviens à ma première idée :
Comment faire pour que les n° de page (par référence à la base entière et non pas par référence à la seule ZW du chapitre "machin") apparaissent en pied de chaque page ?

Visiblement, mon besoin semble assez exotique
ou bien 4D write n'a pas imaginé qu'un tel besoin pourrait exister...

à te lire...
12/12/2011, 16h39
ZeFiF

tu rajoutes un bouton "imprimer" en regard de ta sélection de chapitre.
Tu appelles la fonction avec le n° de chapitre en paramètre...

Si tu en reviens à ta première idée, c'est de l'approche parcellaire qui à mon avis te bloque dans ta progression.

Quand à 4D lui même je doute que c'est un besoin exotique qu'il ne puisse résoudre.
13/12/2011, 14h27
Vincent Heude

Bonjour Philippe

Pour 4D tu as raison, il existe une commande que personne n'avait trouvée :
WR Fixer Propriété Document(Zone; WR première Page; valeur)

qui permet de débuter la numérotation d'une ZW non pas à 1 (par défaut) mais à "valeur" entier long qui es une valeur connue et déjà présente dans ma base.

Je viens de le tester, cela fonctionne et permet d'écrire en pied de chaque page le n° désiré.

Ton code reste valide pour ce qui est du nb total de pages dans la base
et merci pour cela.
13/12/2011, 14h30
ZeFiF

Bonjour Vincent,

jette quand même un oeil sur la dernière version de code qui donne soif...

c'est à mon humble avis plus simple et plus ROBUSTE que de bidouiller les pages...

hth
FiF
13/12/2011, 19h01
Vincent Heude

Bonsoir Philippe
Je viens de tester ton code qui donne soif !
J'ai créé un bouton en pied de liste de [Chapitres]
Effectivement cela donne un doc en ".PDF"
tout à fait imprimable même qu'on peut sélectionner les pages à imprimer dans le cadre du gestionnaire d'impression de la machine (Mac en l'occurrence)

Mais c'est long : environ 15 secondes pour 46 pages au total et le thermomètre de progression apparait à 6 reprises autant de fois qu'il y a de [Documents] dans ma base.

Ces 6 enregistrements possèdent en tout 23 enregistrements liés [Chapitres] (46 pages de WR); Ce qui est peu somme toute.

Quand on aura 40 ou 50 [Documents] et 200 ou 300 pages, çà sera lourd et lent.
Et cela ne répond pas au besoin des utilisateurs de savoir dans quelle page ils sont quand ils y font de la saisie puisque la pagination n'apparait que dans le Doc ".PDF".

Peut-être ai-je mal placé ton code, mais en pied de liste m'apparait la meilleure solution car il n'est pas question de déranger l'utilisateur en pleine saisie d'un texte dans le format page de [Chapitres].

Dis-moi si je résonne comme un tambour !
ici à Toulouse, il crachine comme dans ma Normandie natale, mais...
c'est quand même l'heure de l'apéro !
Tchin !!
13/12/2011, 19h09
ZeFiF

t'es pas obligé de faire une sélection sur tout les documents !

je tiens à ta disposition ma base de test qui te permettra peut être de ne plus faire le tambour... :mrgreen:
13/12/2011, 19h17
ZeFiF

Citation:

Envoyé par Vincent Heude

Et cela ne répond pas au besoin des utilisateurs de savoir dans quelle page ils sont quand ils y font de la saisie puisque la pagination n'apparait que dans le Doc ".PDF".

ah ça tu n'en avais pas parlé non plus....
13/12/2011, 19h20
Vincent Heude

Comme disait ma grand-Mère, "Tout ce qui tombe dans le fossé est bon pour le soldat"
donc le soldat Vincent (bleusaille de chez bleusaille) prendra volontiers ta base test !

merci d'avance
13/12/2011, 19h31
Vincent Heude

Excuse-moi, si je n'ai pas été clair.

En fait, mes futurs utilisateurs, comme je te l'ai peut-être dit il y a quelques mois, travaillent actuellement avec Word et parfois même Powerpoint pour réaliser des guides pour les formateurs (dont je fais partie) et rament comme des fous parce que :
1 - ils ne connaissent pas bien ces logiciels
2 - leur job les oblige à changer parfois beaucoup de choses dans leur rédaction (comme par exemple, passer le chapitre 5 en position 2) ; ce qui les contraint à retravailler à la main par copier-coller toutes les numérotations de documents, chapitres, pagination, sommaire, etc...

Donc, le job que je me suis fixé est de leur faciliter la tâche (plus rapide, plus pratique) et par conséquence plus rapide et plus pratique pour les formateurs;

je sais que ce que je fais est totalement "Ad hoc" pour l'entreprise qui m'emploie. Je trouverais peut-être un jour une adaptation possible pour d'autres métiers, d'autres sociétés.

En tous cas, merci pour le temps que tu passes à tenter de résoudre mes questions.