Afficher seulement certaines lignes de TCD - VBA

Version imprimable

Basiquement, je développe une fonction qui permet à l'utilisateur de choisir dans une Listbox les noms des gens qu'ils veulent voir affichés, les autres sont alors cachés. Le tout est basé sur un TCD

En pratique, j'ai une macro qui lit la Lisbox et stocke les nom dans un Array appelé "output" et qui a un maximum de 1000 éléments.

Suite à ça, j'utilise les noms listés dans "output", et je cherche à ce que ces noms restent affichés dans le TDC (champs de ligne).

Pour ce faire, j'ai écrit le code ci-dessous:
1- Cacher toutes les lignes
2- Afficher les personnes ("Buyers") qui sont listés dans "output"

Le problème est que ça ne marche pas vraiment. La partie qui retire les ligne fonctionne, mais je n'arrive pas à ré-afficher. :(

Qu'est ce qui ne va pas dans mon code?

Merci de votre aide!! :)
Olivier
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 Sub test() Dim pt As PivotTable Dim pi As PivotItem Dim output(0 To 1000) As String Dim i As Integer Dim j As Integer 'Crée Output à partir de la Listbox ByrSelectList, marche OK j = 0 For i = 0 To ActiveSheet.ByrSelectList.ListCount - 1 If ActiveSheet.ByrSelectList.Selected(i) Then output(j) = ActiveSheet.ByrSelectList.List(i) j = j + 1 End If Next i Set pt = ActiveSheet.PivotTables("PivotTable1") 'Cache toutes les lignes champs appelé "Buyer" dans le TCD For Each pi In pt.PivotFields("Buyer").PivotItems On Error Resume Next pi.Visible = False Next pi 'Affiche les lignes qui sont dans l'array output(), ne marche pas :'( For i = 0 To 1000 pt.PivotFields("Buyer").PivotItems(output(i)).Visible = True Next i end sub

Un vieux problème

Bonsoir.

Ton code n'est pas mal conçu mais tu es tombé sur un pb assez connu, quoique pas très bien maîtrisé.

Je te laisse d'abord apprécier l'aide et support Microsoft Unable to Set Visible Property PivotItem class.

Voilà. Je pense que tu aimes beaucoup la solution proposée.:zen:

Je te propose d'essayer cela.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Sub test()
Dim pt As PivotTable, pf As Excel.PivotField, pi As PivotItem
Dim sSortField As String, lSortOrder As Long
Dim output(0 To 1000) As String
Dim i As Integer
Dim j As Integer
 
'Crée Output à partir de la Listbox ByrSelectList, marche OK
j = 0
For i = 0 To ActiveSheet.ByrSelectList.ListCount - 1
    If ActiveSheet.ByrSelectList.Selected(i) Then
        output(j) = ActiveSheet.ByrSelectList.List(i)
        j = j + 1
    End If
Next i
 
 
 
Set pt = ActiveSheet.PivotTables("PivotTable1")
Set pf = pt.PivotFields("Buyer")
 
'accélère le traitement
pt.ManualUpdate = True
 
'conditionne pf
sSortField = pf.AutoSortField
lSortOrder = pf.AutoSortOrder
pf.AutoSort xlManual, pf.Name
 
'Cache toutes les lignes champs appelé "Buyer" dans le TCD
For Each pi In pf.PivotItems
    On Error Resume Next
    pi.Visible = False
Next pi
 
'Affiche les lignes qui sont dans l'array output(), ne marche pas :'(
For i = 0 To 1000
    pf.PivotItems(output(i)).Visible = True
Next i
 
'rétablir état initial
pf.AutoSort lSortOrder, sSortField
pt.ManualUpdate = False
 
Set pf = Nothing
Set pt = Nothing
 
End Sub

Si ça ne marche pas (après mise au point), il faudra passer à des solutions plus lourdes...

COrdialement,

PGZ

Ca marche!

Bonjour à tous,

Merci PGZ pour ta suggestion. Le fait de passer le TCD en mode tri manuel permet de cacher les éléments de colonne, fini les runtime error :ccool:

Ceci étant, il n'est toujours pas possible de cacher le dernier élément du TCD, ce qui s'illustrait dans mon cas en un élément indésirable qui s'avérait être ... le dernier de la liste en tri automatique (une personne dont le nom commence en Z).

Ce que j'ai fait ci-dessous contourne ce problème: je fais en sorte que le dernier élément de ma liste soit "(blank)", de façon à savoir lequel c'est, puis je l'élimine une fois que j'ai réaffiché ma sélection.

Ca marche bien! Merci du coup de main!! Code ci-dessous!

Olivier

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
 
 
Public Sub ReSelect() '**************** BYR SELECTION
 
Application.ScreenUpdating = False
 
'Reads buyers selected in Listbox ByrSelectList, writes it in an array
Dim output(0 To 1000) As String
Dim i As Integer
Dim j As Integer
 
j = 0
    For i = 0 To ActiveSheet.ByrSelectList.ListCount - 1
            If ActiveSheet.ByrSelectList.Selected(i) Then
                output(j) = ActiveSheet.ByrSelectList.List(i) 'only the selected
                j = j + 1
        End If
        Next i
 
Dim pt As PivotTable
Dim pf As Excel.PivotField
Dim sSortField As String, lSortOrder As Long
Dim pi As PivotItem
 
    Set pt = ActiveSheet.PivotTables("PivotTable1")
    Set pf = pt.PivotFields("Buyer")
 
pt.ManualUpdate = True     'Speeds up code dramatically
 
 
'conditionning of buyer list
sSortField = pf.AutoSortField
lSortOrder = pf.AutoSortOrder
pf.AutoSort xlManual, pf.Name
 
pf.PivotItems("(blank)").Visible = True
pf.PivotItems("(blank)").Position = pf.VisibleItems.Count
 
'hides all rows
For Each pi In pf.PivotItems
On Error Resume Next
    pi.Visible = False
Next pi
 
Nextstep:
For i = 0 To 1000
On Error Resume Next
If output(i) <> "" Then pf.PivotItems(output(i)).Visible = True
Next i
 
pf.PivotItems("(blank)").Visible = False
 
'puts the buyers back in their previous order
pf.AutoSort lSortOrder, sSortField
pt.ManualUpdate = False
 
Set pf = Nothing
Set pt = Nothing
 
 
Application.ScreenUpdating = True
 
End Sub