Erreur "Object variable or With block variable not set" en définissant une Range

Version imprimable

Bonjour

J'essaie d'écrire une fonction qui permet de renvoyer la région contenant toutes les cellules non vides au dessous d'une cellule d'origine, s'ils en existent. L'erreur apparait au moment de l'affectation de la region à la fonction (SelectRange = RangeResult). Voici le code de ma fonction:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Public Function SelectRange(ByVal CellRange As Range) As Range If GetLineNumber(CellRange) > 1 Then Dim Ws_Result As Worksheet Set Ws_Result = CellRange.Worksheet Dim RangeResult As Range Set RangeResult = Ws_Result.Range(CellRange, CellRange.End(xlDown)) SelectRange = RangeResult Else SelectRange = CellRange End If End Function
Quelqu'un aura une idée sur l'origine de ce bogue qui me bloque depuis hier?
Merci

Bonjour DamAym,

As-tu essayé :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Public Function SelectRange(ByVal CellRange As Range) As Range
    If GetLineNumber(CellRange) > 1 Then
        Dim Ws_Result As Worksheet
        Set Ws_Result = CellRange.Worksheet
        Dim RangeResult As Range
        Set RangeResult = Ws_Result.Range(CellRange, CellRange.End(xlDown))
        Set SelectRange = RangeResult
    Else
        Set SelectRange = CellRange
    End If
 
End Function

Bonjour,
Voici un code à adapter selon tes besoins
Une fonction renvoie un range de la zone où se trouve la cellule, l'autre fonction renvoie le range uniquement des cellule vide de cette région.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
Public Function SelectRegion(cellRange As Range) As Range
  Set SelectRegion = cellRange.CurrentRegion
End Function
Public Function SelectRegionVide(cellRange As Range) As Range
  Set SelectRegionVide = cellRange.CurrentRegion.SpecialCells(xlCellTypeBlanks)
End Function
Sub Test()
  Dim sht As Worksheet
  Dim maCellule As Range
  Set sht = ThisWorkbook.Worksheets("Test")
  Set maCellule = sht.Range("B3")
  ' Région
  MsgBox SelectRegion(maCellule).Address
  SelectRegion(maCellule).Select
  ' Région Vide
   MsgBox SelectRegionVide(maCellule).Address
  SelectRegionVide(maCellule).Select
End Sub

14/04/2011, 16h06
DamAym

Merci beaucoup pour vos réponses,

Effectivement, maintenant ça passe l'instruction "Set SelectRange = RangeResult", mais il se plante à la fin de la fonction et me remonte la même erreur à ligne "End Function"

Corona, elle est sympa ta fonction, mais elle me renvoie effectivement toute la region, y compris les colonnes voisines. J'essaie de récupérer juste la colonne de la Range passée en paramètre (elle est une cellule dans mon cas)

S'il y en a d'autres idées j'en suis preneur :D

Merci d'avance

Bon une très bonne nouvelle,

Apparemment l'erreur vient de la ligne "Option Explicit", je l'ai ajouté au début du script, et j'ai ajouté le "Set FunctionName" dans les autres fonction et ça a marché.

Je peut dire que mon problème est résolu, Merci beaucoup pour votre aide :ccool:
14/04/2011, 16h32
Philippe Tulliez

Bonjour,
Option Explicit est juste là pour s'obliger à déclarer toutes les variables que l'on utilise dans une procédure. C'est une bonne pratique de programmation qui évite que l'on utilise une variable nommée par erreur.
SET variable = Objet (SET) est l'instruction obligatoire pour attribuer une référence d'objet à la variable contrairement à Variable = Valeur pour les autres variables. L'instruction Variable = Objet provoque un message d'erreur.