[XL-2007] Texte defilement sur Form

Texte defilement sur Form

Bonjour,
Serait-il possible de faire défiler un texte sur une form comme dans les NEWS.

Merci

Bonjour

Merci de consulter la FAQ : Comment faire défiler un texte dans un UserForm ?

Philippe

Ok c'est noté :oops:
merci ca marche !!

Boujour,

Ou alors, une autre façon de faire avec un Label. Pour tester, mets le code ci-dessous dans le module de la Form et pose un Label nommé Label1 puis lance la Form. Le réglage de la vitesse de défilement se fait dans la proc "Chrono()" :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
 
Private Declare Function GetTickCount _
                         Lib "Kernel32" () As Long
 
Dim ArretDefil As Boolean
Dim Texte As String
 
Sub Minuterie(Milliseconde As Long)
 
    Dim Arret As Long
 
    Arret = GetTickCount() + Milliseconde
 
    Do While GetTickCount() < Arret
 
        DoEvents
 
    Loop
 
End Sub
 
Public Sub Chrono()
 
    Do
 
        If ArretDefil = True Then Exit Do
            'régler ici la vitesse en modifiant
            'la valeur (en millisecondes)
        Minuterie 200
        Message "Droite"
 
    Loop
 
End Sub
 
Sub Message(Sens As String)
 
    Dim Chaine1 As String
    Dim Chaine2 As String
 
            'Faire défiler un Label dans un Frame
            'ou une Form vers la droite ou vers la gauche
    'With Label1
    '    If Sens = "Droite" Then
    '        .Left = .Left + 4 'régler ici la vitesse
    '        If .Left > Me.Width Then
    '        'dans la Form
    '            .Left = 0 - .Width
    '        'dans un Frame
    '        '   .Left = 0 - Frame1.Width
    '        End If
    '    ElseIf Sens = "Gauche" Then
    '        .Left = .Left - 4 'régler ici la vitesse
    '        If .Left + .Width < 0 Then
    '        'dans la Form
    '            .Left = Me.Width
    '        'dans un Frame
    '        '   .Left = Frame1.Width
    '        End If
    '    End If
    'End With
 
    'Faire défiler un texte dans un Label
    'vers la droite ou vers la gauche
    With Label1
 
        If Sens = "Droite" Then
 
            Chaine2 = Left(.Caption, 1)
            Chaine1 = Right(.Caption, Len(.Caption) - 1) & Chaine2
            .Caption = Chaine1
 
        ElseIf Sens = "Gauche" Then
 
            Chaine2 = Right(.Caption, 1)
            Chaine1 = Chaine2 & Left(.Caption, Len(.Caption) - 1)
            .Caption = Chaine1
 
        End If
 
    End With
 
End Sub
 
Private Sub UserForm_Activate()
 
    Chrono
 
End Sub
 
Private Sub UserForm_Click()
 
    ArretDefil = Not ArretDefil
    'des clics successifs sur la Form arrêtent
    'ou démarrent le défilement en
    'fonction de la valeur d'ArretDefil
    Chrono
 
End Sub
 
Private Sub UserForm_Initialize()
 
    Texte = "Voici un message " & _
        "défilant pour animer et " & _
        "attirer l'attention !" & Space(5)
 
    With Label1
 
        .Caption = Texte
        .Font.Bold = True
 
    End With
 
End Sub
 
 
Private Sub UserForm_QueryClose(Cancel As Integer, _
                                CloseMode As Integer)
 
    ArretDefil = True
 
End Sub

Hervé.

Merci Theze,
j'ai testé et ca marche mais comment faire pour rendre plus fluide?

Re,

Tu peux jouer sur la vitesse de défilement mais tu n'aura pas une fluidité excellente. Les Labels et autres contrôles n'ont pas été conçus pour ça alors, dès que tu bidouille ça ne peut être parfait :o(. Tu pourrai peut être créer une animation avec un logiciel dédié et la jouer avec un WebBrowser ?

Hervé.

oui je pense
merci beaucoup