Erreur d'éxécution 1004

Version imprimable

1 pièce(s) jointe(s)

Bonsoir j'ai un soucis depuis quelque temps, j'ai crée un programme sous vba excel ou je récupère le contenu de plusieurs listes déroulantes dans une textbox.

Je veux ensuite aller ouvrir le fichier qui apparait dans ma textbox et que le contenu de celui-ci (qui existe sur mon disque dur) vienne se coller dans ma feuille excel a partir de la colonne A6.

J'ai donc fait une macro en allant rechercher un fichier dans le chemin mais j'aimerai maintenant pouvoir ouvrir n'importe quel fichier quand je change la valeur de ma liste déroulante.

le message d'érreur est : la méthode select de la classe range a échoué.

Voici mon code pour la partir ouvrir et coller le contenu du fichier de la textbox.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Dim fichier As String fichier = Txtselection.Text Txtselection.Text = "CH" & Combo1.Text & combo2.Text & "REP" & Combo3.Text & "BN" & Combo4.Text ChDir "C:\Documents and Settings\c550852\Desktop\Yoann" Workbooks.OpenText Filename:= _ "C:\Documents and Settings\c550852\Desktop\Yoann\" & fichier & ".txt", _ Origin:=xlMSDOS, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _ xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _ Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 1), _ TrailingMinusNumbers:=True Range("A2:A19").Select Selection.Copy ActiveWindow.Close Range("A6").Select ActiveSheet.Paste
Merci de m'aider s'il vous plait, je vous en serai reconnaissant.

Je vous mets en PJ le fichier

Essaies quelque chose comme ceci (pas testé)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub ButValider_Click()
Dim Chemin As String, Fichier As String
 
Txtselection.Text = "CH" & Combo1.Text & combo2.Text & "REP" & Combo3.Text & "BN" & Combo4.Text
Fichier = Txtselection.Text & ".txt"
Chemin = "C:\Documents and Settings\c550852\Desktop\Yoann\"
 
If Dir(Chemin & Fichier) <> "" Then
    Workbooks.OpenText Filename:=Chemin & Fichier, Origin:=xlMSDOS, StartRow:=1, _
                       DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
                       ConsecutiveDelimiter:=False, Tab:=True, FieldInfo:=Array(1, 1), _
                       TrailingMinusNumbers:=True
    ActiveWorkbook.Worksheets(1).Range("A2:A19").Copy ThisWorkbook.Worksheets(1).Range("A6")
    ActiveWorkbook.Close False
    MsgBox "Import " & Fichier & " terminé"
Else
    MsgBox "Fichier " & Chemin & Fichier & " inéxistant"
End If
End Sub

24/05/2011, 19h22
Maxime082

ça a marché parfaitement :)

merci beaucoup

J'allais oublier, pourriez-vous m'aider à mettre les lignes de code qu'il faut pour que le fichier s'enregistre automatiquement sous la forme :

CHC02SERIEREP01BN04_20110524192036 dans un chemin spécifique.

CHC02SERIEREP01BN04 : c'est le contenu de la textbox
20110524192036 : c'est la date du jour ainsi que l'heure
AAAAMMJJHHmmss

Il faut donc que quand je clique sur un bouton "enregistrer", celui-ci enregistre le fichier automatiquement avec la date et l'heure actuelle.

Cordialement