[VS2010] Fichier de config

Version imprimable

20/09/2011, 09h47
hunteshiva

[VS2010] Fichier de config

Bonjour,

J'aimerais avoir un ou plusieurs fichiers de config que mon appli vb pourrait lire et modifier au besoin.
je pensé à un fichier .csv, mais je ne trouve pas de tuto sur la lecture ou l'écriture de ces fichiers.
j'ai la net impression que ce n'est pas ou plus utilisé...

j'aimerais votre avis sur la question
20/09/2011, 09h55
BenoitM

Fait une recheche sur l' "AppConfig" , il est spécialement crée pour ca ;)
20/09/2011, 10h15
hunteshiva

Merci Benoit,
mais cette solution en me parait pas très simple...

je précise un peut l'environnement,
je suis sur une appli industrielle qui simule des courbes de chauffes des produits.

l'idée est de faire appel à des fichiers *mini base de données*
qui contiennent par exemple les formats de produits, ou des emballages.
On n'atteint pas de grosses quantités d'infos (pas plus de 20 - 30 types)

c'est pour ça que faire des mini-fichiers me paraissait simple,
les données n'ont pas besoin d’être sécurisées.

PS: je reste ouvert à des propositions
20/09/2011, 10h25
Nathanael Marchand

Ben si c'est une mini-base de données autant mettre une vraie base de données :aie:
Un SQL Server Compact ou SQLite par exemple :)
20/09/2011, 10h28
hunteshiva

Merci pour toutes ces idées,
mais le code a supporté n'est-il pas un peut lourd juste pour une base de 20-30 lignes?
20/09/2011, 10h29
asmduty

Parcourir et maintenir un fichier (via le code) est moins efficace et moins facile qu'une base de données.
20/09/2011, 10h35
hunteshiva

Entièrement d'accord avec toi asmduty,
mais cette vérité ne se justifie-t-elle pas qu'a partir de quelques milliers de lignes?
20/09/2011, 10h50
BenoitM

tu peux alors peut-être passer par un dataset et un fichier xml (il y a une méthode fourni par le framework pour sauvé le DataSet au format xml)
20/09/2011, 10h50
Pol63

pour quelques infos, le fichier xml est suffisant
il y a la sérialisation xml qui est simple à mettre en place

tu fais une classe avec tes propriétés (même des collections)
ensuite tu as une instrucion pour écrire l'instance dans un fichier xml
et une instruction pour charger le fichier xml dans l'instance
(voir system.xml.serialization.xmlserializer)

il faut gérer le design pattern singleton au passage
hors le code des paramètres en propriétés, il faut une dizaine de lignes de code pour gérer la lecture et la sauvegarde

Le xml ok mais pourquoi?

je ne voit pas l’intérêt de ce genre de fichier optimisé pour les balises xml...
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Dim elemSite As XmlElement elemSite = XmlDoc.CreateElement("SITE") 'creation et definition de la balise url (enfant) Dim elemUrl As XmlElement elemUrl = XmlDoc.CreateElement("URL") elemUrl.InnerText = " http://www.peuw.net/index.xml " 'creation et definition de la balise Nom (enfant) Dim elemNom As XmlElement elemNom = XmlDoc.CreateElement("NOM") elemNom.InnerText = peuw.net
l'idée est de récupérer les données sous forme de tableaux *simple*
je sais que le csv avec un "split()" fonctionne nikel

j'aimerais même créer des structures si c'est possible
Code:

1 2 3 4 5 'exemple d'aboutissement emballage(0).largeur emballage(0).longueur emballage(0).hauteur '...

20/09/2011, 11h35
Pol63

je propose la sérialisation xml pour différentes raisons : (liste non exhaustive des avantages du fichier xml)
déjà tu n'as aucune question à te poser sur les formats, une date, un nombre décimal, un tableau ou collection etc... ca peut poser des problèmes dans certains cas
le framework va s'occuper de tout

de plus en .net on code en POO (classes, propriétés etc...)
donc faire des classes qui contiennent les paramètres est essentiel
ensuite si tu fais de la lecture ligne par ligne pour lire les paramètres et les ranger au bon endroit dans ton code, ca va te prendre une ligne par variables
ca fait long pour rien, c'est spécifique
avec la sérialisation xml, 2 lignes pour charger tout (pas une par variable) et 2 pour sauvegarder

autre raison, la maintenance
si dans une semaine tu rajoutes un paramètre, il va te falloir coder le split qui va avec pour la lecture, et l'écriture aussi
avec la sérialisation rien à modifier, la propriété de la classe sera prise en compte automatiquement

il y a aussi l'interopérabilité, n'importe qui pourra lire le xml sans te demander comment c'est codé dedans

exemple si tu as une classe emballage avec comme propriétés largeur, longueur et hauteur
tu peux faire une collection emballages as list(of emballage)
tu pourras en avoir autant que tu veux dans la collection, et rien à coder

et je parle bien de sérialisation xml, et pas de manipulation d'xml, utiliser xmlelement et autre n'est pas utile, la sérialisation englobe tout le traitement
20/09/2011, 11h57
hunteshiva

Tout ça me parait trés optimisé te suis prêt a adhérer à ta cause Pol63
si tu me l'explique en me montrant 2-3 lignes de code :mouarf:

je veux récupérer les données un peut sous forme de tableau
*aperçu de l'existant*
http://img844.imageshack.us/img844/384/fromat.png
20/09/2011, 11h58
yonpo

Salut,

Je pense également que la sérialisation xml est un bonne solution pour ce que tu veux faire à condition de travailler en POO. Jetes un coup d'oeil pour découvrir : http://tlevesque.developpez.com/dotn...serialization/

Tu créé une classe qui a pour propriété chaque colonne de ton tableau.
(Propiété 1 => Colonne 1, etc).
Ensuite avec une List(Of TaClasse) tu auras les données rangées correctement.
Une ligne de la liste => une ligne du tableau.
20/09/2011, 12h08
hunteshiva

OK, je vais travailler dessus
ça a pas l'air simple a première vue, mais ça semble puissant :mrgreen:
*après je n'ai pas besoin de tout ça, les formats que j'utilise sont basique: texte, entier ou flottant*
20/09/2011, 12h23
Pol63

Citation:

Envoyé par hunteshiva

Tout ça me parait trés optimisé te suis prêt a adhérer à ta cause Pol63
si tu me l'explique en me montrant 2-3 lignes de code :mouarf:

je veux récupérer les données un peut sous forme de tableau
*aperçu de l'existant*
http://img844.imageshack.us/img844/384/fromat.png

et les colonnes de ce tableau c'est quoi ?
20/09/2011, 13h59
hunteshiva

C'est de l'existant *pas forcement ce que je veux conserver* :mouarf:

Si je devais dedonner un nom aux colonnes ce serrait:

Citation:

NomEmballage | Type | NomTaille1 | ValeurTaille1 | NomTaille2 | ValeurTaille2 | NomTaille3 | ValeurTaille3

le tableau est coupé, il est conçu pour stocker les cotes d'emballage 3D
*or je n'ai que des emballages Cylindrique*

je pense m'orienter vers un tableau à 3 colonnes

Citation:

Nom | Diamètre | Hauteur
20/09/2011, 14h15
Pol63

cette liste est fournie avec le logiciel ?
modifiable par l'utilisateur ?

les emballages ne devraient-ils pas avoir des "colonnes" différentes selon leur type ?
20/09/2011, 14h27
hunteshiva

Oui, l'idée est que l'utilisateur puisse choisir un format d'emballage dans une liste,
et si il n’existe pas, l'utilisateur le créer
*je pense même a ajouter une fonction pour supprimer des emballages*

une idée en POO, tu peux t'en inspirer au travers des différents concepts utilisés :
une classe emballage
une classe par type d'emballage (rectangle, sphère etc...)
il faut ensuite faire de l'héritage (un emballage rectangle est un emballage)
après pour les propriétés, il faut se poser la question "où la déclarer"
si c'est une propriété commune à tous les emballages, il faut la mettre sur la classe de base (comme le nom)
si c'est une propriété spécifique (diamètre pour la sphère) il faut la mettre sur la classe fille
si c'est commun mais différent pour chaque, il faut le déclarer sur la classe de base avec le mot clé mustoverride (oblige les classes filles à définir le code du membre)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
 
'l'attribut XmlInclude est nécessaire pour dire que la classe héritée est sérialisable
<System.Xml.Serialization.XmlInclude(GetType(EmballageRectangle)), System.Xml.Serialization.XmlInclude(GetType(EmballageRond))> _
Public MustInherit Class Emballage
 
    Protected Sub New()
    End Sub
 
    Private _Nom As String
    Public Property Nom As String
        Get
            Return _Nom
        End Get
        Set(value As String)
            _Nom = value
        End Set
    End Property
 
    ' MustOverride pour dire que les classes filles doivent définir le code, on déclare seulement ici
    ' Overrides signifie que l'on redéfini le code pour ne pas utiliser l'existant (ToString existe sur la classe Object dont toutes les classes héritent)
    ' ToString est appelé souvent, par exemple en mettant un Emballage dans un listbox, celui ci va appeler tostring pour savoir quoi afficher
    Public MustOverride Overrides Function ToString() As String
 
 
 
    Private Shared _Types As List(Of Emballage)
    Public Shared Function Types() As List(Of Emballage)
        Return _Types
    End Function
 
    ' le shared sub new d'une classe est appelé automatiquement lorsqu'on utilise la classe pour la 1ère fois à l'exécution du code
    ' il n'est appelé qu'une unique fois lors de l'exécution
    Shared Sub New()
        ' si le fichier n'existe pas (1er démarrage ou jamais d'écriture) on initialise quand même _Types avec le new mais la collection restera vide vu qu'on sort avec Exit Sub
        If Not System.IO.File.Exists("emballages.xml") Then
            _Types = New List(Of Emballage)
            Exit Sub
        End If
 
 
        ' en passant ici, ca veut dire que le fichier existe, donc on va le lire pour charger la variable _Types
 
        ' on déclare le désérialiseur en lui donnant le type de l'instance qui est dans le fichier (ici une collection d'emballages)
        Dim s As New System.Xml.Serialization.XmlSerializer(GetType(List(Of Emballage)))
 
        Using fs As New System.IO.FileStream("emballages.xml", IO.FileMode.Open) ' filestream permet d'accéder à un fichier, mode open pour lire
            _Types = DirectCast(s.Deserialize(fs), List(Of Emballage))
            'pour désérialiser, on fournit l'accesseur du fichier, et le type censé être dans le fichier (le new sera appelé par Deserialize)
            'il faut utiliser directcast car Deserialize sert pour tous les types, et donc retourne un Objet mais on sait que notre fichier est fait pour un list(of emballage)
        End Using
 
    End Sub
 
    Public Shared Sub SauvegardeFichierXml()
        ' on déclare le désérialiseur en lui donnant le type de l'instance qui est dans le fichier (ici une collection d'emballages)
        Dim s As New System.Xml.Serialization.XmlSerializer(GetType(List(Of Emballage)))
 
        Using fs As New System.IO.FileStream("emballages.xml", IO.FileMode.Create) ' filestream permet d'accéder à un fichier, mode create pour créer (remplacer si existant)
            s.Serialize(fs, _Types) ' à partir de l'instance _Types, ca écrit le fichier complètement
        End Using
 
    End Sub
 
End Class
 
 
 
Public Class EmballageRectangle
    Inherits Emballage
 
    Private _Largeur As Decimal
    Public Property Largeur As Decimal
        Get
            Return _Largeur
        End Get
        Set(value As Decimal)
            _Largeur = value
        End Set
    End Property
 
    Private _Hauteur As Decimal
    Public Property Hauteur As Decimal
        Get
            Return _Hauteur
        End Get
        Set(value As Decimal)
            _Hauteur = value
        End Set
    End Property
 
    Private _Profondeur As Decimal
    Public Property Profondeur As Decimal
        Get
            Return _Profondeur
        End Get
        Set(value As Decimal)
            _Profondeur = value
        End Set
    End Property
 
    Public Overrides Function ToString() As String
        Return Me.Nom & " (L:" & Largeur.ToString & " H:" & Hauteur.ToString & " P:" & Profondeur.ToString & ")"
    End Function
 
End Class
 
 
 
Public Class EmballageRond
    Inherits Emballage
 
    Private _Diametre As Decimal
    Public Property Diametre As Decimal
        Get
            Return _Diametre
        End Get
        Set(value As Decimal)
            _Diametre = value
        End Set
    End Property
 
    Public Overrides Function ToString() As String
        Return Me.Nom & " (0:" & Diametre.ToString & ")"
    End Function
 
End Class

je n'ai pas mis de try catch mais il en faut (et gérer ce qu'on fait si ca ne marche pas)
parce que lire un fichier ca peut planter
désérialiser ca peut planter aussi si le code xml ne correspond pas (si quelqu'un a modifié à la main en oubliant une > par exemple)

voici ce que j'ai utilisé pour tester le code : (form1, listbox1, button1)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Public Class Form1
 
    Public Sub New()
        InitializeComponent()
 
 
        Me.ListBox1.Items.AddRange(Emballage.Types.ToArray)
        'l'appel à emballage.types va déclencher le shared sub new et donc le chargement, et les instances seront mises dans le listbox
        'comme dit précédemment celui ci va appeler ToString pour savoir quoi afficher
    End Sub
 
 
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim r As New EmballageRectangle
        r.Nom = "rect 1"
        r.Hauteur = 50
        r.Largeur = 80.5D
        Emballage.Types.Add(r)
        Emballage.SauvegardeFichierXml()
        Me.ListBox1.Items.Clear
        Me.ListBox1.Items.AddRange(Emballage.Types.ToArray)
    End Sub
 
End Class

et voici le contenu du fichier avec un seul emballage :

Code:

1
2
3
4
5
6
7
8
<?xml version="1.0"?>
<ArrayOfEmballage xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
  <Emballage xsi:type="EmballageRectangle">
    <Largeur>80.5</Largeur>
    <Hauteur>50</Hauteur>
    <Profondeur>0</Profondeur>
  </Emballage>
</ArrayOfEmballage>

avec plusieurs emballages il y aura plusieurs fois <Emballage>(...)</Emballage>

après pour en supprimer un, tu le supprimes de la collection et tu resauvegarde derrière

Code:

Emballage.Types.Remove(un_emballage)

(il est aussi possible d'en modifier)

non expliqué : Shared, MustInherit, Inherits, Using/End Using, Collection ; mais ce sont des concepts de base donc tu vois surement ce que ca signifie ...
je n'ai pas expliqué non plus comment manipuler le tout si tu en as besoin après, voir : For Each, TypeOf, linq to object (facultatif mais bien pratique)