[XL-2003] [VBA-stage]Problème Diagramme automatisé

Bonsoir,

Je ne suis pas certain d'avoir correctement saisi le but de votre code...
Mais... voici un exemple très simple qui pourra vous permettre de partir sur des bases plus saines:
(a insérer dans votre module)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Option Explicit
 
Const cSheetDataName As String = "Feuil1"
Const cSheetChartName As String = "Feuil2"
Const cRangeData As String = "C:E"
 
Sub prcCreateChart()
Dim vScreenUpdating As Boolean
Dim vSheetData As Worksheet
Dim vSheetChart As Worksheet
Dim vChart As ChartObject
On Error GoTo lblErr
 
'Historiser la valeur de maj de l'écran
vScreenUpdating = Application.ScreenUpdating
 
'Désactiver la maj de l'écran
If vScreeUpdating Then Application.ScreenUpdating = False
 
'Initialiser les feuillees
Set vSheetData = ThisWorkbook.Worksheets(cSheetDataName)
Set vSheetChart = ThisWorkbook.Worksheets(cSheetChartName)
 
'Supprimer les graphes existants
While vSheetChart.ChartObjects.Count > 0
  vSheetChart.ChartObjects(1).Delete
Wend
 
'Ajouter un graphe
Set vChart = vSheetChart.ChartObjects.Add(10, 10, 500, 500)
 
'Formater le graphe
With vChart.chart
  .SetSourceData Worksheets(cSheetDataName).Range(cRangeData)
  .ChartType = xl3DColumnStacked
  'Suite de la mise en forme
End With
 
GoTo lblFin
 
lblErr:
  Debug.Print Err.Number
  Debug.Print Err.Description
 
lblFin:
Set vChart = Nothing
Set vSheetChart = Nothing
Set vSheetData = Nothing
 
If vScreenUpdating <> Application.ScreenUpdating Then Application.ScreenUpdating = vScreenUpdating
 
End Sub