Condition if en vba

Version imprimable

05/07/2011, 23h55
aminee1666

Condition if en vba
bonjour,

j'ai une colonne sur mon fichier qui contient plusieurs donnée:
ex: colonne1: uib/erc/a/b
colonne2: iu/erc/t/

je veux faire une condtion if sur cette colonne pour recupérer juste les ligne qui contient "erc".

voici mon code:
Code:

1 2 3 4 5 6 7 8 9 fin = Feuil3.Range("A" & Rows.Count).End(xlUp).Row aa = Feuil3.Range("A2:B" & fin) For i = 1 To UBound(aa) If aa(i, 4) = "*erc*" Then end if
Merci d'avance

Bonjour aminee1666,

Voici un code qui te permettra d’effectuer la recherche de la chaine de caractères « erc » dans la plage comprenant les colonnes A et B.
A adapter si besoin.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Test()
Dim DerLig As Long
Dim MaPlage As Range
 
With Worksheets("Feuil3")
    DerLig = .Range("A" & .Rows.Count).End(xlUp).Row
    Set MaPlage = .Range("A1:B" & DerLig)
    Set c = MaPlage.Find("*erc*", LookIn:=xlValues)
    If Not c Is Nothing Then
        firstAddress = c.Address
        Do
            MsgBox "La chaine de caractère" & """erc""" & "a été trouvée en ligne " & c.Row & " ; colonne " & c.Column
            Set c = MaPlage.FindNext(c)
        Loop While Not c Is Nothing And c.Address <> firstAddress
    End If
    Set c = Nothing
End With
End Sub

Cordialement.

06/07/2011, 09h54
Maxim0

bonjour,
je voulais savoir, si possible de faire une petite modificaion sur l'instruction if,
pour me filtrer juste les lignes ou il y a "erc"

Code:

If aa(i, 4) = "*erc*" Then

Merci d'avance

Re-bonjour aminee1666,

Autre solution en conservant le test sur aa

Code:

1
2
3
4
5
6
7
fin = Sheets("Feuil3").Range("A" & Rows.Count).End(xlUp).Row
aa = Sheets("Feuil3").Range("A2:B" & fin)
 
For i = 1 To UBound(aa)
    If InStr(1, aa(i, 1), "erc", vbTextCompare) <> 0 Then MsgBox "Trouvé à la ligne " & i & "; colonne 1"
    If InStr(1, aa(i, 2), "erc", vbTextCompare) <> 0 Then MsgBox "Trouvé à la ligne " & i & "; colonne 2"
Next

Cordialement

07/07/2011, 09h57
Qwazerty

Salut

Citation:

Envoyé par Maxim0

bonjour,
je voulais savoir, si possible de faire une petite modificaion sur l'instruction if,
pour me filtrer juste les lignes ou il y a "erc"

If aa(i, 4) = "*erc*" Then

Merci d'avance

Regarde du coté de Like (un petit coup de F1).

Code:

If aa(i, 4) Like "*erc*" Then

++
Qwaz