Probleme de recuperation de Texbox

Version imprimable

Bonjour
J'ai le code suivant:
Je recupere le texbox dans la feuille en cours, mais je n'arrive pas a le recuperer dans une autre feuille, je recupere bien le dtpicker.
j'ai mis en rouge l'endroit ou le code ne fonctionne plus
si quelqu'un peu me dire dans ce code, comment faire pour ne pas faire
de .select, car j'ai encore la mauvaise habitude d'utilise ceci, mais je ne sais comment faire
merci
cris

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim i As Integer
 
If Controls("Textbox1") = "" Then
   MsgBox "Vous devez ABSOLUMENT indiquer Un Nom !", vbExclamation, _
          "ERREUR ... Entrez un Nom SVP !"
   Controls("Textbox1").SetFocus
   Exit Sub
End If
 
Application.ScreenUpdating = False
With Selection
   .HorizontalAlignment = xlCenter
   .VerticalAlignment = xlCenter
End With
Selection.Merge
Selection = UserForm1.Textbox1
Unload UserForm1
With Selection.Interior
   .Color = 65535
End With
With Selection.Font
   .ColorIndex = xlAutomatic
   Selection.Font.Bold = True
End With
'#--------------------------------------------------
For Each Sh In Worksheets(Array("janv", "fevr", "mars", "Avr", "Mai", "Juin", "Juil", "Aout", "Sept", "Oct", "Nov", "Dec"))
   With Sh
      For i = 9 To 73
         .Range("B" & i) = 0
         If .Range("C" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
         If .Range("K" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
         If .Range("R" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
         If .Range("Y" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
      Next i
   End With
Next Sh
Sheets("recap_clients").Select
    [B3] = UserForm1.Textbox1
    [C3] = UserForm1.DTPicker1.Value
  Rows("3:3").Select
  Selection.Insert Shift:=xlDown
Application.ScreenUpdating = True
End Sub

12/04/2011, 09h43
OokieDookie91

Bonjour,

Je pense que le souci vient de la ligne 19:

Code:

Unload UserForm1

(cf. http://silkyroad.developpez.com/VBA/UserForm/)

Il serait préférable d'utiliser

Code:

UserForm1.Hide

+ Unload en fin de procédure.

Bonne journée

Bonjour le forum, cris,

Une approche, attention à mes remarques

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim i As Integer
 
If userform1.Textbox1 = "" Then 'remplacer par nom USF
   MsgBox "Vous devez ABSOLUMENT indiquer Un Nom !", vbExclamation, _
          "ERREUR ... Entrez un Nom SVP !"
   userform1.Textbox1.SetFocus 'remplacer par nom USF
   Exit Sub
End If
 
Application.ScreenUpdating = False
With Selection 'si la selection est effective...
   .HorizontalAlignment = xlCenter
   .VerticalAlignment = xlCenter
    .Merge 'si la selection est effective...
    Selection = userform1.Textbox1 'si la selection est effective et n'est que sur 1 cellule
    .Interior.Color = 65535 'si la selection est effective... (je me répète)
    With .Font
        .ColorIndex = xlAutomatic
        .Bold = True
    End With
End With
'#--------------------------------------------------
For Each Sh In Worksheets(Array("janv", "fevr", "mars", "Avr", "Mai", "Juin", "Juil", "Aout", "Sept", "Oct", "Nov", "Dec"))
   With Sh
      For i = 9 To 73
         .Range("B" & i) = 0
         If .Range("C" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
         If .Range("K" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
         If .Range("R" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
         If .Range("Y" & i).Interior.Color = 65535 Then .Range("B" & i) = .Range("B" & i) + 0.25
      Next i
   End With
Next Sh
With Sheets("recap_clients")
    .Range("B3") = userform1.Textbox1
    .Range("C3") = userform1.DTPicker1.Value
    .Rows("3:3").Insert Shift:=xlDown
End With
Unload userform1
Application.ScreenUpdating = True
End Sub

PS : j'avais oublié un "End With

12/04/2011, 10h41
chris09300

Merci dom
j'ai tout note ce que tu me disait et ca fonctionne
merci
cris