combobox2 filtré par combobox1

Version imprimable

Bonjour,

J'ai une base de données d'emprunt de materiel avec des noms de clés et leur numero

J'ai creer dans une autre feuille deux combobox,
- une affiche les noms de clé de ma BDD,
- l'autre affiche les numeros
Je voudrais que : lorsque je choisi un nom de clé , ma combobox numero soit triée et n'affiche que les numeros correspondant au type de clé choisi

Voici mon malheureux code VBA, s'il vous plaît aidez moi!!! :oops:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub ComboBox1_DropButtonClick()
Dim Lescles As Object, Cel As Range
Set Lescles = CreateObject("Scripting.Dictionary")
With Sheets("BD")
    For Each Cel In .Range("c3:c" & .[c65000].End(xlUp).Row)
        If Not Lescles.Exists(Cel.Value) And Cel.Value <> "" _
            Then Lescles.Add Cel.Value, Cel.Value
    Next Cel
End With
Me.ComboBox1.List = Application.Transpose(Lescles.items)
 
End Sub
 
Private Sub ComboBox2_DropButtonClick()
Dim Lesnumeros As Object, Cel As Range
Set Lesnumeros = CreateObject("Scripting.Dictionary")
With Sheets("BD")
    For Each Cel In .Range("d3:d" & .[d65000].End(xlUp).Row)
        If Not Lesnumeros.Exists(Cel.Value) And Cel.Value <> "" _
            Then Lesnumeros.Add Cel.Value, Cel.Value
    Next Cel
End With
Me.ComboBox2.List = Application.Transpose(Lesnumeros.items)
 
End Sub

03/06/2011, 13h05
mercatog

Bonjour

Une piste de la FAQ

Merci beaucoup, mais cela ne m'aide pas, je suis extrêmement novice en VBA.

Sauriez-vous comment faire pour:
que ma ComboBox2 dépende de ma ComboBox1

Actuellement la ComboBox2 m'affiche tout les résultats sans tenir compte du choix de ComboBox1 :cry:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub ComboBox1_DropButtonClick()
Dim Lescles As Object, Cel As Range
Set Lescles = CreateObject("Scripting.Dictionary")
With Sheets("BD")
    For Each Cel In .Range("c3:c" & .[c65000].End(xlUp).Row)
        If Not Lescles.Exists(Cel.Value) And Cel.Value <> "" _
            Then Lescles.Add Cel.Value, Cel.Value
    Next Cel
End With
Me.ComboBox1.List = Application.Transpose(Lescles.items)
 
End Sub
 
Private Sub ComboBox2_DropButtonClick()
Dim Lesnumeros As Object, Cel As Range
Set Lesnumeros = CreateObject("Scripting.Dictionary")
With Sheets("BD")
    For Each Cel In .Range("d3:d" & .[d65000].End(xlUp).Row)
        If Not Lesnumeros.Exists(Cel.Value) And Cel.Value <> "" _
            Then Lesnumeros.Add Cel.Value, Cel.Value
    Next Cel
End With
Me.ComboBox2.List = Application.Transpose(Lesnumeros.items)
 
End Sub

En utilisant ta méthode, essaies ceci

La ComobBox1 se rempli à l’initialisation de l'userform
La ComboBox2 se remplie au changement de la valeur de ComboBox2

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub UserForm_Initialize()
Dim LesCles As Object
Dim LastLig As Long
Dim Cel As Range
 
Set LesCles = CreateObject("Scripting.Dictionary")
With Sheets("BD")
    LastLig = .Cells(.Rows.Count, "C").End(xlUp).Row
    For Each Cel In .Range("C3:C" & LastLig)
        If Not LesCles.Exists(Cel.Value) And Cel.Value <> "" Then LesCles.Add Cel.Value, Cel.Value
    Next Cel
End With
Me.ComboBox1.List = Application.Transpose(LesCles.items)
Set LesCles = Nothing
End Sub
 
Private Sub ComboBox1_Change()
Dim LesNumeros As Object
Dim LastLig As Long
Dim Cel As Range
Dim Cle As String
 
Me.ComboBox2.Clear
If Me.ComboBox1.ListIndex > -1 Then
    Cle = Me.ComboBox1.Value
    Set LesNumeros = CreateObject("Scripting.Dictionary")
    With Sheets("BD")
        LastLig = .Cells(.Rows.Count, "C").End(xlUp).Row
        For Each Cel In .Range("D3:D" & LastLig)
            If Not LesNumeros.Exists(Cel.Value) And Cel.Value <> "" And Cel.Offset(0, -1).Value = Cle Then LesNumeros.Add Cel.Value, Cel.Value
        Next Cel
    End With
    If LesNumeros.Count > 0 Then Me.ComboBox2.List = Application.Transpose(LesNumeros.items)
    Set LesNumeros = Nothing
End If
End Sub

03/06/2011, 14h48
aurelia06

C'est parfait!!!
Merci mille fois!!!!!