Do while Loop

Version imprimable

Do while Loop

Bonjour,

Je souhaiterais à l'aide d'une macro recherche un numéro sur toutes les feuilles et dans toutes les cellules existantes.

Pour ce faire je souhaiterais utilisé un do/loop. Je me sert de ce do/loop pour trouver une feuille par rapport à son nom :
Code:

1 2 3 4 5 6 7 8 9 10 Dim ind As Integer Do While ind <= ThisWorkbook.Sheets.Count If ThisWorkbook.Sheets(ind).Name = ThisWorkbook.Sheets("Feuil1").Range("A50").Text Then Exit Do End If ind = ind + 1 Loop
Il me faudrait quelque chose de simillaire mais comme dit pour trouver dans une cellule d'une feuille autre que ma feuil1 la valeur donnée.

Bonjour

Pour ton cas, une proposition avec For Each Next (on connait la collection des feuilles de ton classeur)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Test()
Dim Sh As Worksheet
Dim c As Range
Dim Rech As String
Dim Trouve As Boolean
 
Rech = "toto"                                    'Mot à rechercher
For Each Sh In ThisWorkbook.Worksheets           'Pour chaque feuille dans ce classeur
    If Sh.Name <> "Feuil1" Then                  'Si le nom de la feuille est différent de Feuil1
        Set c = Sh.UsedRange.Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la feuille
        If Not c Is Nothing Then
            MsgBox "Occurence du mot " & Rech & " trouvée en " & Sh.Name & "!" & c.Address(0, 0)
            Set c = Nothing
            Trouve = True
        End If
    End If
Next Sh
If Not Trouve Then MsgBox "Aucune occurence du mot " & Rech
End Sub

02/06/2011, 11h36
gigalia

Merci Mercatog pour ta réponse, j'ai facilement pu l'adapté à ma macro.

Petites question : la valeur cherchée ne peut être présente qu'à un seul autre endroit que la feuil1. Il ne peut y avoir cette valeur sur plusieurs feuilles ou plusieurs cellules. Donc est ce qu'un Do/Loop ne serait pas mieux?

Pour arrêter la recherche dès que le mot cherché est trouvé, j'ai ajouté un Exit For

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Test()
Dim Sh As Worksheet
Dim c As Range
Dim Rech As String
Dim Trouve As Boolean
 
Rech = "toto"                                    'Mot à rechercher
For Each Sh In ThisWorkbook.Worksheets           'Pour chaque feuille dans ce classeur
    If Sh.Name <> "Feuil1" Then                  'Si le nom de la feuille est différent de Feuil1
        Set c = Sh.UsedRange.Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la feuille
        If Not c Is Nothing Then
            MsgBox "Occurence du mot " & Rech & " trouvée en " & Sh.Name & "!" & c.Address(0, 0)
            Set c = Nothing
            Trouve = True
            Exit For                             'Ici pour arrêter la recherche dans les autres feuilles dès qu'on trouve le mot recherché
        End If
    End If
Next Sh
If Not Trouve Then MsgBox "Aucune occurence du mot " & Rech
End Sub

02/06/2011, 13h50
gigalia

Re,

Dans ta macro le resultat de la recherche c'est "c"? Et "c" est une cellule?
02/06/2011, 14h29
mercatog

En effet, "c" est la cellule trouvé (de type Range) avec:
c.address son adresse
c.value sa valeur
c.row sa ligne
c.column sa colonne

Re,

Comment lui dire de selectionner la ligne sur laquel il se trouve?

Je me suis permis d'ajouter un application.goto C à la macro

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
 
Rech = Sheets("Tom").Range("G50").Text                                  'Mot à rechercher
For Each Sh In ThisWorkbook.Worksheets           'Pour chaque feuille dans ce classeur
    If Sh.Name <> "Tom" Then                  'Si le nom de la feuille est différent de Feuil1
        Set c = Sh.UsedRange.Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la feuille
        If Not c Is Nothing Then
            Application.Goto c
            Set c = Nothing
            Trouve = True
            Exit For
        End If
    End If
Next Sh
If Not Trouve Then

02/06/2011, 14h47
mercatog

Et pourquoi tu veux sélectionner cette ligne? Tu n'auras pas besoin de sélectionner quoi que ce soit.
Tu veux faire quoi si tu trouve la cellule "c" contenant le mot recherché?
02/06/2011, 14h53
gigalia

Re,

Si je trouve la cellule "c", je veux copier la ligne sur laquelle elle se trouve et coller cette ligne sur une autre tableau. Je n'est pas de soucis avec le copier coller mais avec la selection de la ligne.

Par exemple si tu veux copier toute la ligne de la cellule trouvé vers A20 de Feuil1 (Remarque que rien n'est sélectionné)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Test()
Dim Sh As Worksheet
Dim c As Range
Dim Rech As String
Dim Trouve As Boolean
 
Rech = "toto"                                    'Mot à rechercher
For Each Sh In ThisWorkbook.Worksheets           'Pour chaque feuille dans ce classeur
    If Sh.Name <> "Feuil1" Then                  'Si le nom de la feuille est différent de Feuil1
        Set c = Sh.UsedRange.Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la feuille
        If Not c Is Nothing Then
            c.EntireRow.Copy Sheets("Feuil1").Range("A20") 'par exemple on copie la ligne trouvé en A20 de Feuil1
            Set c = Nothing
            Trouve = True
            Exit For                             'Ici pour arrêter la recherche dans les autres feuilles dès qu'on trouve le mot recherché
        End If
    End If
Next Sh
If Not Trouve Then MsgBox "Aucune occurence du mot " & Rech
End Sub

Edit:

1. Ou bien si on veut copier seulement une partie de la ligne

Code:

Sh.Range("A" & c.Row & ":M" & c.Row).Copy Sheets("Feuil1").Range("A20")

2. Si on connait la colonne de recherche dans les feuilles, on peut limiter la recherche dans cette colonne

Code:

Set c = Sh.Range("E:E").Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la colonne E des feuilles

03/06/2011, 10h39
gigalia

merci pour toutes ces infos ma macro marche très bien maitenant.