Boutons de commande

Version imprimable

Boutons de commande

Bonjour à tous,

Nous sommes des étudiants et devons réaliser un projet sur excel en VBA. N'étant pas informaticien, nous nous débrouillons avec le peu appris en cours et les tutoriaux sur internet. Mais nous sommes bloqué depuis peu et n'arrivons pas à comprendre d'où viennent nos erreurs.

Il nous a fallu créer des boutons de commande "créer", "modifier", "rechercher", "supprimer"

Lorsque nous rentrons nos données dans les champs que nous avons établi dans nos différents userforms, le bouton "créer" focntionne à merveille et insère les valeurs dans nos feuilles excels. Cependant, lorsqu'il s'agit d'utiliser les autres commandes, nous rencontrons différents problèmes:
soit cela supprime nos en-têtes, soit cela rajoute une ligne, etc..

J'espère que vous pourrez nous mettre sur une piste

Merci d'avance

Voici ce que nous avons codés pour un de nos formulaires nommé "Employés":

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Private Sub CB_Créer_Click()
Dim ws As Worksheet
Dim i As Long
Set ws = Worksheets("Employés")
 
'Trouver la première cellule disponible
i = ws.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row
 
'Vérifier si le nom existe
If Trim(Me.nom_TB.Value) = "" Then
    Me.nom_TB.SetFocus
    MsgBox "Entrez un nom"
    Exit Sub
End If
 
'Entrer les données dans le ws
ws.Cells(i, 1).Value = Me.nom_TB.Value
ws.Cells(i, 2).Value = Me.Prénom_TB.Value
ws.Cells(i, 3).Value = Me.Fonction_TB.Value
ws.Cells(i, 4).Value = Me.Matricule_TB.Value
ws.Cells(i, 5).Value = Me.Date_Naissance_TB.Value
ws.Cells(i, 6).Value = Me.Adresse_TB.Value
ws.Cells(i, 7).Value = Me.Code_postal_TB.Value
ws.Cells(i, 8).Value = Me.Ville_TB.Value
ws.Cells(i, 9).Value = Me.Pays_TB.Value
ws.Cells(i, 10).Value = Me.TB_Salaire.Value
ws.Cells(i, 11).Value = Me.Téléphone_TB.Value
ws.Cells(i, 12).Value = Me.GSM_TB.Value
ws.Cells(i, 13).Value = Me.Email_TB.Value
 
'Initialiser les données
Me.nom_TB.Value = ""
Me.Prénom_TB.Value = ""
Me.Fonction_TB.Value = ""
Me.Matricule_TB.Value = ""
Me.Date_Naissance_TB.Value = ""
Me.Adresse_TB.Value = ""
Me.Code_postal_TB.Value = ""
Me.Ville_TB.Value = ""
Me.Pays_TB.Value = ""
Me.TB_Salaire = ""
Me.Téléphone_TB.Value = ""
Me.GSM_TB.Value = ""
Me.Email_TB.Value = ""
 
Me.nom_TB.SetFocus
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub CB_Modifier_Click()
Dim ws As Worksheet
Dim i As Long
Set ws = Worksheets("Employés")
 
'Sélectionner la ligne à modifier
i = Me.SpinButton1.Value
 
'Vérifier si le nom existe
If Trim(Me.nom_TB.Value) = "" Then
    Me.nom_TB.SetFocus
    MsgBox "Entrez un nom"
    Exit Sub
End If
 
'Entrer les données dans le ws
ws.Cells(i, 1).Value = Me.nom_TB.Value
ws.Cells(i, 2).Value = Me.Prénom_TB.Value
ws.Cells(i, 3).Value = Me.Fonction_TB.Value
ws.Cells(i, 4).Value = Me.Matricule_TB.Value
ws.Cells(i, 5).Value = Me.Date_Naissance_TB.Value
ws.Cells(i, 6).Value = Me.Adresse_TB.Value
ws.Cells(i, 7).Value = Me.Code_postal_TB.Value
ws.Cells(i, 8).Value = Me.Ville_TB.Value
ws.Cells(i, 9).Value = Me.Pays_TB.Value
ws.Cells(i, 10).Value = Me.TB_Salaire.Value
ws.Cells(i, 11).Value = Me.Téléphone_TB.Value
ws.Cells(i, 12).Value = Me.GSM_TB.Value
ws.Cells(i, 13).Value = Me.Email_TB.Value
 
Me.nom_TB.SetFocus
 
End Sub

Code:

1
2
3
4
5
Private Sub CB_Quitter_Click()
 
Unload Me
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub CB_Rechercher_Click()
 
Dim ws As Worksheet
Dim i As Long
Set ws = Worksheets("Employés")
 
 
'Recherche Nom
For i = 1 To ws.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row Step 1
If InStr(1, ws.Cells(i, 1).Value, Me.nom_TB.Value, 1) Then
Exit For
End If
 
Next i
 
'Retrouver la fiche
ws.Cells(i, 1).Value = Me.nom_TB.Value
ws.Cells(i, 2).Value = Me.Prénom_TB.Value
ws.Cells(i, 3).Value = Me.Fonction_TB.Value
ws.Cells(i, 4).Value = Me.Matricule_TB.Value
ws.Cells(i, 5).Value = Me.Date_Naissance_TB.Value
ws.Cells(i, 6).Value = Me.Adresse_TB.Value
ws.Cells(i, 7).Value = Me.Code_postal_TB.Value
ws.Cells(i, 8).Value = Me.Ville_TB.Value
ws.Cells(i, 9).Value = Me.Pays_TB.Value
ws.Cells(i, 10).Value = Me.TB_Salaire.Value
ws.Cells(i, 11).Value = Me.Téléphone_TB.Value
ws.Cells(i, 12).Value = Me.GSM_TB.Value
ws.Cells(i, 13).Value = Me.Email_TB.Value
 
Me.nom_TB.SetFocus
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub CB_Supprimer_Click()
Dim ws As Worksheet
Dim i As Long
Set ws = Worksheets("Employés")
 
'Trouver la première cellule disponible
i = Me.SpinButton.Value
 
'Supprimer une donnée
ws.Rows(i).EntireRow.Delete
 
'Initialiser les données
Me.nom_TB.Value = ""
Me.Prénom_TB.Value = ""
Me.Fonction_TB.Value = ""
Me.Matricule_TB.Value = ""
Me.Date_Naissance_TB.Value = ""
Me.Adresse_TB.Value = ""
Me.Code_postal_TB.Value = ""
Me.Ville_TB.Value = ""
Me.Pays_TB.Value = ""
Me.TB_Salaire = ""
Me.Téléphone_TB.Value = ""
Me.GSM_TB.Value = ""
Me.Email_TB.Value = ""
 
Me.nom_TB.SetFocus
 
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub SpinButton_1Change()
 
Dim ws As Worksheet
Dim i As Long
Set ws = Worksheets("Employés")
 
i = Me.SpinButton.Value
 
   'Empêche de trop remonter
       If i < 2 Then
        i = 2
        SpinButton1.Value = 1
    End If
 
 
Me.nom_TB.Value = ws.Cells(i, 1).Value
Me.Prénom_TB.Value = ws.Cells(i, 2).Value
Me.Fonction_TB.Value = ws.Cells(i, 3).Value
Me.Matricule_TB.Value = ws.Cells(i, 4).Value
Me.Date_Naissance_TB.Value = ws.Cells(i, 5).Value
Me.Adresse_TB.Value = ws.Cells(i, 6).Value
Me.Code_postal_TB.Value = ws.Cells(i, 7).Value
Me.Ville_TB.Value = ws.Cells(i, 8).Value
Me.Pays_TB.Value = ws.Cells(i, 9).Value
Me.TB_Salaire.Value = ws.Cells(i, 10).Value
Me.Téléphone_TB.Value = ws.Cells(i, 11).Value
Me.GSM_TB.Value = ws.Cells(i, 12).Value
Me.Email_TB.Value = ws.Cells(i, 13).Value
 
End Sub

Bonsoir,

Un début pour voir si j'ai compris :

Code:

1
2
3
Option Explicit
Dim ws As Worksheet
Dim i As Long

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub CB_Créer_Click()
Dim Ctrl As Control
Set ws = Worksheets("Employés")
 
'vu la suite, je pense qu'il faut enlever "offset"
i = ws.Range("A" & ws.Rows.Count).End(xlUp).Row
 
'Vérifier si le nom existe
If Trim(Me.nom_TB.Value) = "" Then
    Me.nom_TB.SetFocus
    MsgBox "Entrez un nom"
    Exit Sub
Else
   'Entrer les données dans le ws
   ws.Cells(i, 1).Value = Me.nom_TB.Value
   ws.Cells(i, 2).Value = Me.Prénom_TB.Value
   ws.Cells(i, 3).Value = Me.Fonction_TB.Value
   ws.Cells(i, 4).Value = Me.Matricule_TB.Value
   ws.Cells(i, 5).Value = Me.Date_Naissance_TB.Value
   ws.Cells(i, 6).Value = Me.Adresse_TB.Value
   ws.Cells(i, 7).Value = Me.Code_postal_TB.Value
   ws.Cells(i, 8).Value = Me.Ville_TB.Value
   ws.Cells(i, 9).Value = Me.Pays_TB.Value
   ws.Cells(i, 10).Value = Me.TB_Salaire.Value
   ws.Cells(i, 11).Value = Me.Téléphone_TB.Value
   ws.Cells(i, 12).Value = Me.GSM_TB.Value
   ws.Cells(i, 13).Value = Me.Email_TB.Value
   'Initialiser les données
   For Each Ctrl In Me.Controls
      If TypeOf Ctrl Is MSForms.TextBox Then
         Ctrl.Object.Value = ""
      End If
   Next Ctrl
End If
Me.nom_TB.SetFocus
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub CB_Modifier_Click()
Set ws = Worksheets("Employés")
 
'Sélectionner la ligne à modifier
i = Me.SpinButton1.Value
 
'Vérifier si le nom existe
If Trim(Me.nom_TB.Value) = "" Then
   Me.nom_TB.SetFocus
   MsgBox "Entrez un nom"
   Exit Sub
Else
'Entrer les données dans le ws
'pour vérifier l'adresse de ws.Cells(i, 1), msgbox temporaire
   MsgBox ws.Cells(i, 1).Address
   ws.Cells(i, 1).Value = Me.nom_TB.Value
   ws.Cells(i, 2).Value = Me.Prénom_TB.Value
   ws.Cells(i, 3).Value = Me.Fonction_TB.Value
   ws.Cells(i, 4).Value = Me.Matricule_TB.Value
   ws.Cells(i, 5).Value = Me.Date_Naissance_TB.Value
   ws.Cells(i, 6).Value = Me.Adresse_TB.Value
   ws.Cells(i, 7).Value = Me.Code_postal_TB.Value
   ws.Cells(i, 8).Value = Me.Ville_TB.Value
   ws.Cells(i, 9).Value = Me.Pays_TB.Value
   ws.Cells(i, 10).Value = Me.TB_Salaire.Value
   ws.Cells(i, 11).Value = Me.Téléphone_TB.Value
   ws.Cells(i, 12).Value = Me.GSM_TB.Value
   ws.Cells(i, 13).Value = Me.Email_TB.Value
End If
Me.nom_TB.SetFocus
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Private Sub CB_Rechercher_Click()
Dim plage As Range
Dim rech As Range
Set ws = Worksheets("Employés")
i = ws.Cells(Rows.Count, 1).End(xlUp).Row
Set plage = ws.Range("A2:A" & i)
'Recherche Nom
'si un nom est entré dans le "nom_TB"
Set rech = plage.Find(Me.nom_TB.Value)
If rech Is Nothing Then
   MsgBox "nom non trouvé"
   Exit Sub
Else
   Me.nom_TB.Value = ws.Range("A" & rech.Row).Value
   Me.Prénom_TB.Value = ws.Range("B" & rech.Row).Value
   Me.Fonction_TB.Value = ws.Range("C" & rech.Row).Value
   Me.Matricule_TB.Value = ws.Range("D" & rech.Row).Value
   Me.Date_Naissance_TB.Value = ws.Range("E" & rech.Row).Value
   Me.Adresse_TB.Value = ws.Range("F" & rech.Row).Value
   Me.Code_postal_TB.Value = ws.Range("G" & rech.Row).Value
   Me.Ville_TB.Value = ws.Range("H" & rech.Row).Value
   Me.Pays_TB.Value = ws.Range("I" & rech.Row).Value
   Me.TB_Salaire.Value = ws.Range("J" & rech.Row).Value
   Me.Téléphone_TB.Value = ws.Range("K" & rech.Row).Value
   Me.GSM_TB.Value = ws.Range("L" & rech.Row).Value
   Me.Email_TB.Value = ws.Range("M" & rech.Row).Value
 
 
'GARDER LA SUITE POUR LES MODIFS
'ws.Cells(i, 1).Value = Me.nom_TB.Value
'ws.Cells(i, 2).Value = Me.Prénom_TB.Value
'ws.Cells(i, 3).Value = Me.Fonction_TB.Value
'ws.Cells(i, 4).Value = Me.Matricule_TB.Value
'ws.Cells(i, 5).Value = Me.Date_Naissance_TB.Value
'ws.Cells(i, 6).Value = Me.Adresse_TB.Value
'ws.Cells(i, 7).Value = Me.Code_postal_TB.Value
'ws.Cells(i, 8).Value = Me.Ville_TB.Value
'ws.Cells(i, 9).Value = Me.Pays_TB.Value
'ws.Cells(i, 10).Value = Me.TB_Salaire.Value
'ws.Cells(i, 11).Value = Me.Téléphone_TB.Value
'ws.Cells(i, 12).Value = Me.GSM_TB.Value
'ws.Cells(i, 13).Value = Me.Email_TB.Value
End If
Me.nom_TB.SetFocus
 
End Sub

Par contre, pour le bouton "supprimer", je n'ai rien fait car ce n'est pas clair, ça manque d'explication sur le but à atteindre

Bonne soirée

16/05/2011, 20h08
Leswiss

hallelujah!

Merci pour ta réponse: le bouton "rechercher" fonctionne! Maintenant reste plus qu'a comprendre pourquoi ^^

Par contre la fonction "modifier" m'indique $A$1 lorsque je clique sur le bouton.

Et pour ce qui est du bouton "supprimer", voici les consignes:
"Supprimer : pour supprimer une ligne de données sélectionnée via un des
userForms développés"
16/05/2011, 20h12
casefayere

Citation:

Par contre la fonction "modifier" m'indique $A$1 lorsque je clique sur le bouton.

je l'ai fait volontairement pour que tu vérifies si l'adresse est bien la bonne

Commences-tu à écrire en A1 ?, ça m'étonnerai, il faut donc adapter en fonction, c'est la valeur de ton spinbutton qui prime
17/05/2011, 15h54
Leswiss

Bonjour bonjour !

Non je commence à écrire en ligne 2.

Par contre quand vous parlez de la valeur du spinbutton, je ne vois pas comment lui donner la valeur de la ligne que je traite. Je m'explique: quand j'utilise la fonction spinbutton, que je clique sur la flèche de droite ou de gauche, il me remet à la première ligne d'information= ligne2 (ligne 1 = en-tête). Je suppose qu'il considère donc que sa valeur vaut ligne 2..?
17/05/2011, 17h39
mercatog

Bonjour
Réponse à l'un de tes collègues qui est en avance:
Lien réponse
17/05/2011, 23h13
Leswiss

Merci pour le lien ;) bonne soirée!

Meme en regardant la réponse donnée dans l'autre post, la ligne que je supprime est toujours la meme :
Quelque soit la recherche effectuée (cela peut autant etre la ligne 2 que 20), il supprimera automatiquement la ligne 1. Le probleme vient de la:

i = Me.SpinButton1.Value

car lorsque j'écris i = Me.SpinButton1.Value + 1, il supprime la seconde ligne automatiquement. Que faire?
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 Private Sub CB_Supprimer_Click() Dim ws As Worksheet Dim i As Long Set ws = Worksheets("Employés") With Employés If Me.nom_TB.Value <> "" Then i = Me.SpinButton1.Value If MsgBox("Confirmer la suppression de " & Me.nom_TB.Value & "?", vbCritical + vbYesNo) = vbYes Then ws.Rows(i).EntireRow.Delete Me.SpinButton1.Value = i - 1 MsgBox "Suppression terminée" Unload Me End If Else MsgBox "Veuillez introduire un nom" End If End With End Sub

Il faut reprendre tous les codes, ils sont liés

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
Private Sub UserForm_Initialize()
Dim Fin As Long
 
With Feuil2    'ou Sheets("employes")
    Fin = .Range("A" & .Rows.Count).End(xlUp).Row
End With
With Me.SpinButton1
    .Min = 1
    .Max = Fin + 1
End With
Me.btnmodifier.Enabled = False
Me.btnsupprimer.Enabled = False
End Sub
 
Private Sub T_datedenaissance_Change()
Dim Valeur As Byte
 
T_datedenaissance.MaxLength = 10                                     'nb caractères maxi autorisé dans le textbox
Valeur = Len(T_datedenaissance)
If Valeur = 2 Or Valeur = 5 Then T_datedenaissance = T_datedenaissance & "/"
End Sub
 
 
Private Sub SpinButton1_SpinDown()
 
With Me.SpinButton1
    If .Value <= .Min + 1 Then .Value = .Max - 1
End With
End Sub
 
 
Private Sub SpinButton1_SpinUp()
 
With Me.SpinButton1
    If .Value >= .Max Then .Value = .Min + 1
End With
End Sub
 
Private Sub SpinButton1_Change()
Dim i As Long
 
i = Me.SpinButton1.Value
If i >= 2 Then
    With Feuil2
        Me.T_nom = .Cells(i, 1)
        Me.T_prenom = .Cells(i, 2)
        Me.T_fonction = .Cells(i, 3)
        Me.T_matricule = .Cells(i, 4)
        Me.T_datedenaissance = .Cells(i, 5)
        Me.T_adresse = .Cells(i, 6)
        Me.T_codepostal = .Cells(i, 7)
        Me.T_ville = .Cells(i, 8)
        Me.T_pays = .Cells(i, 9)
        Me.T_salairebrutannuel = .Cells(i, 10)
        Me.T_numerodetelephone = .Cells(i, 11)
        Me.T_numerodegsm = .Cells(i, 12)
        Me.T_email = .Cells(i, 13)
    End With
End If
Me.btnmodifier.Enabled = True
Me.btnsupprimer.Enabled = True
End Sub
 
Private Sub btncreer_Click()
Dim i As Long
 
With Feuil2    'ou Sheets("employes")
    If Me.T_nom.Value <> "" Then
        i = .Range("A" & .Rows.Count).End(xlUp).Row + 1
        With Me.SpinButton1
            .Max = .Max + 1
        End With
        .Cells(i, 1) = Me.T_nom
        .Cells(i, 2) = Me.T_prenom
        .Cells(i, 3) = Me.T_fonction
        .Cells(i, 4) = Me.T_matricule
        .Cells(i, 5) = Me.T_datedenaissance
        .Cells(i, 6) = Me.T_adresse
        .Cells(i, 7) = Me.T_codepostal
        .Cells(i, 8) = Me.T_ville
        .Cells(i, 9) = Me.T_pays
        .Cells(i, 10) = Me.T_salairebrutannuel
        .Cells(i, 11) = Me.T_numerodetelephone
        .Cells(i, 12) = Me.T_numerodegsm
        .Cells(i, 13) = Me.T_email
        MsgBox "Création effectuée"
        Me.SpinButton1.Value = i
    Else
        MsgBox "Veuillez introduire un code produit"
    End If
End With
End Sub
 
Private Sub btnrecherche_Click()
Dim Fin As Long
Dim c As Range
 
If Me.T_nom.Value = "" Then
    MsgBox "Introduisez un nom SVP!!"
Else
    With Feuil2
        Fin = .Cells(.Rows.Count, 1).End(xlUp).Row
        Set c = .Range("A2:A" & Fin).Find(Me.T_nom.Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            Me.SpinButton1.Value = c.Row
            Set c = Nothing
        Else
            Me.SpinButton1.Value = 1
            MsgBox "Aucun résultat"
        End If
    End With
End If
Me.btnmodifier.Enabled = True
Me.btnsupprimer.Enabled = True
End Sub
 
Private Sub btnmodifier_Click()
Dim i As Long
 
With Feuil2    'ou Sheets("employes")
    If Me.T_nom.Value <> "" Then
        i = Me.SpinButton1.Value
        If MsgBox("Confirmer modification de " & Me.T_nom.Value & "?", vbCritical + vbYesNo) = vbYes Then
            .Cells(i, 1) = Me.T_nom
            .Cells(i, 2) = Me.T_prenom
            .Cells(i, 3) = Me.T_fonction
            .Cells(i, 4) = Me.T_matricule
            .Cells(i, 5) = Me.T_datedenaissance
            .Cells(i, 6) = Me.T_adresse
            .Cells(i, 7) = Me.T_codepostal
            .Cells(i, 8) = Me.T_ville
            .Cells(i, 9) = Me.T_pays
            .Cells(i, 10) = Me.T_salairebrutannuel
            .Cells(i, 11) = Me.T_numerodetelephone
            .Cells(i, 12) = Me.T_numerodegsm
            .Cells(i, 13) = Me.T_email
            MsgBox "Modification effectuée"
            Unload Me
        End If
    Else
        MsgBox "Veuillez introduire un code produit"
    End If
End With
End Sub
 
Private Sub btnsupprimer_Click()
Dim i As Long
 
With Feuil2    'ou Sheets("employes")
    If Me.T_nom.Value <> "" Then
        i = Me.SpinButton1.Value
        If MsgBox("Confirmer suppression de " & Me.T_nom.Value & "?", vbCritical + vbYesNo) = vbYes Then
            .Rows(i).Delete
            Me.SpinButton1.Value = i - 1
            MsgBox "Suppression effectuée"
            Unload Me
        End If
    Else
        MsgBox "Veuillez introduire un code produit"
    End If
End With
End Sub
 
Private Sub btnquitter_Click()
 
Unload Me
End Sub

Teste et reviens ici pour les explications après adaptation des noms des feuilles et des divers contrôles de ton userform

18/05/2011, 22h25
Leswiss

Okay je regarderai ça demain et je reviendrai dire quoi ;-) En tout cas, deja merci pour l'aide !
19/05/2011, 22h33
Leswiss

Certains trucs ne fonctionnent toujours mais je vais en rester la. Bonne soirée à tous et merci pour les réponses
19/05/2011, 22h47
mercatog

Bonsoir
Par respect au forum, quels sont les "trucs" qui ne fonctionnent encore pas? Il fallait relater ton code adapté et indiquer le(s) souci(s).

Désolé pour mon français mais qu'entend-tu par "truc"?

Le but final et d'arriver à un résultat valable qui pourrait aider les éventuels forumistes qui auraient un problème ou situation similaire.