code formulaire redondant

Version imprimable

bonjour a tous
j'utilise le code ci-dessous pour mettre des information dans des textbox à chaque fois que la combobox change

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Private Sub cmb_ref1_Change()
On Error Resume Next
Dim libelle As String
Dim reference As String
Dim prix As Single
Dim poids, prixcarton, prixdétail, prixcartonpromo, prixdétailpromo As Double
Sheets("source").Select
reference = Me.cmb_ref1.Text
Cells.Find(What:=reference, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext).Activate
'faire apparaitre le libéllé
libelle = ActiveCell.Offset(0, 3).Text
Me.txt_lib1.Text = libelle
'faire apparaitre le poids
poids = ActiveCell.Offset(0, 4).Value
Me.txt_poids1.Value = poids
'faire apparaitre le poids
poids = ActiveCell.Offset(0, 4).Value
Me.txt_poids1.Value = poids
'faire apparaitre le prix au carton
prixcarton = ActiveCell.Offset(0, 8).Value
txt_prix_carton1.Value = prixcarton
 
'faire apparaitre le prix au détail
prixdétail = ActiveCell.Offset(0, 9).Value
txt_prix_detail1.Value = prixdétail
 
'faire apparaitre le prix au carton promo
prixcartonpromo = ActiveCell.Offset(0, 13).Value
txt_prixpromo_carton1.Value = prixcartonpromo
 
'faire apparaitre le prix au détail promo
prixdétailpromo = ActiveCell.Offset(0, 14).Value
txt_prixpromo_detail1.Value = prixdétailpromo
End Sub

j'ai donc 10 combobox et je répète ce code 10 fois

existe-t-il un moyen d’alléger ce système

bonjour bosk1000, le forum,

plusieurs solutions :

1) mettre le code affiché ci-dessus dans une fonction

2) une solution est de placer dans le TAG du COMBOBOX le nom de la TEXTBOX correspondante. Dans chaque évènement change, on passe la valeur de la propriété TAG à la fonction. On ne change rien dans la "USERFORM" et on utilise le paramètre de la fonction.

une autre solution est de renommer chaque combobox avec un numéro et chaque textbox avec le même numéro (pas trop dur avec 20 objets, et ça correspond au code ci-dessus). On va chercher le nombre final dans le nom de la COMBOBOX que l'on réutilise pour la TEXTBOX. Un code simpliste pour comprendre :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Sub Cbo01_Change() TraiteChoix End Sub Sub Cbo02_Change() TraiteChoix End Sub Function TraiteChoix NbFinal = Right(ActiveControl.name,2) Controls("TxtBox" & NbFinal).value = Rnd End Function
une dernière solution est de faire une classe...

ESVBA

merci pour ton aide
je vais opter pour la fonction

car je n'ai pas compris le fonctionnement du module de classe
a moins que quelqu'un veuille bien me guider

je confirme après si j'ai réussi la fonction

voici ce que j'ai mis

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
Private Sub cmb_ref1_Change()
TraiteChoix
End Sub
 
Function TraiteChoix()
Dim nbfinal As Variant
Dim libelle As String
Dim reference As String
Dim prix As Single
Dim poids, prixcarton, prixdétail, prixcartonpromo, prixdétailpromo As Double
 
   nbfinal = Right(ActiveControl.Name, 2)
 
 
On Error Resume Next
Sheets("source").Select
reference = Controls("cmb_ref" & nbfinal).Text
Cells.Find(What:=reference, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext).Activate
'faire apparaitre le libéllé
libelle = ActiveCell.Offset(0, 3).Text
Controls("txt_lib" & nbfinal).Text = libelle
'faire apparaitre le poids
poids = ActiveCell.Offset(0, 4).Value
Controls("txt_poids" & nbfinal).Value = poids
'faire apparaitre le poids
poids = ActiveCell.Offset(0, 4).Value
Controls("txt_poids" & nbfinal).Value = poids
'faire apparaitre le prix au carton
prixcarton = ActiveCell.Offset(0, 8).Value
Controls("txt_prix_carton" & nbfinal).Value = prixcarton
'faire apparaitre le prix au détail
prixdétail = ActiveCell.Offset(0, 9).Value
Controls("txt_prix_detailé" & nbfinal).Value = prixdétail
'faire apparaitre le prix au carton promo
prixcartonpromo = ActiveCell.Offset(0, 13).Value
Controls("txt_prixpromo_carton" & nbfinal).Value = prixcartonpromo
'faire apparaitre le prix au détail promo
prixdétailpromo = ActiveCell.Offset(0, 14).Value
Controls("txt_prixpromo_detail" & nbfinal).Value = prixdétailpromo
 
End Function

mais je n’obtiens rien
ou est mon erreur ?

07/07/2011, 22h01
ESVBA

les noms des contrôles textbox et combobox se terminent biens par "01" "02" "03"...
avec mon exemple, on avait "x1", "x2"... que ce soit des combo ou des txbox.

Précise l'objet "conteneur" avec les "activecell", "Controls(...)", ... :
- "UserForm."
- "Me."
- "Sheets("Source").
- ...

ça évite les méprises de VBA et de nous.

ESVBA
07/07/2011, 22h23
bosk1000
merci
effectivement il fallait nommer 01, 02
et pas 1, 2

par contre ma boucle
Code:

1 2 3 4 5 6 Private Sub UserForm_Initialize() Dim i As Byte For i = 1 To 10 Me.Controls("cmb_ref" & i).RowSource = "source!a2:a" & Sheets("source").Cells(1, 15).End(xlDown).Row Next i End Sub
ne fonctionne plus car j'ai due renommer les combobox cmb_ref en 01, 02 au lieu de 1, 2

donc j'ai mis à la place

Code:

cmb_ref01.RowSource = "source!a2:a" & Sheets("source").Cells(1, 15).End(xlDown).Row

etc... jusqu'a cmb_ref10
s'il y a un moyen de quand même faire la boucle avec les 01, 02 ?

par contre je ne comprend pas ce que tu veux dire :

Citation:

Précise l'objet "conteneur" avec les "activecell", "Controls(...)", ... :
- "UserForm."
- "Me."
- "Sheets("Source").
- ...
07/07/2011, 22h40
mercatog

Code:

Me.Controls("cmb_ref" & Format(i, "00"))

Pour i=3, tu auras cmb_ref03
Et pour i=14, tu auras cmb_ref14
07/07/2011, 22h45
ESVBA

Me.Controls("cmb_ref" & i).RowSource

c'est une concaténation (vba) donc en formatant la chaine pour avoir deux caractères :

Code:

Me.Controls("cmb_ref" & Format( i, "00")).RowSource

ESVBA

si je comprend bien
le code devrait etre :
Code:

1 2 3 4 5 6 7 Private Sub UserForm_Initialize() Dim i As Byte For i = 1 To 10 Me.Controls("cmb_ref" & Format(i, "00")).RowSource = "source!a2:a" & Sheets("source").Cells(1, 15).End(xlDown).Row Next i End Sub
mais j’obtiens un message d'erreur
erreur d’exécution '-2147024809 (80070057)
objet spécifié introuvable

07/07/2011, 22h54
ESVBA

Pour le conteneur

Dans ton code ajoute l'objet "parent", l'objet qui contient l'objet utilisé.

Une cellule peut faire partie d'une plage (Range), d'une feuille (WorkSheet ou Sheet), d'un classeur.
Une combobox est contenue dans l'objet UserForm (dénommé plus rapidement "Me").

Quant on gère plusieurs choses en même temps, l'exécution des tâches et des évènements peuvent ne pas coïncider.

Cet allongement du code permet de garantir de quelle cellule (sur quelle feuille ou quel classeur) ou de quel contrôle ActiveX on utilise sur quel formulaire (userform).

ESVBA
07/07/2011, 22h59
bosk1000

merci pour cette éclairage
07/07/2011, 23h05
ESVBA

Si je me souviens bien c'est une limitation de "RowSource".
J'ai cherché pendant des heures.

Citation:

"RowSource" doit absolument être une contante à l'affectation de la plage de valeurs à la propriété.

Enfin, si quelqu'un peut me prouver le contraire, je serais vivement intéressé.

Donc il faut passer par ".List()".

ESVBA
07/07/2011, 23h11
bosk1000

merci pour ton aide

Récapitulatif
Avec tous les codes dans le module de ton userform (suite à la proposition de ESVBA de renommer les combobox et les textbox)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Option Explicit
 
Private Sub UserForm_Initialize()
Dim LastLig As Long
Dim i As Byte
 
With Worksheets("Source")
    LastLig = .Cells(.Rows.Count, 15).End(xlUp).Row
    For i = 1 To 20                                                                                '20 nombre de tes commbo cmb_ref01...cmb_ref20
        Me.Controls("cmb_ref" & Format(i, "00")).RowSource = .Name & "!" & .Range("A2:A" & LastLig).Address
    Next i
End With
End Sub
 
Private Sub Rech(ByVal Ref As String)
Dim c As Range
Dim Indx As String
 
If Ref <> "" Then
    Indx = Format(Right(Me.activecontrol.Name, 2), "00")
    With Sheets("source")
        Set c = .UsedRange.Find(Ref, LookIn:=xlFormulas, LookAt:=xlPart)                           'ici au lieu de usedrange, mets ta colonne de recherche des references
        If Not c Is Nothing Then 'ce test sur c dans ton cas est inutile, mais bon, c'est pour la démonstration
            'faire apparaitre le libelle
            Me.Controls("txt_lib" & Indx) = c.Offset(0, 3)                                         'txt_lib01, txt_lib02...txt_lib20
            'faire apparaitre le poids
            Me.Controls("txt_poids" & Indx) = c.Offset(0, 4)                                       'txt_poids01, txt_poids02...txt_poids20
            'faire apparaitre le prix au carton
            Me.Controls("txt_prix_carton" & Indx) = c.Offset(0, 8)
            'faire apparaitre le prix au detail
            Me.Controls("txt_prix_detail" & Indx) = c.Offset(0, 9)
            'faire apparaitre le prix au carton promo
            Me.Controls("txt_prixpromo_carton" & Indx) = c.Offset(0, 13)
            'faire apparaitre le prix au detail promo
            Me.Controls("txt_prixpromo_detail" & Indx) = c.Offset(0, 14)
            Set c = Nothing
        End If
    End With
End If
End Sub
 
Private Sub cmb_ref01_Change()
 
Rech cmb_ref01
End Sub
Private Sub cmb_ref02_Change()
 
Rech cmb_ref02
End Sub
 
'...etc

20 étant le nombre de combobox et les textbox qui leur sont liés

PS (n'y a t il pas une petit souci de conception? )

07/07/2011, 23h47
ESVBA

:oops:j'ai dit n'importe quoi.

Oui, ".address" je me souviens tardivement.
Pourtant l'aide signale qu'il faut un type "string" (comme ".address").
Alors pourquoi pourquoi ça ne fonctionne pas avec la méthode de Bosk1000 ?

ESVBA
07/07/2011, 23h59
mercatog

Citation:

erreur d’exécution '-2147024809 (80070057)
objet spécifié introuvable

Il a oublié de renommer convenablement l'un des contrôles et dans sa boucle, au moins un contrôle n'est pas trouvé.
08/07/2011, 00h06
bosk1000

merci mercatog

ta méthode avec address résout le problème

tout roule

a moi de biens comprendre le code