arraylist vba, boucles imbriquées

Version imprimable

Bonjour,

Dans une feuille contenant 4000 lignes, je chercher à réaliser une macro, qui va sortir une arraylist contenant les 10 valeurs les plus élevées de la colonne A.

Le problème est que les champs de la colonne A sont des dates, j'ai donc une incompatibilité de type avec ce code :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 Sub entrainement () Dim tabdates_compta_max(10) As Date Dim cpt1 As Integer Dim i As Integer Dim j As Integer tabdates_compta_max(0) = Range("A" & 1).Value For cpt1 = 0 To Range("A:A").End(xlDown).Row Step 1 For i = 9 To 0 Step -1 If Range("A" & cpt1).Value > tabdates_compta_max(i) Then For j = i To 10 Step 1 tabdates_compta_max(j + 1) = tabdates_compta_max(j) Next j End If Next i Next cpt1 End Sub
Merci de m'éclairer SVP! =)

Bonjour,

Je peux te proposer autre chose si ça t'intéresse ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Sub entrainement()
 
    Dim Plage As Range
    Dim tabdates_compta_max(1 To 10) As Date
    Dim I As Integer
 
    'défini la plage de recherche en colonne A
    Set Plage = Range([A1], [A65536].End(xlUp))
 
    'boucle pour récupérer les 10 plus grandes dates
    '(en ordre croissant, de la plus récente à la plus ancienne)
    With Application.WorksheetFunction
 
        For I = 1 To UBound(tabdates_compta_max)
 
            tabdates_compta_max(I) = .Large(Plage, I)
 
        Next I
 
    End With
 
    'pour l'exemple, affiche le résultat dans la fenêtre de débogage
    'c'est ici que tu vas utiliser tes 10 dates...
    For I = 1 To UBound(tabdates_compta_max)
 
        Debug.Print tabdates_compta_max(I)
 
    Next I
 
End Sub

Hervé.

Bonjour

Code:

1
2
3
4
5
6
7
8
9
10
11
Sub les_10_recents()
Dim fin As Integer, cptr As Byte
Dim Tablo(1 To 10)
 
fin = Columns("A").Find("*", Range("A1"), , , , xlPrevious).Row
For cptr = 1 To 10
     Tablo(cptr) = Application.Large(Range("A1:A" & fin), cptr)
Next
'pour vérifier
     Range("C1:C10") = Application.Transpose(Tablo)
End Sub

Bonjour et merci pour vos réponses.

J'ai de mon côté réalisé ce code, mais je le trouve bien compliqué par rapport aux vôtres.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub entrainement()
 
Dim tabdates_compta_max(10) As Date
Dim cpt1 As Integer
Dim I As Integer
Dim j As Integer
Dim enfin As Boolean
 
enfin = True
tabdates_compta_max(0) = Range("A" & 2).Value
 
For cpt1 = 2 To Range("A:A").End(xlDown).Row Step 1
    For I = 0 To 9 Step 1
        If enfin = True Then
            If Range("A" & cpt1).Value > tabdates_compta_max(I) Then
 
                enfin = False
                For j = 9 To j = I + 1 Step -1
                tabdates_compta_max(j + 1) = tabdates_compta_max(j)
                Next j
                tabdates_compta_max(I) = Range("A" & cpt1).Value
                End If
            End If
        Next I
    enfin = True
Next cpt1
 
Msgbox "voici les 5 plus grosses dates " & tabdates_compta_max(0) & tabdates_compta_max(1) & tabdates_compta_max(2) & tabdates_compta_max(3) & tabdates_compta_max(4) & tabdates_compta_max(5), vbOKOnly, "Mdr"
 
End Sub

Puis-je continuer sur cette lancée ou vous me conseillez d’utiliser le votre?
Car maintenant, je vais pour chacune des 10 dates les plus élevées renvoyer la valeur en colonne C & i également par exemple.

(En effet vous utilisez des méthodes/fonctions que je ne connais absolument pas)

12/07/2011, 08h46
Michel_M

Bonjour,

Citation:

J'ai de mon côté réalisé ce code, mais je le trouve bien compliqué par rapport aux vôtres.
....
Puis-je continuer sur cette lancée ou vous me conseillez d’utiliser le votre?

c'est ton projet, pas le notre !!!:calim2:

Citation:

En effet vous utilisez des méthodes/fonctions que je ne connais absolument pas

eh bien, c'est l'occasion d'en faire la connaissance pour progresser

http://excel.developpez.com/cours/ :ccool:
12/07/2011, 10h17
julio44

vous avez raison, je vais me perfectionner en suivant votre voie ! =)

Juste une petite précision svp.

J'ai créé un tableau de la meme facon que vous l'avez fait précedemment, qui contient des integer.

Je voudrais stocker dans ce tableau le numéro de la ligne correspondante à la valeur trouvée dans tab_dates_compta_max(I), le but étant de ressortir la ligne complète ultérieurement.

J'ai essayé d'utiliser la fonction .index, mais sans succès. Pourriez-vous m'éclairer ?

Merci

Bonjour,

Avec un tableau à deux dimensions, dans la première les dates et dans la seconde le numéro de la ligne correspondante :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Sub entrainement()
 
    Dim Plage As Range
    Dim tabdates_compta_max(1 To 10, 1 To 2)
    Dim I As Integer
 
    'défini la plage de recherche en colonne A
    Set Plage = Range([A1], [A65536].End(xlUp))
 
    'boucle pour récupérer les 10 plus grandes dates
    '(en ordre croissant, de la plus récente à la plus ancienne)
    'avec le numéro de ligne où se trouve la date correspondante
    With Application.WorksheetFunction
 
        For I = 1 To UBound(tabdates_compta_max)
 
            tabdates_compta_max(I, 1) = CDate(.Large(Plage, I))
            tabdates_compta_max(I, 2) = Plage.Find(tabdates_compta_max(I, 1), , _
                                                   xlValues, xlWhole).Row
 
        Next I
 
    End With
 
    'pour l'exemple, affiche le résultat dans la fenêtre de débogage
    'c'est ici que tu vas utiliser tes 10 dates...
    For I = 1 To UBound(tabdates_compta_max)
 
        Debug.Print tabdates_compta_max(I, 1) 'date
        Debug.Print tabdates_compta_max(I, 2) 'numéro de la ligne
 
    Next I
 
End Sub

Hervé.

12/07/2011, 12h57
julio44

merci beaucoup !

C'est une grande victoire pour moi ! je vois enfin l'interêt des tableaux à plusieurs dimensions ! :mouarf::mouarf:

Le code fonctionne cependant il me retourne toujours non seulement la même valeur mais également le même numéro de ligne !

je ne comprends vraiment pas :

Pour I = 1 :

Il renvoie la plus forte valeur

Pour I = 2 :

Il renvoie la 2 ème plus forte valeur (qui ne peut donc être la première)

Où est la faille ??

Edit : je pense que c'est lié aux valeurs égales, il se perd au niveau de l'indice.
Je n'arrive pas à y remédier, je vous tiens au courant.

Bonjour,

Citation:

je ne comprends vraiment pas :

Pour I = 1 :

Il renvoie la plus forte valeur

Pour I = 2 :

Il renvoie la 2 ème plus forte valeur (qui ne peut donc être la première)

Où est la faille ??

La boucle commence à 1 et la fonction Large renvoi la plus grande valeur pour l'indice 1 et la deuxième plus grande pour l'indice 2 et ainsi de suite, je ne vois pas où est le problème ?

Citation:

Le code fonctionne cependant il me retourne toujours non seulement la même valeur mais également le même numéro de ligne !

Bizarre, parce que avec les tests que j'ai effectués, les résultats ont toujours été corrects ?

Dans la seconde dimensions, ce sont les numéros de ligne qui sont stockés seulement, avec deux ou plusieurs dates identiques, c'est la première trouvée qui est prise en compte. Pour récupérer les autres, il faut faire un Do Loop sur Find. Regarde si le résultat te convient en testant ce qui suit :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
 
Sub entrainement()
 
    Dim Plage As Range
    Dim tabdates_compta_max(1 To 10, 1 To 2)
    Dim Cel As Range
    Dim Adr As String
    Dim I As Integer
    Dim J As Integer
 
    'défini la plage de recherche en colonne A
    Set Plage = Range([A1], [A65536].End(xlUp))
 
    'boucle pour récupérer les 10 plus grandes dates
    '(en ordre croissant, de la plus récente à la plus ancienne)
    'avec le numéro de ligne où se trouve la date correspondante
    With Application.WorksheetFunction
 
        'défini J à 1 pour correspondre à I en début de boucle
        J = 1
 
        For I = 1 To UBound(tabdates_compta_max)
 
            tabdates_compta_max(I, 1) = CDate(.Large(Plage, J))
'            tabdates_compta_max(I, 2) = Plage.Find(tabdates_compta_max(I, 1), , _
'                                                   xlValues, xlWhole).Row
            Set Cel = Plage.Find(tabdates_compta_max(I, 1), , _
                                 xlValues, xlWhole)
 
            If Not Cel Is Nothing Then
 
                'mémorise l'adresse de la cellule pour ne pas y revenir dessus (fin de boucle Do Loop)
                Adr = Cel.Address
 
                Do
 
                    'récupère les différents numéros de ligne dans la même dimension
                    tabdates_compta_max(I, 2) = tabdates_compta_max(I, 2) & "," & Cel.Row
 
                    'incrémente J afin de récupérer un seule fois les dates en doublon
                    'tout en récupérant les différents numéros de ligne
                    'J est incrémenté pour récupérer l'indice correspondant pour la fonction Large
                    J = J + 1
 
                    'cherche la suivante
                    Set Cel = Plage.FindNext(Cel)
 
                Loop While Adr <> Cel.Address
 
                'supprime la première virgule inutile
                tabdates_compta_max(I, 2) = Replace(tabdates_compta_max(I, 2), ",", "", 1, 1)
 
            End If
 
        Next I
 
    End With
 
    'pour l'exemple, affiche le résultat dans la fenêtre de débogage
    'c'est ici que tu vas utiliser tes 10 dates...
    For I = 1 To UBound(tabdates_compta_max)
 
        Debug.Print tabdates_compta_max(I, 1) 'date
        Debug.Print tabdates_compta_max(I, 2) 'numéro de la ligne
 
    Next I
 
End Sub

La sub ci-dessus ne te retourne aucune date en doublon (incrémentation de l'indice pour la fonction Large) mais stocke malgré tout dans la même dimension que la date en doublon les numéros de ligne où se trouvent ces doublons.
Ensuite, si tu veux faire un traitement sur ces lignes il te faut extraire chaque numéro, ce qui est très facile.

Hervé.

19/07/2011, 09h41
julio44

Bonjour Hervé et merci de ta réponse.

En fait mon code fonctionne lorsque les dates sont différentes.

Par contre, lorsque plusieurs dates sont les mêmes(date large1 (individu ligne 31) = date large 2 (individu ligne 59))
Il me renvoie le même numéro de ligne pour les deux dates, alors qu'elles correspondent à deux lignes différentes !

Est-ce que je suis clair ?

Tu as peut être déjà répondu à ma question et dans ce cas c'est moi qui n'ai pas compris.

Peux-tu m'éclairer ?

Encore merci,

Julien

Je voudrais donc la chose suivante :

Si Large(1) = Large (2), ceci signifie que deux lignes ont la même date.

Il me faudrait donc :

pour .Large(Plage, 1) l'indice de la première ligne.
pour .Large(Plage, 2) l'indice de la deuxième ligne.

Sachant que les dates seraient les mêmes pour les deux lignes.

Je n'arrive absolument pas à réaliser ceci, si quelqu'un avait une idée SVP.
20/07/2011, 09h49
julio44

Bonjour, je ferme mon topic afin de mieux reformuler ma demande.

Lien ici :

http://www.developpez.net/forums/d11...e/#post6131682