UserForm extraction et Filtre ComboBox

Version imprimable

Bonjour,

Je me permets de poster ma question ici après de longues heures de balades infructueuses sur des forums pour y trouver une réponse. Je ne sais pas si la question a déjà été posée mais dans le doute...

Mon problème porte en fait sur le code permettant d'extraire des informations via un combobox situé dans un userform. Le userform doit pouvoir combiner plusieurs filtres (date, valeur et nature de l'opération via un combobox pour cette dernire).

Mais plus qu'un long discours:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Private Sub CommandButton1_Click() Sheets("Total").Select Sheets("Total").Copy Before:=Sheets(1) Sheets("Total (2)").Activate Sheets("Total (2)").Name = InputBox("Nom de l'onglet?", "Onglet") Dim i As Long For i = 1000 To 3 Step -1 If Cells(i, 2).Value < CDate(TextDate1) Or Cells(i, 2).Value > CDate(TextDate2) Then Rows(i).Delete If Cells(i, 10).Value < CLng(TextMin) Or Cells(i, 10).Value > CLng(TextMax) Then Rows(i).Delete 'Et c'est là que je bloque complétement..... End Sub
Sachant que ma combobox a été appelée ComboBoxSecteur et a été alimentée via un:

Code:

ComboBoxSecteur.AddItem ("XXXX")

etc... Sachant qu'il y a effectivement plus simple pour cela.

Dans tous les cas, je vous remercie pour votre réponse.

Loïc

15/06/2011, 10h35
Many31

Bonjour,

Tout d'abord, il serait agréable de poser une vraie question avec un "?" claire et précise parce que là ca ressemble plus à du "vous pouvez continuer" sans réel contenu...

Bref je comprend pas où vous voulez en venir.

Deuxième remarque le For i = X to XX OK ca peut le faire (je préfère perso le While mais bon...) le soucis dans ce que vous écrivez c'est que lorsqu'une ligne est supprimée (exemple ligne "n") la suivante n'est pas "n+1" mais à nouveau "n"

Ce qui fait qu'en cas de suppression de ligne il faut ramener i à "i+1" pour que la boucle for revienne sur la valeur "n"

Pour consulter la valeur prise par une combobox rien de plus simple.... if cells(ligne,colonne) = combobox1 par exemple et si vous voulez être rigoureux, cells(ligne,colonne) = combobox1.value

Mais vu que vous ne posez pas de question clair je ne sais même pas si ca répond à vos intérrogations.
15/06/2011, 10h44
lchauvet1

Bonjour Many,

Je vous remercie pour votre réponse/commentaires!

En fait ma question portait réellement sur le filtre via un combobox: comment faire?

Mais je crois que vous m'avez bien indiqué la voie:

Citation:

Pour consulter la valeur prise par une combobox rien de plus simple.... if cells(ligne,colonne) = combobox1 par exemple et si vous voulez être rigoureux, cells(ligne,colonne) = combobox1.value

Je vais tester ça et revient vous dire ce qu'il en est.

Loïc
15/06/2011, 10h48
mercatog

Pourquoi ne pas utiliser un filtre automatique? (sans boucle sur les lignes et sans suppression de lignes)
15/06/2011, 11h02
lchauvet1

:? ....

Parce que je suis débutant et que je suis parti d'une base que j'avais sous la main sans forcément saisir toutes les possibilités offertes...

Je suis maintenant entrain de tester la même chose sur un filtre utilisant plusieurs combobox.

Loïc

EDIT: Correction

Un exemple (à adapter suivant les commentaires)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim LastLig As Long
Dim DteDeb As Date, DteFin As Date
Dim ValMin As Double, ValMAx As Double
Dim Sect As String
 
Application.ScreenUpdating = False
DteDeb = CDate(Me.TextDate1.Value)
DteFin = CDate(Me.TextDate2.Value)
ValMin = Val(Me.TextMin.Value)
ValMAx = Val(Me.TextMax.Value)
Sect = Me.ComboBoxSecteur.Value
 
Set Sh = Worksheets.Add(Before:=Sheets("Total"))
With Sheets("Total")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    With .Range("A1:Z" & LastLig)
        .AutoFilter Field:=2, Criteria1:="<=" & CLng(DteFin), Criteria2:=">=" & CLng(DteDeb), Operator:=xlAnd       'Filtre colonne 2 entre les 2 dates
        .AutoFilter Field:=10, Criteria1:="<=" & ValMAx, Criteria2:=">=" & ValMin, Operator:=xlAnd          'Filtre colonne 10 entre les 2 valeurs min et max
        .AutoFilter Field:=3, Criteria1:=Sect                                                                           'Filtre la colonne 3 sur la valeur de ComboBoxSecteur
        .SpecialCells(xlCellTypeVisible).Copy Sh.Range("A1")
    End With
    .AutoFilterMode = False
End With
Set Sh = Nothing
End Sub

Many, la commande est impeccable!

Mais mon soucis c'est que mon formulaire contient plusieurs combobox que l'utilisateur n'est pas obligé de renseigner. Lorsque j'applique le code suivant
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Dim t As Boolean t = False If Cells(i, 13) = ComboBox1.Value = True Then ElseIf ComboBox1.Value = ("") Then t = True End If If Cells(i, 5) = ComboBox2.Value = True Then ElseIf ComboBox2.Value = ("") Then t = True End If If Cells(i, 8) = ComboBox3.Value = True Then ElseIf 3.Value = ("") Then t = True End If If t Then Rows(i).Delete: t = False
Le filtre considère les emplacements vides comme étant à supprimer... Avez-vous une idée de la façon dont je peux contourner la chose? S'il vous plait.

Edit: je vais jeter un gros oeil sur le code, merci mercatog

Loïc

Pour ne pas tenir compte de la combobox si aucun élément n'a été sélectionné

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim LastLig As Long
Dim DteDeb As Date, DteFin As Date
Dim ValMin As Double, ValMAx As Double
Dim Sect As String
 
Application.ScreenUpdating = False
DteDeb = CDate(Me.TextDate1.Value)
DteFin = CDate(Me.TextDate2.Value)
ValMin = Val(Me.TextMin.Value)
ValMAx = Val(Me.TextMax.Value)
Sect = Me.ComboBoxSecteur.Value
 
Set Sh = Worksheets.Add(Before:=Sheets("Total"))
With Sheets("Total")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    With .Range("A1:Z" & LastLig)
        .AutoFilter Field:=2, Criteria1:="<=" & CLng(DteFin), Criteria2:=">=" & CLng(DteDeb), Operator:=xlAnd       'Filtre colonne 2 entre les 2 dates
        .AutoFilter Field:=10, Criteria1:="<=" & ValMAx, Criteria2:=">=" & ValMin, Operator:=xlAnd          'Filtre colonne 10 entre les 2 valeurs min et max
        If Sect <> "" Then .AutoFilter Field:=3, Criteria1:=Sect                                                                         'Filtre la colonne 3 sur la valeur de ComboBoxSecteur
        .SpecialCells(xlCellTypeVisible).Copy Sh.Range("A1")
    End With
    .AutoFilterMode = False
End With
Set Sh = Nothing
End Sub

Voilà ce que j'ai fait (ajout de autres combobox):

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim LastLig As Long
Dim DteDeb As Date, DteFin As Date
Dim ValMin As Double, ValMAx As Double
Dim Sect As String
 
Application.ScreenUpdating = False
DteDeb = CDate(Me.TextDate1.Value)
DteFin = CDate(Me.TextDate2.Value)
ValMin = Val(Me.TextMin.Value)
ValMAx = Val(Me.TextMax.Value)
Sect1 = Me.ComboBox1.Value
Sect2 = Me.ComboBox2.Value
Sect3 = Me.ComboBox3.Value
 
Set Sh = Worksheets.Add(Before:=Sheets("Total"))
With Sheets("Total")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    With .Range("A2:M101" & LastLig)
        .AutoFilter Field:=2, Criteria1:="<=" & CLng(DteFin), Criteria2:=">=" & CLng(DteDeb), Operator:=xlAnd       'Filtre colonne 2 entre les 2 dates
        .AutoFilter Field:=10, Criteria1:="<=" & ValMAx, Criteria2:=">=" & ValMin, Operator:=xlAnd          'Filtre colonne 10 entre les 2 valeurs min et max
         If Sect1 <> "" Then .AutoFilter Field:=13, Criteria1:=Sect1                                                                         'Filtre la colonne 3 sur la valeur de ComboBoxSecteur
         If Sect2 <> "" Then .AutoFilter Field:=5, Criteria1:=Sect2                                                                         'Filtre la colonne 3 sur la valeur de ComboBoxSecteur
         If Sect3 <> "" Then .AutoFilter Field:=8, Criteria1:=Sect3                                                                         'Filtre la colonne 3 sur la valeur de ComboBoxSecteur
         .SpecialCells(xlCellTypeVisible).Copy Sh.Range("A1")
 
           End With
    .AutoFilterMode = False
End With
Set Sh = Nothing
 
Unload Me
 
End Sub

Mon problème tient maintenant plus sur la forme du nouvel onglet créé. Est-il possible de garder la forme source?

Dans tous les cas, merci beaucoup!

Loïc

Déja pour le code, il ne faut copier qu'à la fin de tous les filtres

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim LastLig As Long
Dim DteDeb As Date, DteFin As Date
Dim ValMin As Double, ValMAx As Double
Dim Sect1 As String, Sect2 As String, Sect3 As String
 
Application.ScreenUpdating = False
DteDeb = CDate(Me.TextDate1.Value)
DteFin = CDate(Me.TextDate2.Value)
ValMin = Val(Me.TextMin.Value)
ValMAx = Val(Me.TextMax.Value)
Sect1 = Me.ComboBox1.Value
Sect2 = Me.ComboBox2.Value
Sect3 = Me.ComboBox3.Value
Set Sh = Worksheets.Add(Before:=Sheets("Total"))
With Sheets("Total")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    With .Range("A2:M101" & LastLig)
        .AutoFilter Field:=2, Criteria1:="<=" & CLng(DteFin), Criteria2:=">=" & CLng(DteDeb), Operator:=xlAnd    'Filtre colonne 2 entre les 2 dates
        .AutoFilter Field:=10, Criteria1:="<=" & ValMAx, Criteria2:=">=" & ValMin, Operator:=xlAnd    'Filtre colonne 10 entre les 2 valeurs min et max
        If Sect1 <> "" Then .AutoFilter Field:=13, Criteria1:=Sect1  'Filtre la colonne 13 sur la valeur de ComboBox1
        If Sect2 <> "" Then .AutoFilter Field:=5, Criteria1:=Sect2   'Filtre la colonne 5 sur la valeur de ComboBox2
        If Sect3 <> "" Then .AutoFilter Field:=8, Criteria1:=Sect3   'Filtre la colonne 8 sur la valeur de ComboBox3
        .SpecialCells(xlCellTypeVisible).Copy Sh.Range("A1")
    End With
    .AutoFilterMode = False
End With
Set Sh = Nothing
Unload Me
End Sub

Qu'entends tu par la même mise en forme?

15/06/2011, 14h11
lchauvet1

C'est du pinaillage mais la largeur des colonnes et des lignes n'est pas conservée ce qui "oblige" l'utilisateur à sélectionner l'ensemble du fichier et à appliquer un "Format painter" et c'est vrai que le principe de nommer l'onglet nouvellement créé est confortable pour l'utilisateur.

Mais à dire vrai, je pense que je pourrai m'en débrouiller en enregistrant la macro.
Dans tous les cas, je te remercie grandement, tu m'as sorti une belle épine du pied!

Loïc

Copie la feuille, l'efface et transfert les lignes résultat du filtre

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim LastLig As Long
Dim DteDeb As Date, DteFin As Date
Dim ValMin As Double, ValMAx As Double
Dim Sect1 As String, Sect2 As String, Sect3 As String
 
Application.ScreenUpdating = False
DteDeb = CDate(Me.TextDate1.Value)
DteFin = CDate(Me.TextDate2.Value)
ValMin = Val(Me.TextMin.Value)
ValMAx = Val(Me.TextMax.Value)
Sect1 = Me.ComboBox1.Value
Sect2 = Me.ComboBox2.Value
Sect3 = Me.ComboBox3.Value
 
Sheets("Total").Copy Before:=Sheets("Total")
Set Sh = ActiveSheet
Sh.UsedRange.Clear
With Sheets("Total")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    With .Range("A2:M101" & LastLig)
        .AutoFilter Field:=2, Criteria1:="<=" & CLng(DteFin), Criteria2:=">=" & CLng(DteDeb), Operator:=xlAnd    'Filtre colonne 2 entre les 2 dates
        .AutoFilter Field:=10, Criteria1:="<=" & ValMAx, Criteria2:=">=" & ValMin, Operator:=xlAnd    'Filtre colonne 10 entre les 2 valeurs min et max
        If Sect1 <> "" Then .AutoFilter Field:=13, Criteria1:=Sect1  'Filtre la colonne 13 sur la valeur de ComboBox1
        If Sect2 <> "" Then .AutoFilter Field:=5, Criteria1:=Sect2   'Filtre la colonne 5 sur la valeur de ComboBox2
        If Sect3 <> "" Then .AutoFilter Field:=8, Criteria1:=Sect3   'Filtre la colonne 8 sur la valeur de ComboBox3
        .SpecialCells(xlCellTypeVisible).Copy Sh.Range("A1")
    End With
    .AutoFilterMode = False
End With
Set Sh = Nothing
Unload Me
End Sub

15/06/2011, 14h59
lchauvet1

C'est impeccable comme ça!!!!

J'ai simplement ajouté la commande suivante pour permettre à l'utilisateur de changer le nom de l'onglet:

Code:

ActiveSheet.Name = InputBox("Nom de l'onglet?", "Onglet")

Mercatog, merci encore!!!

Loïc
15/06/2011, 15h22
mercatog

Mauvaise approche pour renommer ta feuille

L’utilisateur peut annuler l'inputbox
Il peut donner un nom de feuille déjà existant
Il peut entrer des caractères interdits

mais bon, à toi de penser comment nommer explicitement ta feuille